vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/panelbar.cpp \
  74     ui/panelbase.cpp \
  75     ui/panelcontentstack.cpp \
  76     ui/panelcontextbuttonbar.cpp \
  77     ui/paneltab.cpp \
  78     ui/paneltabbar.cpp \
  79     ui/tabbedpanel.cpp \
  80     ui/routingpanel.cpp \
  81     ui/routewaypointlistitem.cpp \
  82     ui/routewaypointlistview.cpp \
  83     user/user.cpp
  84 HEADERS += application.h \
  85     common.h \
  86     coordinates/geocoordinate.h \
  87     coordinates/scenecoordinate.h \
  88     engine/engine.h \
  89     engine/mce.h \
  90     error.h \
  91     facebookservice/facebookauthentication.h \
  92     facebookservice/facebookcommon.h \
  93     facebookservice/facebookcredentials.h \
  94     gps/gpscommon.h \
  95     gps/gpsposition.h \
  96     map/baselocationitem.h \
  97     map/friendgroupitem.h \
  98     map/frienditemshandler.h \
  99     map/friendlocationitem.h \
 100     map/gpslocationitem.h \
 101     map/mapcommon.h \
 102     map/mapengine.h \
 103     map/mapfetcher.h \
 104     map/maprouteitem.h \
 105     map/mapscene.h \
 106     map/mapscroller.h \
 107     map/maptile.h \
 108     map/maptilerequest.h \
 109     map/mapview.h \
 110     map/osm.h \
 111     map/ownlocationitem.h \
 112     network/networkaccessmanager.h \
 113     network/networkcookiejar.h \
 114     network/networkhandler.h \
 115     network/networkreply.h \
 116     routing/geocodingservice.h \
 117     routing/location.h \
 118     routing/route.h \
 119     routing/routesegment.h \
 120     routing/routingcommon.h \
 121     routing/routingservice.h \
 122     situareservice/imagefetcher.h \
 123     situareservice/situarecommon.h \
 124     situareservice/situareservice.h \
 125     ui/updatelocation/texteditautoresizer.h \
 126     ui/updatelocation/updatelocationdialog.h \
 127     ui/avatarimage.h \
 128     ui/extendedlistitem.h \
 129     ui/extendedlistitemdelegate.h \
 130     ui/extendedlistitemstore.h \
 131     ui/friendlistitem.h \
 132     ui/friendlistitemdelegate.h \
 133     ui/friendlistpanel.h \
 134     ui/friendlistview.h \
 135     ui/fullscreenbutton.h \
 136     ui/imagebutton.h \
 137     ui/indicatorbutton.h \
 138     ui/indicatorbuttonpanel.h \
 139     ui/logindialog.h \
 140     ui/locationlistitem.h \
 141     ui/locationlistview.h \
 142     ui/mainwindow.h \
 143     ui/mapscale.h \
 144     ui/settingsdialog.h \
 145     ui/userinfo.h \
 146     ui/userinfopanel.h \
 147     ui/zoombutton.h \
 148     ui/zoombuttonpanel.h \
 149     ui/listcommon.h \
 150     ui/listview.h \
 151     ui/listitem.h \
 152     ui/listitemdelegate.h \
 153     ui/searchdialog.h \
 154     ui/panelbar.h \
 155     ui/panelbase.h \
 156     ui/panelcommon.h \
 157     ui/panelcontentstack.h \
 158     ui/panelcontextbuttonbar.h \
 159     ui/paneltab.h \
 160     ui/paneltabbar.h \
 161     ui/tabbedpanel.h \
 162     ui/routingpanel.h \
 163     ui/routewaypointlistitem.h \
 164     ui/routewaypointlistview.h \
 165     user/user.h
 166 QT += network \
 167     webkit
 168 DEFINES += QT_NO_DEBUG_OUTPUT
 169
 170 simulator {
 171     SOURCES += network/networkhandlerprivatestub.cpp \
 172                gps/gpspositionprivate.cpp
 173     HEADERS += network/networkhandlerprivatestub.h \
 174                gps/gpspositionprivate.h
 175     QT += maemo5
 176     CONFIG += mobility
 177     MOBILITY += location
 178 } else:maemo5 {
 179     armel {
 180         DEFINES += ARMEL
 181         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 182         SOURCES += network/networkhandlerprivate.cpp \
 183                    engine/mceprivate.cpp
 184         HEADERS += network/networkhandlerprivate.h \
 185                    engine/mceprivate.h
 186         QT += dbus xml
 187         CONFIG += icd2 qdbus
 188         SOURCES += gps/gpspositionprivateliblocation.cpp \
 189                    gps/liblocationwrapper.cpp \
 190                    gps/geopositioninfo.cpp
 191         HEADERS += gps/gpspositionprivateliblocation.h \
 192                    gps/liblocationwrapper.h \
 193                    gps/geopositioninfo.h
 194         CONFIG += link_pkgconfig
 195         PKGCONFIG += glib-2.0 liblocation mce
 196         LIBS += -llocation
 197     } else {
 198         SOURCES += gps/gpspositionprivatestub.cpp \
 199                    network/networkhandlerprivatestub.cpp \
 200                    engine/mceprivatestub.cpp
 201         HEADERS += gps/gpspositionprivatestub.h \
 202                    network/networkhandlerprivatestub.h \
 203                    engine/mceprivatestub.h
 204     }
 205
 206     QT += maemo5
 207
 208     message([QJson])
 209     message(Make sure you have QJson development headers installed)
 210     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 211     message(to Scratchbox's sources.list in /etc/apt)
 212     message(run: apt-get update)
 213     message(install headers with: apt-get install libqjson-dev)
 214     message([QtMobility])
 215     message(Make sure you have QtMobility development headers installed)
 216     message(install headers with: apt-get install libqtm-dev)
 217 } else {
 218     SOURCES += gps/gpspositionprivatestub.cpp \
 219                network/networkhandlerprivatestub.cpp \
 220                engine/mceprivatestub.cpp
 221     HEADERS += gps/gpspositionprivatestub.h \
 222                network/networkhandlerprivatestub.h \
 223                engine/mceprivatestub.h
 224     message(QJson built in)
 225     message(Make sure you have QJson development headers installed)
 226     message(install headers with: sudo apt-get install libqjson-dev)
 227 }
 228
 229 # -----------------------------------------------------------------
 230 # Debian packetizing additions
 231 # -----------------------------------------------------------------
 232 unix {
 233     # VARIABLES
 234     isEmpty(PREFIX):PREFIX = /usr
 235     BINDIR = $$PREFIX/bin
 236     DATADIR = $$PREFIX/share
 237     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 238         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 239
 240     # MAKE INSTALL
 241     desktop.path = $$DATADIR/applications/hildon
 242     desktop.files += situare.desktop
 243     INSTALLS += desktop
 244     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 245     icon48.files += ../res/icon/48x48/situare.png
 246     INSTALLS += icon48
 247     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 248     icon64.files += ../res/icon/64x64/situare.png
 249     INSTALLS += icon64
 250     target.path = $$BINDIR
 251     INSTALLS += target
 252 }