vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     engine/engine.cpp \
  13     facebookservice/facebookauthentication.cpp \
  14     facebookservice/facebookcredentials.cpp \
  15     gps/gpsposition.cpp \
  16     map/baselocationitem.cpp \
  17     map/friendgroupitem.cpp \
  18     map/frienditemshandler.cpp \
  19     map/friendlocationitem.cpp \
  20     map/gpslocationitem.cpp \
  21     map/mapengine.cpp \
  22     map/mapfetcher.cpp \
  23     map/mapscene.cpp \
  24     map/maptile.cpp \
  25     map/maptilerequest.cpp \
  26     map/mapview.cpp \
  27     map/ownlocationitem.cpp \
  28     network/networkaccessmanager.cpp \
  29     network/networkcookiejar.cpp \
  30     network/networkhandler.cpp \
  31     network/networkreply.cpp \
  32     situareservice/imagefetcher.cpp \
  33     situareservice/situareservice.cpp \
  34     ui/updatelocation/texteditautoresizer.cpp \
  35     ui/updatelocation/updatelocationdialog.cpp \
  36     ui/avatarimage.cpp \
  37     ui/friendlistitem.cpp \
  38     ui/friendlistpanel.cpp \
  39     ui/friendlistview.cpp \
  40     ui/imagebutton.cpp \
  41     ui/logindialog.cpp \
  42     ui/mainwindow.cpp \
  43     ui/mapscale.cpp \
  44     ui/panelsidebar.cpp \
  45     ui/panelsliderbar.cpp \
  46     ui/settingsdialog.cpp \
  47     ui/sidepanel.cpp \
  48     ui/sidepanelbase.cpp \
  49     ui/userinfo.cpp \
  50     ui/userinfopanel.cpp \
  51     ui/zoombutton.cpp \
  52     ui/zoombuttonpanel.cpp \
  53     user/user.cpp \
  54     map/mapscroller.cpp \
  55     ui/fullscreenbutton.cpp
  56 HEADERS += common.h \
  57     engine/engine.h \
  58     facebookservice/facebookauthentication.h \
  59     facebookservice/facebookcommon.h \
  60     facebookservice/facebookcredentials.h \
  61     gps/gpscommon.h \
  62     gps/gpsposition.h \
  63     map/baselocationitem.h \
  64     map/friendgroupitem.h \
  65     map/frienditemshandler.h \
  66     map/friendlocationitem.h \
  67     map/gpslocationitem.h \
  68     map/mapcommon.h \
  69     map/mapengine.h \
  70     map/mapfetcher.h \
  71     map/mapscene.h \
  72     map/maptile.h \
  73     map/maptilerequest.h \
  74     map/mapview.h \
  75     map/ownlocationitem.h \
  76     network/networkaccessmanager.h \
  77     network/networkcookiejar.h \
  78     network/networkhandler.h \
  79     network/networkreply.h \
  80     situareservice/imagefetcher.h \
  81     situareservice/situarecommon.h \
  82     situareservice/situareservice.h \
  83     ui/updatelocation/texteditautoresizer.h \
  84     ui/updatelocation/updatelocationdialog.h \
  85     ui/avatarimage.h \
  86     ui/friendlistitem.h \
  87     ui/friendlistpanel.h \
  88     ui/friendlistview.h \
  89     ui/imagebutton.h \
  90     ui/logindialog.h \
  91     ui/mainwindow.h \
  92     ui/mapscale.h \
  93     ui/panelcommon.h \
  94     ui/panelsidebar.h \
  95     ui/panelsliderbar.h \
  96     ui/settingsdialog.h \
  97     ui/userinfo.h \
  98     ui/userinfopanel.h \
  99     ui/sidepanel.h \
 100     ui/sidepanelbase.h \
 101     ui/zoombutton.h \
 102     ui/zoombuttonpanel.h \
 103     user/user.h \
 104     map/mapscroller.h \
 105     ui/fullscreenbutton.h
 106 QT += network \
 107     webkit
 108 DEFINES += QT_NO_DEBUG_OUTPUT
 109
 110 simulator {
 111     SOURCES += network/networkhandlerprivatestub.cpp \
 112                gps/gpspositionprivate.cpp
 113     HEADERS += network/networkhandlerprivatestub.h \
 114                gps/gpspositionprivate.h
 115     QT += maemo5
 116     CONFIG += mobility
 117     MOBILITY += location
 118 } else:maemo5 {
 119     armel {
 120         DEFINES += ARMEL
 121         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 122         SOURCES += network/networkhandlerprivate.cpp
 123         HEADERS += network/networkhandlerprivate.h
 124         QT += dbus
 125         CONFIG += icd2
 126 #        SOURCES += gps/gpspositionprivateliblocation.cpp \
 127 #                   gps/liblocationwrapper.cpp \
 128 #                   gps/geopositioninfo.cpp \
 129 #                   gps/geocoordinate.cpp
 130 #        HEADERS += gps/gpspositionprivateliblocation.h \
 131 #                   gps/liblocationwrapper.h \
 132 #                   gps/geopositioninfo.h \
 133 #                   gps/geocoordinate.h
 134 #        CONFIG += link_pkgconfig
 135 #        PKGCONFIG += glib-2.0 liblocation
 136         SOURCES += gps/gpspositionprivatestub.cpp
 137         HEADERS += gps/gpspositionprivatestub.h
 138     } else {
 139         SOURCES += gps/gpspositionprivatestub.cpp \
 140                    network/networkhandlerprivatestub.cpp
 141         HEADERS += gps/gpspositionprivatestub.h \
 142                    network/networkhandlerprivatestub.h
 143     }
 144
 145     QT += maemo5
 146
 147     message([QJson])
 148     message(Make sure you have QJson development headers installed)
 149     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 150     message(to Scratchbox's sources.list in /etc/apt)
 151     message(run: apt-get update)
 152     message(install headers with: apt-get install libqjson-dev)
 153     message([QtMobility])
 154     message(Make sure you have QtMobility development headers installed)
 155     message(install headers with: apt-get install libqtm-dev)
 156 } else {
 157     SOURCES += gps/gpspositionprivatestub.cpp \
 158                network/networkhandlerprivatestub.cpp
 159     HEADERS += gps/gpspositionprivatestub.h \
 160                network/networkhandlerprivatestub.h
 161     message(QJson built in)
 162     message(Make sure you have QJson development headers installed)
 163     message(install headers with: sudo apt-get install libqjson-dev)
 164 }
 165
 166 # -----------------------------------------------------------------
 167 # Debian packetizing additions
 168 # -----------------------------------------------------------------
 169 unix {
 170     # VARIABLES
 171     isEmpty(PREFIX):PREFIX = /usr
 172     BINDIR = $$PREFIX/bin
 173     DATADIR = $$PREFIX/share
 174     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 175         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 176
 177     # MAKE INSTALL
 178     desktop.path = $$DATADIR/applications/hildon
 179     desktop.files += situare.desktop
 180     INSTALLS += desktop
 181     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 182     icon48.files += ../res/icon/48x48/situare.png
 183     INSTALLS += icon48
 184     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 185     icon64.files += ../res/icon/64x64/situare.png
 186     INSTALLS += icon64
 187     target.path = $$BINDIR
 188     INSTALLS += target
 189 }