vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc
   9 SOURCES += main.cpp \
  10     ui/mainwindow.cpp \
  11     situareservice/situareservice.cpp \
  12     situareservice/imagefetcher.cpp \
  13     facebookservice/facebookcredentials.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     map/mapengine.cpp \
  16     map/mapview.cpp \
  17     map/mapscene.cpp \
  18     map/maptile.cpp \
  19     map/mapfetcher.cpp \
  20     map/ownlocationitem.cpp \
  21     map/baselocationitem.cpp \
  22     map/friendlocationitem.cpp \
  23     ui/updatelocation/updatelocationdialog.cpp \
  24     ui/updatelocation/texteditautoresizer.cpp \
  25     ui/friendlistview.cpp \
  26     ui/friendlistitem.cpp \
  27     user/user.cpp \
  28     ui/avatarimage.cpp \
  29     engine/engine.cpp \
  30     ui/settingsdialog.cpp \
  31     ui/logindialog.cpp \
  32     map/maptilerequest.cpp \
  33     ui/imagebutton.cpp \
  34     ui/friendlistpanel.cpp \
  35     ui/userinfopanel.cpp \
  36     ui/panelsidebar.cpp \
  37     ui/panelsliderbar.cpp \
  38     map/friendgroupitem.cpp \
  39     map/frienditemshandler.cpp \
  40     gps/gpsposition.cpp \
  41     map/gpslocationitem.cpp \
  42     ui/zoombuttonpanel.cpp \
  43     ui/userinfo.cpp \
  44     ui/sidepanel.cpp \
  45     ui/zoombutton.cpp \
  46     network/networkaccessmanager.cpp \
  47     network/networkhandler.cpp \
  48     network/networkcookiejar.cpp \
  49     network/networkreply.cpp
  50 HEADERS += ui/mainwindow.h \
  51     map/mapengine.h \
  52     map/mapview.h \
  53     map/mapscene.h \
  54     map/maptile.h \
  55     map/mapfetcher.h \
  56     map/mapcommon.h \
  57     map/ownlocationitem.h \
  58     map/baselocationitem.h \
  59     map/friendlocationitem.h \
  60     ui/updatelocation/updatelocationdialog.h \
  61     ui/updatelocation/texteditautoresizer.h \
  62     situareservice/situareservice.h \
  63     situareservice/situarecommon.h \
  64     situareservice/imagefetcher.h \
  65     facebookservice/facebookcredentials.h \
  66     facebookservice/facebookauthentication.h \
  67     facebookservice/facebookcommon.h \
  68     ui/friendlistview.h \
  69     ui/friendlistitem.h \
  70     user/user.h \
  71     ui/avatarimage.h \
  72     engine/engine.h \
  73     ui/settingsdialog.h \
  74     ui/logindialog.h \
  75     map/maptilerequest.h \
  76     ui/imagebutton.h \
  77     ui/friendlistpanel.h \
  78     ui/userinfopanel.h \
  79     ui/panelcommon.h \
  80     ui/panelsidebar.h \
  81     ui/panelsliderbar.h \
  82     map/friendgroupitem.h \
  83     map/frienditemshandler.h \
  84     gps/gpsposition.h \
  85     map/gpslocationitem.h \
  86     gps/gpscommon.h \
  87     ui/zoombuttonpanel.h \
  88     common.h \
  89     ui/userinfo.h \
  90     ui/sidepanel.h \
  91     ui/zoombutton.h \
  92     network/networkaccessmanager.h \
  93     network/networkhandler.h \
  94     network/networkcookiejar.h \
  95     network/networkreply.h
  96 QT += network \
  97     webkit
  98 #DEFINES += QT_NO_DEBUG_OUTPUT
  99
 100 maemo5 | simulator {
 101     armel {
 102         DEFINES += ARMEL
 103         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 104         SOURCES += network/networkhandlerprivate.cpp
 105         HEADERS += network/networkhandlerprivate.h
 106         QT += dbus
 107         CONFIG += icd2
 108     }
 109     else {
 110         SOURCES += network/networkhandlerprivatestub.cpp
 111         HEADERS += network/networkhandlerprivatestub.h
 112     }
 113     SOURCES += gps/gpspositionprivate.cpp
 114     HEADERS += gps/gpspositionprivate.h
 115     QT += maemo5
 116     CONFIG += mobility
 117     MOBILITY = location
 118     message([QJson])
 119     message(Make sure you have QJson development headers installed)
 120     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 121     message(to Scratchbox's sources.list in /etc/apt)
 122     message(run: apt-get update)
 123     message(install headers with: apt-get install libqjson-dev)
 124     message([QtMobility])
 125     message(Make sure you have QtMobility development headers installed)
 126     message(install headers with: apt-get install libqtm-dev)
 127 } else {
 128     SOURCES += gps/gpspositionprivatestub.cpp \
 129                network/networkhandlerprivatestub.cpp
 130     HEADERS += gps/gpspositionprivatestub.h \
 131                network/networkhandlerprivatestub.h
 132     message(QJson built in)
 133     message(Make sure you have QJson development headers installed)
 134     message(install headers with: sudo apt-get install libqjson-dev)
 135 }
 136
 137 # -----------------------------------------------------------------
 138 # Debian packetizing additions
 139 # -----------------------------------------------------------------
 140 unix {
 141     # VARIABLES
 142     isEmpty(PREFIX):PREFIX = /usr
 143     BINDIR = $$PREFIX/bin
 144     DATADIR = $$PREFIX/share
 145     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 146         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 147
 148     # MAKE INSTALL
 149     desktop.path = $$DATADIR/applications/hildon
 150     desktop.files += situare.desktop
 151     INSTALLS += desktop
 152     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 153     icon48.files += ../res/icon/48x48/situare.png
 154     INSTALLS += icon48
 155     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 156     icon64.files += ../res/icon/64x64/situare.png
 157     INSTALLS += icon64
 158     target.path = $$BINDIR
 159     INSTALLS += target
 160 }