vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     engine/engine.cpp \
  13     facebookservice/facebookauthentication.cpp \
  14     facebookservice/facebookcredentials.cpp \
  15     gps/gpsposition.cpp \
  16     map/baselocationitem.cpp \
  17     map/friendgroupitem.cpp \
  18     map/frienditemshandler.cpp \
  19     map/friendlocationitem.cpp \
  20     map/gpslocationitem.cpp \
  21     map/mapengine.cpp \
  22     map/mapfetcher.cpp \
  23     map/mapscene.cpp \
  24     map/maptile.cpp \
  25     map/maptilerequest.cpp \
  26     map/mapview.cpp \
  27     map/ownlocationitem.cpp \
  28     network/networkaccessmanager.cpp \
  29     network/networkcookiejar.cpp \
  30     network/networkhandler.cpp \
  31     network/networkreply.cpp \
  32     situareservice/imagefetcher.cpp \
  33     situareservice/situareservice.cpp \
  34     ui/updatelocation/texteditautoresizer.cpp \
  35     ui/updatelocation/updatelocationdialog.cpp \
  36     ui/avatarimage.cpp \
  37     ui/friendlistitem.cpp \
  38     ui/friendlistpanel.cpp \
  39     ui/friendlistview.cpp \
  40     ui/imagebutton.cpp \
  41     ui/logindialog.cpp \
  42     ui/mainwindow.cpp \
  43     ui/mapscale.cpp \
  44     ui/panelsidebar.cpp \
  45     ui/panelsliderbar.cpp \
  46     ui/settingsdialog.cpp \
  47     ui/sidepanel.cpp \
  48     ui/sidepanelbase.cpp \
  49     ui/userinfo.cpp \
  50     ui/userinfopanel.cpp \
  51     ui/zoombutton.cpp \
  52     ui/zoombuttonpanel.cpp \
  53     user/user.cpp \
  54     ui/fullscreenbutton.cpp
  55 HEADERS += common.h \
  56     engine/engine.h \
  57     facebookservice/facebookauthentication.h \
  58     facebookservice/facebookcommon.h \
  59     facebookservice/facebookcredentials.h \
  60     gps/gpscommon.h \
  61     gps/gpsposition.h \
  62     map/baselocationitem.h \
  63     map/friendgroupitem.h \
  64     map/frienditemshandler.h \
  65     map/friendlocationitem.h \
  66     map/gpslocationitem.h \
  67     map/mapcommon.h \
  68     map/mapengine.h \
  69     map/mapfetcher.h \
  70     map/mapscene.h \
  71     map/maptile.h \
  72     map/maptilerequest.h \
  73     map/mapview.h \
  74     map/ownlocationitem.h \
  75     network/networkaccessmanager.h \
  76     network/networkcookiejar.h \
  77     network/networkhandler.h \
  78     network/networkreply.h \
  79     situareservice/imagefetcher.h \
  80     situareservice/situarecommon.h \
  81     situareservice/situareservice.h \
  82     ui/updatelocation/texteditautoresizer.h \
  83     ui/updatelocation/updatelocationdialog.h \
  84     ui/avatarimage.h \
  85     ui/friendlistitem.h \
  86     ui/friendlistpanel.h \
  87     ui/friendlistview.h \
  88     ui/imagebutton.h \
  89     ui/logindialog.h \
  90     ui/mainwindow.h \
  91     ui/mapscale.h \
  92     ui/panelcommon.h \
  93     ui/panelsidebar.h \
  94     ui/panelsliderbar.h \
  95     ui/settingsdialog.h \
  96     ui/userinfo.h \
  97     ui/userinfopanel.h \
  98     ui/sidepanel.h \
  99     ui/sidepanelbase.h \
 100     ui/zoombutton.h \
 101     ui/zoombuttonpanel.h \
 102     user/user.h \
 103     ui/fullscreenbutton.h
 104 QT += network \
 105     webkit
 106 DEFINES += QT_NO_DEBUG_OUTPUT
 107
 108 simulator {
 109     SOURCES += network/networkhandlerprivatestub.cpp \
 110                gps/gpspositionprivate.cpp
 111     HEADERS += network/networkhandlerprivatestub.h \
 112                gps/gpspositionprivate.h
 113     QT += maemo5
 114     CONFIG += mobility
 115     MOBILITY += location
 116 } else:maemo5 {
 117     armel {
 118         DEFINES += ARMEL
 119         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 120         SOURCES += network/networkhandlerprivate.cpp
 121         HEADERS += network/networkhandlerprivate.h
 122         QT += dbus
 123         CONFIG += icd2
 124         SOURCES += gps/gpspositionprivateliblocation.cpp \
 125                    gps/liblocationwrapper.cpp \
 126                    gps/geopositioninfo.cpp \
 127                    gps/geocoordinate.cpp
 128         HEADERS += gps/gpspositionprivateliblocation.h \
 129                    gps/liblocationwrapper.h \
 130                    gps/geopositioninfo.h \
 131                    gps/geocoordinate.h
 132         CONFIG += link_pkgconfig
 133         PKGCONFIG += glib-2.0 liblocation
 134     } else {
 135         SOURCES += gps/gpspositionprivatestub.cpp \
 136                    network/networkhandlerprivatestub.cpp
 137         HEADERS += gps/gpspositionprivatestub.h \
 138                    network/networkhandlerprivatestub.h
 139     }
 140
 141     QT += maemo5
 142
 143     message([QJson])
 144     message(Make sure you have QJson development headers installed)
 145     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 146     message(to Scratchbox's sources.list in /etc/apt)
 147     message(run: apt-get update)
 148     message(install headers with: apt-get install libqjson-dev)
 149     message([QtMobility])
 150     message(Make sure you have QtMobility development headers installed)
 151     message(install headers with: apt-get install libqtm-dev)
 152 } else {
 153     SOURCES += gps/gpspositionprivatestub.cpp \
 154                network/networkhandlerprivatestub.cpp
 155     HEADERS += gps/gpspositionprivatestub.h \
 156                network/networkhandlerprivatestub.h
 157     message(QJson built in)
 158     message(Make sure you have QJson development headers installed)
 159     message(install headers with: sudo apt-get install libqjson-dev)
 160 }
 161
 162 # -----------------------------------------------------------------
 163 # Debian packetizing additions
 164 # -----------------------------------------------------------------
 165 unix {
 166     # VARIABLES
 167     isEmpty(PREFIX):PREFIX = /usr
 168     BINDIR = $$PREFIX/bin
 169     DATADIR = $$PREFIX/share
 170     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 171         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 172
 173     # MAKE INSTALL
 174     desktop.path = $$DATADIR/applications/hildon
 175     desktop.files += situare.desktop
 176     INSTALLS += desktop
 177     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 178     icon48.files += ../res/icon/48x48/situare.png
 179     INSTALLS += icon48
 180     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 181     icon64.files += ../res/icon/64x64/situare.png
 182     INSTALLS += icon64
 183     target.path = $$BINDIR
 184     INSTALLS += target
 185 }