vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/panelbar.cpp \
  74     ui/panelbase.cpp \
  75     ui/panelcontentstack.cpp \
  76     ui/panelcontextbuttonbar.cpp \
  77     ui/paneltab.cpp \
  78     ui/paneltabbar.cpp \
  79     ui/tabbedpanel.cpp \
  80     ui/routingpanel.cpp \
  81     ui/routewaypointlistitem.cpp \
  82     ui/routewaypointlistview.cpp \
  83     user/user.cpp \
  84     ui/locationsearchpanel.cpp \
  85     ui/textmodifier.cpp \
  86     ui/searchhistorylistview.cpp \
  87     ui/searchhistorylistitem.cpp
  88 HEADERS += application.h \
  89     common.h \
  90     coordinates/geocoordinate.h \
  91     coordinates/scenecoordinate.h \
  92     engine/engine.h \
  93     engine/mce.h \
  94     error.h \
  95     facebookservice/facebookauthentication.h \
  96     facebookservice/facebookcommon.h \
  97     facebookservice/facebookcredentials.h \
  98     gps/gpscommon.h \
  99     gps/gpsposition.h \
 100     map/baselocationitem.h \
 101     map/friendgroupitem.h \
 102     map/frienditemshandler.h \
 103     map/friendlocationitem.h \
 104     map/gpslocationitem.h \
 105     map/mapcommon.h \
 106     map/mapengine.h \
 107     map/mapfetcher.h \
 108     map/maprouteitem.h \
 109     map/mapscene.h \
 110     map/mapscroller.h \
 111     map/maptile.h \
 112     map/maptilerequest.h \
 113     map/mapview.h \
 114     map/osm.h \
 115     map/ownlocationitem.h \
 116     network/networkaccessmanager.h \
 117     network/networkcookiejar.h \
 118     network/networkhandler.h \
 119     network/networkreply.h \
 120     routing/geocodingservice.h \
 121     routing/location.h \
 122     routing/route.h \
 123     routing/routesegment.h \
 124     routing/routingcommon.h \
 125     routing/routingservice.h \
 126     situareservice/imagefetcher.h \
 127     situareservice/situarecommon.h \
 128     situareservice/situareservice.h \
 129     ui/updatelocation/texteditautoresizer.h \
 130     ui/updatelocation/updatelocationdialog.h \
 131     ui/avatarimage.h \
 132     ui/extendedlistitem.h \
 133     ui/extendedlistitemdelegate.h \
 134     ui/extendedlistitemstore.h \
 135     ui/friendlistitem.h \
 136     ui/friendlistitemdelegate.h \
 137     ui/friendlistpanel.h \
 138     ui/friendlistview.h \
 139     ui/fullscreenbutton.h \
 140     ui/imagebutton.h \
 141     ui/indicatorbutton.h \
 142     ui/indicatorbuttonpanel.h \
 143     ui/logindialog.h \
 144     ui/locationlistitem.h \
 145     ui/locationlistview.h \
 146     ui/mainwindow.h \
 147     ui/mapscale.h \
 148     ui/settingsdialog.h \
 149     ui/userinfo.h \
 150     ui/userinfopanel.h \
 151     ui/zoombutton.h \
 152     ui/zoombuttonpanel.h \
 153     ui/listcommon.h \
 154     ui/listview.h \
 155     ui/listitem.h \
 156     ui/listitemdelegate.h \
 157     ui/searchdialog.h \
 158     ui/panelbar.h \
 159     ui/panelbase.h \
 160     ui/panelcommon.h \
 161     ui/panelcontentstack.h \
 162     ui/panelcontextbuttonbar.h \
 163     ui/paneltab.h \
 164     ui/paneltabbar.h \
 165     ui/tabbedpanel.h \
 166     ui/routingpanel.h \
 167     ui/routewaypointlistitem.h \
 168     ui/routewaypointlistview.h \
 169     user/user.h \
 170     ui/locationsearchpanel.h \
 171     ui/textmodifier.h \
 172     ui/searchhistorylistview.h \
 173     ui/searchhistorylistitem.h
 174 QT += network \
 175     webkit
 176 DEFINES += QT_NO_DEBUG_OUTPUT
 177
 178 simulator {
 179     SOURCES += network/networkhandlerprivatestub.cpp \
 180                gps/gpspositionprivate.cpp
 181     HEADERS += network/networkhandlerprivatestub.h \
 182                gps/gpspositionprivate.h
 183     QT += maemo5
 184     CONFIG += mobility
 185     MOBILITY += location
 186 } else:maemo5 {
 187     armel {
 188         DEFINES += ARMEL
 189         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 190         SOURCES += network/networkhandlerprivate.cpp \
 191                    engine/mceprivate.cpp
 192         HEADERS += network/networkhandlerprivate.h \
 193                    engine/mceprivate.h
 194         QT += dbus xml
 195         CONFIG += icd2 qdbus
 196         SOURCES += gps/gpspositionprivateliblocation.cpp \
 197                    gps/liblocationwrapper.cpp \
 198                    gps/geopositioninfo.cpp
 199         HEADERS += gps/gpspositionprivateliblocation.h \
 200                    gps/liblocationwrapper.h \
 201                    gps/geopositioninfo.h
 202         CONFIG += link_pkgconfig
 203         PKGCONFIG += glib-2.0 liblocation mce
 204         LIBS += -llocation
 205     } else {
 206         SOURCES += gps/gpspositionprivatestub.cpp \
 207                    network/networkhandlerprivatestub.cpp \
 208                    engine/mceprivatestub.cpp
 209         HEADERS += gps/gpspositionprivatestub.h \
 210                    network/networkhandlerprivatestub.h \
 211                    engine/mceprivatestub.h
 212     }
 213
 214     QT += maemo5
 215
 216     message([QJson])
 217     message(Make sure you have QJson development headers installed)
 218     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 219     message(to Scratchbox's sources.list in /etc/apt)
 220     message(run: apt-get update)
 221     message(install headers with: apt-get install libqjson-dev)
 222     message([QtMobility])
 223     message(Make sure you have QtMobility development headers installed)
 224     message(install headers with: apt-get install libqtm-dev)
 225 } else {
 226     SOURCES += gps/gpspositionprivatestub.cpp \
 227                network/networkhandlerprivatestub.cpp \
 228                engine/mceprivatestub.cpp
 229     HEADERS += gps/gpspositionprivatestub.h \
 230                network/networkhandlerprivatestub.h \
 231                engine/mceprivatestub.h
 232     message(QJson built in)
 233     message(Make sure you have QJson development headers installed)
 234     message(install headers with: sudo apt-get install libqjson-dev)
 235 }
 236
 237 # -----------------------------------------------------------------
 238 # Debian packetizing additions
 239 # -----------------------------------------------------------------
 240 unix {
 241     # VARIABLES
 242     isEmpty(PREFIX):PREFIX = /usr
 243     BINDIR = $$PREFIX/bin
 244     DATADIR = $$PREFIX/share
 245     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 246         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 247
 248     # MAKE INSTALL
 249     desktop.path = $$DATADIR/applications/hildon
 250     desktop.files += situare.desktop
 251     INSTALLS += desktop
 252     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 253     icon48.files += ../res/icon/48x48/situare.png
 254     INSTALLS += icon48
 255     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 256     icon64.files += ../res/icon/64x64/situare.png
 257     INSTALLS += icon64
 258     target.path = $$BINDIR
 259     INSTALLS += target
 260 }