vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     engine/engine.cpp \
  13     facebookservice/facebookauthentication.cpp \
  14     facebookservice/facebookcredentials.cpp \
  15     gps/gpsposition.cpp \
  16     map/baselocationitem.cpp \
  17     map/friendgroupitem.cpp \
  18     map/frienditemshandler.cpp \
  19     map/friendlocationitem.cpp \
  20     map/gpslocationitem.cpp \
  21     map/mapengine.cpp \
  22     map/mapfetcher.cpp \
  23     map/mapscene.cpp \
  24     map/mapscroller.cpp \
  25     map/maptile.cpp \
  26     map/maptilerequest.cpp \
  27     map/mapview.cpp \
  28     map/ownlocationitem.cpp \
  29     network/networkaccessmanager.cpp \
  30     network/networkcookiejar.cpp \
  31     network/networkhandler.cpp \
  32     network/networkreply.cpp \
  33     situareservice/imagefetcher.cpp \
  34     situareservice/situareservice.cpp \
  35     ui/updatelocation/texteditautoresizer.cpp \
  36     ui/updatelocation/updatelocationdialog.cpp \
  37     ui/avatarimage.cpp \
  38     ui/friendlistitem.cpp \
  39     ui/friendlistpanel.cpp \
  40     ui/friendlistview.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp
  57 HEADERS += common.h \
  58     engine/engine.h \
  59     facebookservice/facebookauthentication.h \
  60     facebookservice/facebookcommon.h \
  61     facebookservice/facebookcredentials.h \
  62     gps/gpscommon.h \
  63     gps/gpsposition.h \
  64     map/baselocationitem.h \
  65     map/friendgroupitem.h \
  66     map/frienditemshandler.h \
  67     map/friendlocationitem.h \
  68     map/gpslocationitem.h \
  69     map/mapcommon.h \
  70     map/mapengine.h \
  71     map/mapfetcher.h \
  72     map/mapscene.h \
  73     map/mapscroller.h \
  74     map/maptile.h \
  75     map/maptilerequest.h \
  76     map/mapview.h \
  77     map/ownlocationitem.h \
  78     network/networkaccessmanager.h \
  79     network/networkcookiejar.h \
  80     network/networkhandler.h \
  81     network/networkreply.h \
  82     situareservice/imagefetcher.h \
  83     situareservice/situarecommon.h \
  84     situareservice/situareservice.h \
  85     ui/updatelocation/texteditautoresizer.h \
  86     ui/updatelocation/updatelocationdialog.h \
  87     ui/avatarimage.h \
  88     ui/friendlistitem.h \
  89     ui/friendlistpanel.h \
  90     ui/friendlistview.h \
  91     ui/imagebutton.h \
  92     ui/logindialog.h \
  93     ui/mainwindow.h \
  94     ui/mapscale.h \
  95     ui/panelcommon.h \
  96     ui/panelsidebar.h \
  97     ui/panelsliderbar.h \
  98     ui/settingsdialog.h \
  99     ui/userinfo.h \
 100     ui/userinfopanel.h \
 101     ui/sidepanel.h \
 102     ui/sidepanelbase.h \
 103     ui/zoombutton.h \
 104     ui/zoombuttonpanel.h \
 105     user/user.h \
 106     ui/fullscreenbutton.h \
 107     engine/mce.h
 108 QT += network \
 109     webkit
 110
 111 DEFINES += QT_NO_DEBUG_OUTPUT
 112
 113 simulator {
 114     SOURCES += network/networkhandlerprivatestub.cpp \
 115                gps/gpspositionprivate.cpp
 116     HEADERS += network/networkhandlerprivatestub.h \
 117                gps/gpspositionprivate.h
 118     QT += maemo5
 119     CONFIG += mobility
 120     MOBILITY += location
 121 } else:maemo5 {
 122     armel {
 123         DEFINES += ARMEL
 124         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 125         SOURCES += network/networkhandlerprivate.cpp \
 126                    engine/mceprivate.cpp
 127         HEADERS += network/networkhandlerprivate.h \
 128                    engine/mceprivate.h
 129         QT += dbus
 130         CONFIG += icd2 qdbus
 131         SOURCES += gps/gpspositionprivateliblocation.cpp \
 132                    gps/liblocationwrapper.cpp \
 133                    gps/geopositioninfo.cpp \
 134                    gps/geocoordinate.cpp
 135         HEADERS += gps/gpspositionprivateliblocation.h \
 136                    gps/liblocationwrapper.h \
 137                    gps/geopositioninfo.h \
 138                    gps/geocoordinate.h
 139         CONFIG += link_pkgconfig
 140         PKGCONFIG += glib-2.0 liblocation mce
 141         LIBS += -llocation
 142     } else {
 143         SOURCES += gps/gpspositionprivatestub.cpp \
 144                    network/networkhandlerprivatestub.cpp \
 145                    engine/mceprivatestub.cpp
 146         HEADERS += gps/gpspositionprivatestub.h \
 147                    network/networkhandlerprivatestub.h \
 148                    engine/mceprivatestub.h
 149     }
 150
 151     QT += maemo5
 152
 153     message([QJson])
 154     message(Make sure you have QJson development headers installed)
 155     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 156     message(to Scratchbox's sources.list in /etc/apt)
 157     message(run: apt-get update)
 158     message(install headers with: apt-get install libqjson-dev)
 159     message([QtMobility])
 160     message(Make sure you have QtMobility development headers installed)
 161     message(install headers with: apt-get install libqtm-dev)
 162 } else {
 163     SOURCES += gps/gpspositionprivatestub.cpp \
 164                network/networkhandlerprivatestub.cpp \
 165                engine/mceprivatestub.cpp
 166     HEADERS += gps/gpspositionprivatestub.h \
 167                network/networkhandlerprivatestub.h \
 168                engine/mceprivatestub.h
 169     message(QJson built in)
 170     message(Make sure you have QJson development headers installed)
 171     message(install headers with: sudo apt-get install libqjson-dev)
 172 }
 173
 174 # -----------------------------------------------------------------
 175 # Debian packetizing additions
 176 # -----------------------------------------------------------------
 177 unix {
 178     # VARIABLES
 179     isEmpty(PREFIX):PREFIX = /usr
 180     BINDIR = $$PREFIX/bin
 181     DATADIR = $$PREFIX/share
 182     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 183         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 184
 185     # MAKE INSTALL
 186     desktop.path = $$DATADIR/applications/hildon
 187     desktop.files += situare.desktop
 188     INSTALLS += desktop
 189     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 190     icon48.files += ../res/icon/48x48/situare.png
 191     INSTALLS += icon48
 192     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 193     icon64.files += ../res/icon/64x64/situare.png
 194     INSTALLS += icon64
 195     target.path = $$BINDIR
 196     INSTALLS += target
 197 }