vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/friendlistitem.cpp \
  49     ui/friendlistpanel.cpp \
  50     ui/fullscreenbutton.cpp \
  51     ui/imagebutton.cpp \
  52     ui/indicatorbutton.cpp \
  53     ui/indicatorbuttonpanel.cpp \
  54     ui/logindialog.cpp \
  55     ui/mainwindow.cpp \
  56     ui/mapscale.cpp \
  57     ui/settingsdialog.cpp \
  58     ui/userinfo.cpp \
  59     ui/userinfopanel.cpp \
  60     ui/zoombutton.cpp \
  61     ui/zoombuttonpanel.cpp \
  62     ui/listview.cpp \
  63     ui/listitem.cpp \
  64     ui/listitemdelegate.cpp \
  65     ui/friendlistitemdelegate.cpp \
  66     ui/searchdialog.cpp \
  67     ui/panelbar.cpp \
  68     ui/panelcontentstack.cpp \
  69     ui/paneltab.cpp \
  70     ui/paneltabbar.cpp \
  71     ui/tabbedpanel.cpp \
  72     user/user.cpp
  73 HEADERS += application.h \
  74     common.h \
  75     coordinates/geocoordinate.h \
  76     coordinates/scenecoordinate.h \
  77     engine/engine.h \
  78     engine/mce.h \
  79     error.h \
  80     facebookservice/facebookauthentication.h \
  81     facebookservice/facebookcommon.h \
  82     facebookservice/facebookcredentials.h \
  83     gps/gpscommon.h \
  84     gps/gpsposition.h \
  85     map/baselocationitem.h \
  86     map/friendgroupitem.h \
  87     map/frienditemshandler.h \
  88     map/friendlocationitem.h \
  89     map/gpslocationitem.h \
  90     map/mapcommon.h \
  91     map/mapengine.h \
  92     map/mapfetcher.h \
  93     map/maprouteitem.h \
  94     map/mapscene.h \
  95     map/mapscroller.h \
  96     map/maptile.h \
  97     map/maptilerequest.h \
  98     map/mapview.h \
  99     map/osm.h \
 100     map/ownlocationitem.h \
 101     network/networkaccessmanager.h \
 102     network/networkcookiejar.h \
 103     network/networkhandler.h \
 104     network/networkreply.h \
 105     routing/geocodingservice.h \
 106     routing/location.h \
 107     routing/route.h \
 108     routing/routesegment.h \
 109     routing/routingcommon.h \
 110     routing/routingservice.h \
 111     situareservice/imagefetcher.h \
 112     situareservice/situarecommon.h \
 113     situareservice/situareservice.h \
 114     ui/updatelocation/texteditautoresizer.h \
 115     ui/updatelocation/updatelocationdialog.h \
 116     ui/avatarimage.h \
 117     ui/friendlistitem.h \
 118     ui/friendlistitemdelegate.h \
 119     ui/friendlistpanel.h \
 120     ui/fullscreenbutton.h \
 121     ui/imagebutton.h \
 122     ui/indicatorbutton.h \
 123     ui/indicatorbuttonpanel.h \
 124     ui/logindialog.h \
 125     ui/mainwindow.h \
 126     ui/mapscale.h \
 127     ui/settingsdialog.h \
 128     ui/userinfo.h \
 129     ui/userinfopanel.h \
 130     ui/zoombutton.h \
 131     ui/zoombuttonpanel.h \
 132     ui/listcommon.h \
 133     ui/listview.h \
 134     ui/listitem.h \
 135     ui/listitemdelegate.h \
 136     ui/searchdialog.h \
 137     ui/panelbar.h \
 138     ui/panelcommon.h \
 139     ui/panelcontentstack.h \
 140     ui/paneltab.h \
 141     ui/paneltabbar.h \
 142     ui/tabbedpanel.h \
 143     user/user.h
 144 QT += network \
 145     webkit
 146
 147 DEFINES += QT_NO_DEBUG_OUTPUT
 148
 149 simulator {
 150     SOURCES += network/networkhandlerprivatestub.cpp \
 151                gps/gpspositionprivate.cpp
 152     HEADERS += network/networkhandlerprivatestub.h \
 153                gps/gpspositionprivate.h
 154     QT += maemo5
 155     CONFIG += mobility
 156     MOBILITY += location
 157 } else:maemo5 {
 158     armel {
 159         DEFINES += ARMEL
 160         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 161         SOURCES += network/networkhandlerprivate.cpp \
 162                    engine/mceprivate.cpp
 163         HEADERS += network/networkhandlerprivate.h \
 164                    engine/mceprivate.h
 165         QT += dbus xml
 166         CONFIG += icd2 qdbus
 167         SOURCES += gps/gpspositionprivateliblocation.cpp \
 168                    gps/liblocationwrapper.cpp \
 169                    gps/geopositioninfo.cpp
 170         HEADERS += gps/gpspositionprivateliblocation.h \
 171                    gps/liblocationwrapper.h \
 172                    gps/geopositioninfo.h
 173         CONFIG += link_pkgconfig
 174         PKGCONFIG += glib-2.0 liblocation mce
 175         LIBS += -llocation
 176     } else {
 177         SOURCES += gps/gpspositionprivatestub.cpp \
 178                    network/networkhandlerprivatestub.cpp \
 179                    engine/mceprivatestub.cpp
 180         HEADERS += gps/gpspositionprivatestub.h \
 181                    network/networkhandlerprivatestub.h \
 182                    engine/mceprivatestub.h
 183     }
 184
 185     QT += maemo5
 186
 187     message([QJson])
 188     message(Make sure you have QJson development headers installed)
 189     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 190     message(to Scratchbox's sources.list in /etc/apt)
 191     message(run: apt-get update)
 192     message(install headers with: apt-get install libqjson-dev)
 193     message([QtMobility])
 194     message(Make sure you have QtMobility development headers installed)
 195     message(install headers with: apt-get install libqtm-dev)
 196 } else {
 197     SOURCES += gps/gpspositionprivatestub.cpp \
 198                network/networkhandlerprivatestub.cpp \
 199                engine/mceprivatestub.cpp
 200     HEADERS += gps/gpspositionprivatestub.h \
 201                network/networkhandlerprivatestub.h \
 202                engine/mceprivatestub.h
 203     message(QJson built in)
 204     message(Make sure you have QJson development headers installed)
 205     message(install headers with: sudo apt-get install libqjson-dev)
 206 }
 207
 208 # -----------------------------------------------------------------
 209 # Debian packetizing additions
 210 # -----------------------------------------------------------------
 211 unix {
 212     # VARIABLES
 213     isEmpty(PREFIX):PREFIX = /usr
 214     BINDIR = $$PREFIX/bin
 215     DATADIR = $$PREFIX/share
 216     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 217         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 218
 219     # MAKE INSTALL
 220     desktop.path = $$DATADIR/applications/hildon
 221     desktop.files += situare.desktop
 222     INSTALLS += desktop
 223     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 224     icon48.files += ../res/icon/48x48/situare.png
 225     INSTALLS += icon48
 226     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 227     icon64.files += ../res/icon/64x64/situare.png
 228     INSTALLS += icon64
 229     target.path = $$BINDIR
 230     INSTALLS += target
 231 }