vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     ui/indicatorbutton.cpp \
  58     routing/routingservice.cpp \
  59     routing/routesegment.cpp \
  60     routing/route.cpp \
  61     routing/location.cpp \
  62     map/maprouteitem.cpp \
  63     coordinates/scenecoordinate.cpp \
  64     coordinates/geocoordinate.cpp \
  65     ui/listview.cpp \
  66     ui/listitem.cpp \
  67     ui/listitemdelegate.cpp \
  68     ui/friendlistitemdelegate.cpp \
  69     ui/searchdialog.cpp \
  70     ui/locationlistitem.cpp \
  71     ui/extendedlistitem.cpp \
  72     ui/extendedlistitemstore.cpp \
  73     ui/extendedlistitemdelegate.cpp \
  74     ui/locationlistview.cpp \
  75     ui/friendlistview.cpp
  76 HEADERS += application.h \
  77     common.h \
  78     engine/engine.h \
  79     facebookservice/facebookauthentication.h \
  80     facebookservice/facebookcommon.h \
  81     facebookservice/facebookcredentials.h \
  82     gps/gpscommon.h \
  83     gps/gpsposition.h \
  84     map/baselocationitem.h \
  85     map/friendgroupitem.h \
  86     map/frienditemshandler.h \
  87     map/friendlocationitem.h \
  88     map/gpslocationitem.h \
  89     map/mapcommon.h \
  90     map/mapengine.h \
  91     map/mapfetcher.h \
  92     map/mapscene.h \
  93     map/mapscroller.h \
  94     map/maptile.h \
  95     map/maptilerequest.h \
  96     map/mapview.h \
  97     map/ownlocationitem.h \
  98     network/networkaccessmanager.h \
  99     network/networkcookiejar.h \
 100     network/networkhandler.h \
 101     network/networkreply.h \
 102     situareservice/imagefetcher.h \
 103     situareservice/situarecommon.h \
 104     situareservice/situareservice.h \
 105     ui/updatelocation/texteditautoresizer.h \
 106     ui/updatelocation/updatelocationdialog.h \
 107     ui/avatarimage.h \
 108     ui/friendlistitem.h \
 109     ui/friendlistpanel.h \
 110     ui/imagebutton.h \
 111     ui/logindialog.h \
 112     ui/mainwindow.h \
 113     ui/mapscale.h \
 114     ui/panelcommon.h \
 115     ui/panelsidebar.h \
 116     ui/panelsliderbar.h \
 117     ui/settingsdialog.h \
 118     ui/userinfo.h \
 119     ui/userinfopanel.h \
 120     ui/sidepanel.h \
 121     ui/sidepanelbase.h \
 122     ui/zoombutton.h \
 123     ui/zoombuttonpanel.h \
 124     user/user.h \
 125     ui/fullscreenbutton.h \
 126     engine/mce.h \
 127     ui/indicatorbutton.h \
 128     routing/routingservice.h \
 129     routing/routingcommon.h \
 130     routing/routesegment.h \
 131     routing/route.h \
 132     routing/location.h \
 133     map/maprouteitem.h \
 134     map/osm.h \
 135     coordinates/scenecoordinate.h \
 136     coordinates/geocoordinate.h \
 137     ui/listview.h \
 138     ui/listitem.h \
 139     ui/listitemdelegate.h \
 140     ui/friendlistitemdelegate.h \
 141     ui/listcommon.h \
 142     ui/searchdialog.h \
 143     ui/locationlistitem.h \
 144     ui/extendedlistitem.h \
 145     ui/extendedlistitemstore.h \
 146     ui/extendedlistitemdelegate.h \
 147     ui/locationlistview.h \
 148     ui/friendlistview.h
 149 QT += network \
 150     webkit
 151
 152 DEFINES += QT_NO_DEBUG_OUTPUT
 153
 154 simulator {
 155     SOURCES += network/networkhandlerprivatestub.cpp \
 156                gps/gpspositionprivate.cpp
 157     HEADERS += network/networkhandlerprivatestub.h \
 158                gps/gpspositionprivate.h
 159     QT += maemo5
 160     CONFIG += mobility
 161     MOBILITY += location
 162 } else:maemo5 {
 163     armel {
 164         DEFINES += ARMEL
 165         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 166         SOURCES += network/networkhandlerprivate.cpp \
 167                    engine/mceprivate.cpp
 168         HEADERS += network/networkhandlerprivate.h \
 169                    engine/mceprivate.h
 170         QT += dbus xml
 171         CONFIG += icd2 qdbus
 172         SOURCES += gps/gpspositionprivateliblocation.cpp \
 173                    gps/liblocationwrapper.cpp \
 174                    gps/geopositioninfo.cpp
 175         HEADERS += gps/gpspositionprivateliblocation.h \
 176                    gps/liblocationwrapper.h \
 177                    gps/geopositioninfo.h
 178         CONFIG += link_pkgconfig
 179         PKGCONFIG += glib-2.0 liblocation mce
 180         LIBS += -llocation
 181     } else {
 182         SOURCES += gps/gpspositionprivatestub.cpp \
 183                    network/networkhandlerprivatestub.cpp \
 184                    engine/mceprivatestub.cpp
 185         HEADERS += gps/gpspositionprivatestub.h \
 186                    network/networkhandlerprivatestub.h \
 187                    engine/mceprivatestub.h
 188     }
 189
 190     QT += maemo5
 191
 192     message([QJson])
 193     message(Make sure you have QJson development headers installed)
 194     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 195     message(to Scratchbox's sources.list in /etc/apt)
 196     message(run: apt-get update)
 197     message(install headers with: apt-get install libqjson-dev)
 198     message([QtMobility])
 199     message(Make sure you have QtMobility development headers installed)
 200     message(install headers with: apt-get install libqtm-dev)
 201 } else {
 202     SOURCES += gps/gpspositionprivatestub.cpp \
 203                network/networkhandlerprivatestub.cpp \
 204                engine/mceprivatestub.cpp
 205     HEADERS += gps/gpspositionprivatestub.h \
 206                network/networkhandlerprivatestub.h \
 207                engine/mceprivatestub.h
 208     message(QJson built in)
 209     message(Make sure you have QJson development headers installed)
 210     message(install headers with: sudo apt-get install libqjson-dev)
 211 }
 212
 213 # -----------------------------------------------------------------
 214 # Debian packetizing additions
 215 # -----------------------------------------------------------------
 216 unix {
 217     # VARIABLES
 218     isEmpty(PREFIX):PREFIX = /usr
 219     BINDIR = $$PREFIX/bin
 220     DATADIR = $$PREFIX/share
 221     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 222         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 223
 224     # MAKE INSTALL
 225     desktop.path = $$DATADIR/applications/hildon
 226     desktop.files += situare.desktop
 227     INSTALLS += desktop
 228     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 229     icon48.files += ../res/icon/48x48/situare.png
 230     INSTALLS += icon48
 231     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 232     icon64.files += ../res/icon/64x64/situare.png
 233     INSTALLS += icon64
 234     target.path = $$BINDIR
 235     INSTALLS += target
 236 }