vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/contactmanager.cpp \
  16     engine/engine.cpp \
  17     engine/mce.cpp \
  18     facebookservice/facebookauthentication.cpp \
  19     facebookservice/facebookcredentials.cpp \
  20     gps/gpsposition.cpp \
  21     map/baselocationitem.cpp \
  22     map/friendgroupitem.cpp \
  23     map/frienditemshandler.cpp \
  24     map/friendlocationitem.cpp \
  25     map/gpslocationitem.cpp \
  26     map/mapengine.cpp \
  27     map/mapfetcher.cpp \
  28     map/maprouteitem.cpp \
  29     map/mapscene.cpp \
  30     map/mapscroller.cpp \
  31     map/maptile.cpp \
  32     map/maptilerequest.cpp \
  33     map/mapview.cpp \
  34     map/ownlocationitem.cpp \
  35     network/networkaccessmanager.cpp \
  36     network/networkcookiejar.cpp \
  37     network/networkhandler.cpp \
  38     network/networkreply.cpp \
  39     routing/geocodingservice.cpp \
  40     routing/location.cpp \
  41     routing/route.cpp \
  42     routing/routesegment.cpp \
  43     routing/routingservice.cpp \
  44     situareservice/imagefetcher.cpp \
  45     situareservice/situareservice.cpp \
  46     ui/updatelocation/texteditautoresizer.cpp \
  47     ui/updatelocation/updatelocationdialog.cpp \
  48     ui/avatarimage.cpp \
  49     ui/extendedlistitem.cpp \
  50     ui/extendedlistitemdelegate.cpp \
  51     ui/extendedlistitemstore.cpp \
  52     ui/friendlistitem.cpp \
  53     ui/friendlistitemdelegate.cpp \
  54     ui/friendlistpanel.cpp \
  55     ui/friendlistview.cpp \
  56     ui/fullscreenbutton.cpp \
  57     ui/imagebutton.cpp \
  58     ui/indicatorbutton.cpp \
  59     ui/listitem.cpp \
  60     ui/listitemdelegate.cpp \
  61     ui/listview.cpp \
  62     ui/locationlistitem.cpp \
  63     ui/locationlistview.cpp \
  64     ui/indicatorbuttonpanel.cpp \
  65     ui/locationsearchpanel.cpp \
  66     ui/logindialog.cpp \
  67     ui/mainwindow.cpp \
  68     ui/mapscale.cpp \
  69     ui/panelbar.cpp \
  70     ui/panelbase.cpp \
  71     ui/panelcontentstack.cpp \
  72     ui/panelcontextbuttonbar.cpp \
  73     ui/paneltab.cpp \
  74     ui/paneltabbar.cpp \
  75     ui/routingpanel.cpp \
  76     ui/routewaypointlistitem.cpp \
  77     ui/routewaypointlistview.cpp \
  78     ui/searchdialog.cpp \
  79     ui/searchhistorylistitem.cpp \
  80     ui/searchhistorylistview.cpp \
  81     ui/settingsdialog.cpp \
  82     ui/tabbedpanel.cpp \
  83     ui/textmodifier.cpp \
  84     ui/userinfo.cpp \
  85     ui/userinfopanel.cpp \
  86     ui/zoombutton.cpp \
  87     ui/zoombuttonpanel.cpp \
  88     user/user.cpp \
  89     ui/listitemcontextbuttonbar.cpp
  90 HEADERS += application.h \
  91     common.h \
  92     coordinates/geocoordinate.h \
  93     coordinates/scenecoordinate.h \
  94     engine/contactmanager.h \
  95     engine/engine.h \
  96     engine/mce.h \
  97     error.h \
  98     facebookservice/facebookauthentication.h \
  99     facebookservice/facebookcommon.h \
 100     facebookservice/facebookcredentials.h \
 101     gps/gpscommon.h \
 102     gps/gpsposition.h \
 103     map/baselocationitem.h \
 104     map/friendgroupitem.h \
 105     map/frienditemshandler.h \
 106     map/friendlocationitem.h \
 107     map/gpslocationitem.h \
 108     map/mapcommon.h \
 109     map/mapengine.h \
 110     map/mapfetcher.h \
 111     map/maprouteitem.h \
 112     map/mapscene.h \
 113     map/mapscroller.h \
 114     map/maptile.h \
 115     map/maptilerequest.h \
 116     map/mapview.h \
 117     map/osm.h \
 118     map/ownlocationitem.h \
 119     network/networkaccessmanager.h \
 120     network/networkcookiejar.h \
 121     network/networkhandler.h \
 122     network/networkreply.h \
 123     routing/geocodingservice.h \
 124     routing/location.h \
 125     routing/route.h \
 126     routing/routesegment.h \
 127     routing/routingcommon.h \
 128     routing/routingservice.h \
 129     situareservice/imagefetcher.h \
 130     situareservice/situarecommon.h \
 131     situareservice/situareservice.h \
 132     ui/updatelocation/texteditautoresizer.h \
 133     ui/updatelocation/updatelocationdialog.h \
 134     ui/avatarimage.h \
 135     ui/extendedlistitem.h \
 136     ui/extendedlistitemdelegate.h \
 137     ui/extendedlistitemstore.h \
 138     ui/friendlistitem.h \
 139     ui/friendlistitemdelegate.h \
 140     ui/friendlistpanel.h \
 141     ui/friendlistview.h \
 142     ui/fullscreenbutton.h \
 143     ui/imagebutton.h \
 144     ui/indicatorbutton.h \
 145     ui/indicatorbuttonpanel.h \
 146     ui/listcommon.h \
 147     ui/listview.h \
 148     ui/listitem.h \
 149     ui/listitemdelegate.h \
 150     ui/logindialog.h \
 151     ui/locationlistitem.h \
 152     ui/locationlistview.h \
 153     ui/locationsearchpanel.h \
 154     ui/mainwindow.h \
 155     ui/mapscale.h \
 156     ui/panelbar.h \
 157     ui/panelbase.h \
 158     ui/panelcommon.h \
 159     ui/panelcontentstack.h \
 160     ui/panelcontextbuttonbar.h \
 161     ui/paneltab.h \
 162     ui/paneltabbar.h \
 163     ui/routingpanel.h \
 164     ui/routewaypointlistitem.h \
 165     ui/routewaypointlistview.h \
 166     ui/searchdialog.h \
 167     ui/searchhistorylistitem.h \
 168     ui/searchhistorylistview.h \
 169     ui/settingsdialog.h \
 170     ui/tabbedpanel.h \
 171     ui/textmodifier.h \
 172     ui/userinfo.h \
 173     ui/userinfopanel.h \
 174     ui/zoombutton.h \
 175     ui/zoombuttonpanel.h \
 176     user/user.h \
 177     ui/listitemcontextbuttonbar.h
 178 QT += network \
 179     webkit
 180 DEFINES += QT_NO_DEBUG_OUTPUT
 181
 182 simulator {
 183     SOURCES += network/networkhandlerprivatestub.cpp \
 184                gps/gpspositionprivate.cpp
 185     HEADERS += network/networkhandlerprivatestub.h \
 186                gps/gpspositionprivate.h
 187     QT += maemo5
 188     CONFIG += mobility
 189     MOBILITY += location
 190 } else:maemo5 {
 191     armel {
 192         DEFINES += ARMEL
 193         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 194         SOURCES += network/networkhandlerprivate.cpp \
 195                    engine/mceprivate.cpp
 196         HEADERS += network/networkhandlerprivate.h \
 197                    engine/mceprivate.h
 198         QT += dbus xml
 199         CONFIG += icd2 qdbus
 200         SOURCES += gps/gpspositionprivateliblocation.cpp \
 201                    gps/liblocationwrapper.cpp \
 202                    gps/geopositioninfo.cpp
 203         HEADERS += gps/gpspositionprivateliblocation.h \
 204                    gps/liblocationwrapper.h \
 205                    gps/geopositioninfo.h
 206         CONFIG += link_pkgconfig
 207         PKGCONFIG += glib-2.0 liblocation mce gtk+-2.0 libosso-abook-1.0
 208         LIBS += -llocation
 209         SOURCES += engine/contactmanagerprivate.cpp \
 210                    ui/ossoabookdialog.cpp
 211         HEADERS += engine/contactmanagerprivate.h \
 212                    ui/ossoabookdialog.h
 213         CONFIG += mobility
 214         MOBILITY += contacts
 215     } else {
 216         SOURCES += gps/gpspositionprivatestub.cpp \
 217                    network/networkhandlerprivatestub.cpp \
 218                    engine/mceprivatestub.cpp
 219         HEADERS += gps/gpspositionprivatestub.h \
 220                    network/networkhandlerprivatestub.h \
 221                    engine/mceprivatestub.h
 222         SOURCES += engine/contactmanagerprivatestub.cpp
 223         HEADERS += engine/contactmanagerprivatestub.h
 224     }
 225
 226     QT += maemo5
 227
 228     message([QJson])
 229     message(Make sure you have QJson development headers installed)
 230     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 231     message(to Scratchbox's sources.list in /etc/apt)
 232     message(run: apt-get update)
 233     message(install headers with: apt-get install libqjson-dev)
 234     message([QtMobility])
 235     message(Make sure you have QtMobility development headers installed)
 236     message(install headers with: apt-get install libqtm-dev)
 237 } else {
 238     SOURCES += gps/gpspositionprivatestub.cpp \
 239                network/networkhandlerprivatestub.cpp \
 240                engine/mceprivatestub.cpp
 241     HEADERS += gps/gpspositionprivatestub.h \
 242                network/networkhandlerprivatestub.h \
 243                engine/mceprivatestub.h
 244     SOURCES += engine/contactmanagerprivatestub.cpp
 245     HEADERS += engine/contactmanagerprivatestub.h
 246     message(QJson built in)
 247     message(Make sure you have QJson development headers installed)
 248     message(install headers with: sudo apt-get install libqjson-dev)
 249 }
 250
 251 # -----------------------------------------------------------------
 252 # Debian packetizing additions
 253 # -----------------------------------------------------------------
 254 unix {
 255     # VARIABLES
 256     isEmpty(PREFIX):PREFIX = /usr
 257     BINDIR = $$PREFIX/bin
 258     DATADIR = $$PREFIX/share
 259     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 260         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 261
 262     # MAKE INSTALL
 263     desktop.path = $$DATADIR/applications/hildon
 264     desktop.files += situare.desktop
 265     INSTALLS += desktop
 266     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 267     icon48.files += ../res/icon/48x48/situare.png
 268     INSTALLS += icon48
 269     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 270     icon64.files += ../res/icon/64x64/situare.png
 271     INSTALLS += icon64
 272     target.path = $$BINDIR
 273     INSTALLS += target
 274 }