vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     engine/engine.cpp \
  13     facebookservice/facebookauthentication.cpp \
  14     facebookservice/facebookcredentials.cpp \
  15     gps/gpsposition.cpp \
  16     map/baselocationitem.cpp \
  17     map/friendgroupitem.cpp \
  18     map/frienditemshandler.cpp \
  19     map/friendlocationitem.cpp \
  20     map/gpslocationitem.cpp \
  21     map/mapengine.cpp \
  22     map/mapfetcher.cpp \
  23     map/mapscene.cpp \
  24     map/mapscroller.cpp \
  25     map/maptile.cpp \
  26     map/maptilerequest.cpp \
  27     map/mapview.cpp \
  28     map/ownlocationitem.cpp \
  29     network/networkaccessmanager.cpp \
  30     network/networkcookiejar.cpp \
  31     network/networkhandler.cpp \
  32     network/networkreply.cpp \
  33     situareservice/imagefetcher.cpp \
  34     situareservice/situareservice.cpp \
  35     ui/updatelocation/texteditautoresizer.cpp \
  36     ui/updatelocation/updatelocationdialog.cpp \
  37     ui/avatarimage.cpp \
  38     ui/friendlistitem.cpp \
  39     ui/friendlistpanel.cpp \
  40     ui/friendlistview.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     ui/indicatorbutton.cpp
  58 HEADERS += common.h \
  59     engine/engine.h \
  60     facebookservice/facebookauthentication.h \
  61     facebookservice/facebookcommon.h \
  62     facebookservice/facebookcredentials.h \
  63     gps/gpscommon.h \
  64     gps/gpsposition.h \
  65     map/baselocationitem.h \
  66     map/friendgroupitem.h \
  67     map/frienditemshandler.h \
  68     map/friendlocationitem.h \
  69     map/gpslocationitem.h \
  70     map/mapcommon.h \
  71     map/mapengine.h \
  72     map/mapfetcher.h \
  73     map/mapscene.h \
  74     map/mapscroller.h \
  75     map/maptile.h \
  76     map/maptilerequest.h \
  77     map/mapview.h \
  78     map/ownlocationitem.h \
  79     network/networkaccessmanager.h \
  80     network/networkcookiejar.h \
  81     network/networkhandler.h \
  82     network/networkreply.h \
  83     situareservice/imagefetcher.h \
  84     situareservice/situarecommon.h \
  85     situareservice/situareservice.h \
  86     ui/updatelocation/texteditautoresizer.h \
  87     ui/updatelocation/updatelocationdialog.h \
  88     ui/avatarimage.h \
  89     ui/friendlistitem.h \
  90     ui/friendlistpanel.h \
  91     ui/friendlistview.h \
  92     ui/imagebutton.h \
  93     ui/logindialog.h \
  94     ui/mainwindow.h \
  95     ui/mapscale.h \
  96     ui/panelcommon.h \
  97     ui/panelsidebar.h \
  98     ui/panelsliderbar.h \
  99     ui/settingsdialog.h \
 100     ui/userinfo.h \
 101     ui/userinfopanel.h \
 102     ui/sidepanel.h \
 103     ui/sidepanelbase.h \
 104     ui/zoombutton.h \
 105     ui/zoombuttonpanel.h \
 106     user/user.h \
 107     ui/fullscreenbutton.h \
 108     engine/mce.h \
 109     ui/indicatorbutton.h
 110 QT += network \
 111     webkit
 112
 113 DEFINES += QT_NO_DEBUG_OUTPUT
 114
 115 simulator {
 116     SOURCES += network/networkhandlerprivatestub.cpp \
 117                gps/gpspositionprivate.cpp
 118     HEADERS += network/networkhandlerprivatestub.h \
 119                gps/gpspositionprivate.h
 120     QT += maemo5
 121     CONFIG += mobility
 122     MOBILITY += location
 123 } else:maemo5 {
 124     armel {
 125         DEFINES += ARMEL
 126         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 127         SOURCES += network/networkhandlerprivate.cpp \
 128                    engine/mceprivate.cpp
 129         HEADERS += network/networkhandlerprivate.h \
 130                    engine/mceprivate.h
 131         QT += dbus
 132         CONFIG += icd2 qdbus
 133         SOURCES += gps/gpspositionprivateliblocation.cpp \
 134                    gps/liblocationwrapper.cpp \
 135                    gps/geopositioninfo.cpp \
 136                    gps/geocoordinate.cpp
 137         HEADERS += gps/gpspositionprivateliblocation.h \
 138                    gps/liblocationwrapper.h \
 139                    gps/geopositioninfo.h \
 140                    gps/geocoordinate.h
 141         CONFIG += link_pkgconfig
 142         PKGCONFIG += glib-2.0 liblocation mce
 143         LIBS += -llocation
 144     } else {
 145         SOURCES += gps/gpspositionprivatestub.cpp \
 146                    network/networkhandlerprivatestub.cpp \
 147                    engine/mceprivatestub.cpp
 148         HEADERS += gps/gpspositionprivatestub.h \
 149                    network/networkhandlerprivatestub.h \
 150                    engine/mceprivatestub.h
 151     }
 152
 153     QT += maemo5
 154
 155     message([QJson])
 156     message(Make sure you have QJson development headers installed)
 157     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 158     message(to Scratchbox's sources.list in /etc/apt)
 159     message(run: apt-get update)
 160     message(install headers with: apt-get install libqjson-dev)
 161     message([QtMobility])
 162     message(Make sure you have QtMobility development headers installed)
 163     message(install headers with: apt-get install libqtm-dev)
 164 } else {
 165     SOURCES += gps/gpspositionprivatestub.cpp \
 166                network/networkhandlerprivatestub.cpp \
 167                engine/mceprivatestub.cpp
 168     HEADERS += gps/gpspositionprivatestub.h \
 169                network/networkhandlerprivatestub.h \
 170                engine/mceprivatestub.h
 171     message(QJson built in)
 172     message(Make sure you have QJson development headers installed)
 173     message(install headers with: sudo apt-get install libqjson-dev)
 174 }
 175
 176 # -----------------------------------------------------------------
 177 # Debian packetizing additions
 178 # -----------------------------------------------------------------
 179 unix {
 180     # VARIABLES
 181     isEmpty(PREFIX):PREFIX = /usr
 182     BINDIR = $$PREFIX/bin
 183     DATADIR = $$PREFIX/share
 184     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 185         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 186
 187     # MAKE INSTALL
 188     desktop.path = $$DATADIR/applications/hildon
 189     desktop.files += situare.desktop
 190     INSTALLS += desktop
 191     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 192     icon48.files += ../res/icon/48x48/situare.png
 193     INSTALLS += icon48
 194     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 195     icon64.files += ../res/icon/64x64/situare.png
 196     INSTALLS += icon64
 197     target.path = $$BINDIR
 198     INSTALLS += target
 199 }