vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     ui/listview.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/friendlistitemdelegate.cpp
  61 HEADERS += application.h \
  62     common.h \
  63     engine/engine.h \
  64     facebookservice/facebookauthentication.h \
  65     facebookservice/facebookcommon.h \
  66     facebookservice/facebookcredentials.h \
  67     gps/gpscommon.h \
  68     gps/gpsposition.h \
  69     map/baselocationitem.h \
  70     map/friendgroupitem.h \
  71     map/frienditemshandler.h \
  72     map/friendlocationitem.h \
  73     map/gpslocationitem.h \
  74     map/mapcommon.h \
  75     map/mapengine.h \
  76     map/mapfetcher.h \
  77     map/mapscene.h \
  78     map/mapscroller.h \
  79     map/maptile.h \
  80     map/maptilerequest.h \
  81     map/mapview.h \
  82     map/ownlocationitem.h \
  83     network/networkaccessmanager.h \
  84     network/networkcookiejar.h \
  85     network/networkhandler.h \
  86     network/networkreply.h \
  87     situareservice/imagefetcher.h \
  88     situareservice/situarecommon.h \
  89     situareservice/situareservice.h \
  90     ui/updatelocation/texteditautoresizer.h \
  91     ui/updatelocation/updatelocationdialog.h \
  92     ui/avatarimage.h \
  93     ui/friendlistitem.h \
  94     ui/friendlistpanel.h \
  95     ui/imagebutton.h \
  96     ui/logindialog.h \
  97     ui/mainwindow.h \
  98     ui/mapscale.h \
  99     ui/panelcommon.h \
 100     ui/panelsidebar.h \
 101     ui/panelsliderbar.h \
 102     ui/settingsdialog.h \
 103     ui/userinfo.h \
 104     ui/userinfopanel.h \
 105     ui/sidepanel.h \
 106     ui/sidepanelbase.h \
 107     ui/zoombutton.h \
 108     ui/zoombuttonpanel.h \
 109     user/user.h \
 110     ui/fullscreenbutton.h \
 111     engine/mce.h \
 112     ui/listview.h \
 113     ui/listitem.h \
 114     ui/listitemdelegate.h \
 115     ui/friendlistitemdelegate.h \
 116     ui/listcommon.h
 117 QT += network \
 118     webkit
 119
 120 DEFINES += QT_NO_DEBUG_OUTPUT
 121
 122 simulator {
 123     SOURCES += network/networkhandlerprivatestub.cpp \
 124                gps/gpspositionprivate.cpp
 125     HEADERS += network/networkhandlerprivatestub.h \
 126                gps/gpspositionprivate.h
 127     QT += maemo5
 128     CONFIG += mobility
 129     MOBILITY += location
 130 } else:maemo5 {
 131     armel {
 132         DEFINES += ARMEL
 133         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 134         SOURCES += network/networkhandlerprivate.cpp \
 135                    engine/mceprivate.cpp
 136         HEADERS += network/networkhandlerprivate.h \
 137                    engine/mceprivate.h
 138         QT += dbus
 139         CONFIG += icd2 qdbus
 140         SOURCES += gps/gpspositionprivateliblocation.cpp \
 141                    gps/liblocationwrapper.cpp \
 142                    gps/geopositioninfo.cpp \
 143                    gps/geocoordinate.cpp
 144         HEADERS += gps/gpspositionprivateliblocation.h \
 145                    gps/liblocationwrapper.h \
 146                    gps/geopositioninfo.h \
 147                    gps/geocoordinate.h
 148         CONFIG += link_pkgconfig
 149         PKGCONFIG += glib-2.0 liblocation mce
 150         LIBS += -llocation
 151     } else {
 152         SOURCES += gps/gpspositionprivatestub.cpp \
 153                    network/networkhandlerprivatestub.cpp \
 154                    engine/mceprivatestub.cpp
 155         HEADERS += gps/gpspositionprivatestub.h \
 156                    network/networkhandlerprivatestub.h \
 157                    engine/mceprivatestub.h
 158     }
 159
 160     QT += maemo5
 161
 162     message([QJson])
 163     message(Make sure you have QJson development headers installed)
 164     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 165     message(to Scratchbox's sources.list in /etc/apt)
 166     message(run: apt-get update)
 167     message(install headers with: apt-get install libqjson-dev)
 168     message([QtMobility])
 169     message(Make sure you have QtMobility development headers installed)
 170     message(install headers with: apt-get install libqtm-dev)
 171 } else {
 172     SOURCES += gps/gpspositionprivatestub.cpp \
 173                network/networkhandlerprivatestub.cpp \
 174                engine/mceprivatestub.cpp
 175     HEADERS += gps/gpspositionprivatestub.h \
 176                network/networkhandlerprivatestub.h \
 177                engine/mceprivatestub.h
 178     message(QJson built in)
 179     message(Make sure you have QJson development headers installed)
 180     message(install headers with: sudo apt-get install libqjson-dev)
 181 }
 182
 183 # -----------------------------------------------------------------
 184 # Debian packetizing additions
 185 # -----------------------------------------------------------------
 186 unix {
 187     # VARIABLES
 188     isEmpty(PREFIX):PREFIX = /usr
 189     BINDIR = $$PREFIX/bin
 190     DATADIR = $$PREFIX/share
 191     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 192         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 193
 194     # MAKE INSTALL
 195     desktop.path = $$DATADIR/applications/hildon
 196     desktop.files += situare.desktop
 197     INSTALLS += desktop
 198     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 199     icon48.files += ../res/icon/48x48/situare.png
 200     INSTALLS += icon48
 201     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 202     icon64.files += ../res/icon/64x64/situare.png
 203     INSTALLS += icon64
 204     target.path = $$BINDIR
 205     INSTALLS += target
 206 }