vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     ui/indicatorbutton.cpp \
  58     routing/routingservice.cpp \
  59     routing/routesegment.cpp \
  60     routing/route.cpp \
  61     routing/location.cpp \
  62     map/maprouteitem.cpp \
  63     coordinates/scenecoordinate.cpp \
  64     coordinates/geocoordinate.cpp \
  65     ui/listview.cpp \
  66     ui/listitem.cpp \
  67     ui/listitemdelegate.cpp \
  68     ui/friendlistitemdelegate.cpp \
  69     ui/searchdialog.cpp
  70 HEADERS += application.h \
  71     common.h \
  72     engine/engine.h \
  73     facebookservice/facebookauthentication.h \
  74     facebookservice/facebookcommon.h \
  75     facebookservice/facebookcredentials.h \
  76     gps/gpscommon.h \
  77     gps/gpsposition.h \
  78     map/baselocationitem.h \
  79     map/friendgroupitem.h \
  80     map/frienditemshandler.h \
  81     map/friendlocationitem.h \
  82     map/gpslocationitem.h \
  83     map/mapcommon.h \
  84     map/mapengine.h \
  85     map/mapfetcher.h \
  86     map/mapscene.h \
  87     map/mapscroller.h \
  88     map/maptile.h \
  89     map/maptilerequest.h \
  90     map/mapview.h \
  91     map/ownlocationitem.h \
  92     network/networkaccessmanager.h \
  93     network/networkcookiejar.h \
  94     network/networkhandler.h \
  95     network/networkreply.h \
  96     situareservice/imagefetcher.h \
  97     situareservice/situarecommon.h \
  98     situareservice/situareservice.h \
  99     ui/updatelocation/texteditautoresizer.h \
 100     ui/updatelocation/updatelocationdialog.h \
 101     ui/avatarimage.h \
 102     ui/friendlistitem.h \
 103     ui/friendlistpanel.h \
 104     ui/imagebutton.h \
 105     ui/logindialog.h \
 106     ui/mainwindow.h \
 107     ui/mapscale.h \
 108     ui/panelcommon.h \
 109     ui/panelsidebar.h \
 110     ui/panelsliderbar.h \
 111     ui/settingsdialog.h \
 112     ui/userinfo.h \
 113     ui/userinfopanel.h \
 114     ui/sidepanel.h \
 115     ui/sidepanelbase.h \
 116     ui/zoombutton.h \
 117     ui/zoombuttonpanel.h \
 118     user/user.h \
 119     ui/fullscreenbutton.h \
 120     engine/mce.h \
 121     ui/indicatorbutton.h \
 122     routing/routingservice.h \
 123     routing/routingcommon.h \
 124     routing/routesegment.h \
 125     routing/route.h \
 126     routing/location.h \
 127     map/maprouteitem.h \
 128     map/osm.h \
 129     coordinates/scenecoordinate.h \
 130     coordinates/geocoordinate.h \
 131     ui/listview.h \
 132     ui/listitem.h \
 133     ui/listitemdelegate.h \
 134     ui/friendlistitemdelegate.h \
 135     ui/listcommon.h \
 136     ui/searchdialog.h \
 137     error.h
 138 QT += network \
 139     webkit
 140
 141 DEFINES += QT_NO_DEBUG_OUTPUT
 142
 143 simulator {
 144     SOURCES += network/networkhandlerprivatestub.cpp \
 145                gps/gpspositionprivate.cpp
 146     HEADERS += network/networkhandlerprivatestub.h \
 147                gps/gpspositionprivate.h
 148     QT += maemo5
 149     CONFIG += mobility
 150     MOBILITY += location
 151 } else:maemo5 {
 152     armel {
 153         DEFINES += ARMEL
 154         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 155         SOURCES += network/networkhandlerprivate.cpp \
 156                    engine/mceprivate.cpp
 157         HEADERS += network/networkhandlerprivate.h \
 158                    engine/mceprivate.h
 159         QT += dbus xml
 160         CONFIG += icd2 qdbus
 161         SOURCES += gps/gpspositionprivateliblocation.cpp \
 162                    gps/liblocationwrapper.cpp \
 163                    gps/geopositioninfo.cpp
 164         HEADERS += gps/gpspositionprivateliblocation.h \
 165                    gps/liblocationwrapper.h \
 166                    gps/geopositioninfo.h
 167         CONFIG += link_pkgconfig
 168         PKGCONFIG += glib-2.0 liblocation mce
 169         LIBS += -llocation
 170     } else {
 171         SOURCES += gps/gpspositionprivatestub.cpp \
 172                    network/networkhandlerprivatestub.cpp \
 173                    engine/mceprivatestub.cpp
 174         HEADERS += gps/gpspositionprivatestub.h \
 175                    network/networkhandlerprivatestub.h \
 176                    engine/mceprivatestub.h
 177     }
 178
 179     QT += maemo5
 180
 181     message([QJson])
 182     message(Make sure you have QJson development headers installed)
 183     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 184     message(to Scratchbox's sources.list in /etc/apt)
 185     message(run: apt-get update)
 186     message(install headers with: apt-get install libqjson-dev)
 187     message([QtMobility])
 188     message(Make sure you have QtMobility development headers installed)
 189     message(install headers with: apt-get install libqtm-dev)
 190 } else {
 191     SOURCES += gps/gpspositionprivatestub.cpp \
 192                network/networkhandlerprivatestub.cpp \
 193                engine/mceprivatestub.cpp
 194     HEADERS += gps/gpspositionprivatestub.h \
 195                network/networkhandlerprivatestub.h \
 196                engine/mceprivatestub.h
 197     message(QJson built in)
 198     message(Make sure you have QJson development headers installed)
 199     message(install headers with: sudo apt-get install libqjson-dev)
 200 }
 201
 202 # -----------------------------------------------------------------
 203 # Debian packetizing additions
 204 # -----------------------------------------------------------------
 205 unix {
 206     # VARIABLES
 207     isEmpty(PREFIX):PREFIX = /usr
 208     BINDIR = $$PREFIX/bin
 209     DATADIR = $$PREFIX/share
 210     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 211         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 212
 213     # MAKE INSTALL
 214     desktop.path = $$DATADIR/applications/hildon
 215     desktop.files += situare.desktop
 216     INSTALLS += desktop
 217     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 218     icon48.files += ../res/icon/48x48/situare.png
 219     INSTALLS += icon48
 220     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 221     icon64.files += ../res/icon/64x64/situare.png
 222     INSTALLS += icon64
 223     target.path = $$BINDIR
 224     INSTALLS += target
 225 }