vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     coordinates/scenecoordinate.cpp \
  58     coordinates/geocoordinate.cpp \
  59     ui/listview.cpp \
  60     ui/listitem.cpp \
  61     ui/listitemdelegate.cpp \
  62     ui/friendlistitemdelegate.cpp
  63 HEADERS += application.h \
  64     common.h \
  65     engine/engine.h \
  66     facebookservice/facebookauthentication.h \
  67     facebookservice/facebookcommon.h \
  68     facebookservice/facebookcredentials.h \
  69     gps/gpscommon.h \
  70     gps/gpsposition.h \
  71     map/baselocationitem.h \
  72     map/friendgroupitem.h \
  73     map/frienditemshandler.h \
  74     map/friendlocationitem.h \
  75     map/gpslocationitem.h \
  76     map/mapcommon.h \
  77     map/mapengine.h \
  78     map/mapfetcher.h \
  79     map/mapscene.h \
  80     map/mapscroller.h \
  81     map/maptile.h \
  82     map/maptilerequest.h \
  83     map/mapview.h \
  84     map/ownlocationitem.h \
  85     network/networkaccessmanager.h \
  86     network/networkcookiejar.h \
  87     network/networkhandler.h \
  88     network/networkreply.h \
  89     situareservice/imagefetcher.h \
  90     situareservice/situarecommon.h \
  91     situareservice/situareservice.h \
  92     ui/updatelocation/texteditautoresizer.h \
  93     ui/updatelocation/updatelocationdialog.h \
  94     ui/avatarimage.h \
  95     ui/friendlistitem.h \
  96     ui/friendlistpanel.h \
  97     ui/imagebutton.h \
  98     ui/logindialog.h \
  99     ui/mainwindow.h \
 100     ui/mapscale.h \
 101     ui/panelcommon.h \
 102     ui/panelsidebar.h \
 103     ui/panelsliderbar.h \
 104     ui/settingsdialog.h \
 105     ui/userinfo.h \
 106     ui/userinfopanel.h \
 107     ui/sidepanel.h \
 108     ui/sidepanelbase.h \
 109     ui/zoombutton.h \
 110     ui/zoombuttonpanel.h \
 111     user/user.h \
 112     ui/fullscreenbutton.h \
 113     engine/mce.h \
 114     map/osm.h \
 115     coordinates/scenecoordinate.h \
 116     coordinates/geocoordinate.h \
 117     ui/listview.h \
 118     ui/listitem.h \
 119     ui/listitemdelegate.h \
 120     ui/friendlistitemdelegate.h \
 121     ui/listcommon.h
 122 QT += network \
 123     webkit
 124
 125 #DEFINES += QT_NO_DEBUG_OUTPUT
 126
 127 simulator {
 128     SOURCES += network/networkhandlerprivatestub.cpp \
 129                gps/gpspositionprivate.cpp
 130     HEADERS += network/networkhandlerprivatestub.h \
 131                gps/gpspositionprivate.h
 132     QT += maemo5
 133     CONFIG += mobility
 134     MOBILITY += location
 135 } else:maemo5 {
 136     armel {
 137         DEFINES += ARMEL
 138         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 139         SOURCES += network/networkhandlerprivate.cpp \
 140                    engine/mceprivate.cpp
 141         HEADERS += network/networkhandlerprivate.h \
 142                    engine/mceprivate.h
 143         QT += dbus
 144         CONFIG += icd2 qdbus
 145         SOURCES += gps/gpspositionprivateliblocation.cpp \
 146                    gps/liblocationwrapper.cpp \
 147                    gps/geopositioninfo.cpp
 148         HEADERS += gps/gpspositionprivateliblocation.h \
 149                    gps/liblocationwrapper.h \
 150                    gps/geopositioninfo.h
 151         CONFIG += link_pkgconfig
 152         PKGCONFIG += glib-2.0 liblocation mce
 153         LIBS += -llocation
 154     } else {
 155         SOURCES += gps/gpspositionprivatestub.cpp \
 156                    network/networkhandlerprivatestub.cpp \
 157                    engine/mceprivatestub.cpp
 158         HEADERS += gps/gpspositionprivatestub.h \
 159                    network/networkhandlerprivatestub.h \
 160                    engine/mceprivatestub.h
 161     }
 162
 163     QT += maemo5
 164
 165     message([QJson])
 166     message(Make sure you have QJson development headers installed)
 167     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 168     message(to Scratchbox's sources.list in /etc/apt)
 169     message(run: apt-get update)
 170     message(install headers with: apt-get install libqjson-dev)
 171     message([QtMobility])
 172     message(Make sure you have QtMobility development headers installed)
 173     message(install headers with: apt-get install libqtm-dev)
 174 } else {
 175     SOURCES += gps/gpspositionprivatestub.cpp \
 176                network/networkhandlerprivatestub.cpp \
 177                engine/mceprivatestub.cpp
 178     HEADERS += gps/gpspositionprivatestub.h \
 179                network/networkhandlerprivatestub.h \
 180                engine/mceprivatestub.h
 181     message(QJson built in)
 182     message(Make sure you have QJson development headers installed)
 183     message(install headers with: sudo apt-get install libqjson-dev)
 184 }
 185
 186 # -----------------------------------------------------------------
 187 # Debian packetizing additions
 188 # -----------------------------------------------------------------
 189 unix {
 190     # VARIABLES
 191     isEmpty(PREFIX):PREFIX = /usr
 192     BINDIR = $$PREFIX/bin
 193     DATADIR = $$PREFIX/share
 194     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 195         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 196
 197     # MAKE INSTALL
 198     desktop.path = $$DATADIR/applications/hildon
 199     desktop.files += situare.desktop
 200     INSTALLS += desktop
 201     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 202     icon48.files += ../res/icon/48x48/situare.png
 203     INSTALLS += icon48
 204     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 205     icon64.files += ../res/icon/64x64/situare.png
 206     INSTALLS += icon64
 207     target.path = $$BINDIR
 208     INSTALLS += target
 209 }