vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 LIBS += -lqjson
   7 RESOURCES += ../images.qrc \
   8     ../languages.qrc
   9 TRANSLATIONS += ../res/languages/situare_fi.ts
  10 SOURCES += main.cpp \
  11     application.cpp \
  12     coordinates/geocoordinate.cpp \
  13     coordinates/scenecoordinate.cpp \
  14     engine/contactmanager.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     gps/gpsposition.cpp \
  19     map/baselocationitem.cpp \
  20     map/friendgroupitem.cpp \
  21     map/frienditemshandler.cpp \
  22     map/friendlocationitem.cpp \
  23     map/gpslocationitem.cpp \
  24     map/mapengine.cpp \
  25     map/mapfetcher.cpp \
  26     map/maprouteitem.cpp \
  27     map/mapscene.cpp \
  28     map/mapscroller.cpp \
  29     map/maptile.cpp \
  30     map/maptilerequest.cpp \
  31     map/mapview.cpp \
  32     map/ownlocationitem.cpp \
  33     network/networkaccessmanager.cpp \
  34     network/networkcookiejar.cpp \
  35     network/networkhandler.cpp \
  36     network/networkreply.cpp \
  37     routing/geocodingservice.cpp \
  38     routing/location.cpp \
  39     routing/route.cpp \
  40     routing/routesegment.cpp \
  41     routing/routingservice.cpp \
  42     situareservice/imagefetcher.cpp \
  43     situareservice/situareservice.cpp \
  44     ui/updatelocation/texteditautoresizer.cpp \
  45     ui/updatelocation/updatelocationdialog.cpp \
  46     ui/avatarimage.cpp \
  47     ui/extendedlistitem.cpp \
  48     ui/extendedlistitemdelegate.cpp \
  49     ui/extendedlistitemstore.cpp \
  50     ui/friendlistitem.cpp \
  51     ui/friendlistitemdelegate.cpp \
  52     ui/friendlistpanel.cpp \
  53     ui/friendlistview.cpp \
  54     ui/fullscreenbutton.cpp \
  55     ui/imagebutton.cpp \
  56     ui/indicatorbutton.cpp \
  57     ui/listitem.cpp \
  58     ui/listitemdelegate.cpp \
  59     ui/listview.cpp \
  60     ui/locationlistitem.cpp \
  61     ui/locationlistview.cpp \
  62     ui/indicatorbuttonpanel.cpp \
  63     ui/locationsearchpanel.cpp \
  64     ui/mainwindow.cpp \
  65     ui/mapscale.cpp \
  66     ui/panelbar.cpp \
  67     ui/panelbase.cpp \
  68     ui/panelcontentstack.cpp \
  69     ui/panelcontextbuttonbar.cpp \
  70     ui/paneltab.cpp \
  71     ui/paneltabbar.cpp \
  72     ui/routingpanel.cpp \
  73     ui/routewaypointlistitem.cpp \
  74     ui/routewaypointlistview.cpp \
  75     ui/searchdialog.cpp \
  76     ui/searchhistorylistitem.cpp \
  77     ui/searchhistorylistview.cpp \
  78     ui/settingsdialog.cpp \
  79     ui/tabbedpanel.cpp \
  80     ui/textmodifier.cpp \
  81     ui/userinfo.cpp \
  82     ui/userinfopanel.cpp \
  83     ui/zoombutton.cpp \
  84     ui/zoombuttonpanel.cpp \
  85     user/user.cpp \
  86     ui/listitemcontextbuttonbar.cpp
  87 HEADERS += application.h \
  88     common.h \
  89     coordinates/geocoordinate.h \
  90     coordinates/scenecoordinate.h \
  91     engine/contactmanager.h \
  92     engine/engine.h \
  93     engine/mce.h \
  94     error.h \
  95     facebookservice/facebookauthentication.h \
  96     gps/gpscommon.h \
  97     gps/gpsposition.h \
  98     map/baselocationitem.h \
  99     map/friendgroupitem.h \
 100     map/frienditemshandler.h \
 101     map/friendlocationitem.h \
 102     map/gpslocationitem.h \
 103     map/mapcommon.h \
 104     map/mapengine.h \
 105     map/mapfetcher.h \
 106     map/maprouteitem.h \
 107     map/mapscene.h \
 108     map/mapscroller.h \
 109     map/maptile.h \
 110     map/maptilerequest.h \
 111     map/mapview.h \
 112     map/osm.h \
 113     map/ownlocationitem.h \
 114     network/networkaccessmanager.h \
 115     network/networkcookiejar.h \
 116     network/networkhandler.h \
 117     network/networkreply.h \
 118     routing/geocodingservice.h \
 119     routing/location.h \
 120     routing/route.h \
 121     routing/routesegment.h \
 122     routing/routingcommon.h \
 123     routing/routingservice.h \
 124     situareservice/imagefetcher.h \
 125     situareservice/situarecommon.h \
 126     situareservice/situareservice.h \
 127     ui/updatelocation/texteditautoresizer.h \
 128     ui/updatelocation/updatelocationdialog.h \
 129     ui/avatarimage.h \
 130     ui/extendedlistitem.h \
 131     ui/extendedlistitemdelegate.h \
 132     ui/extendedlistitemstore.h \
 133     ui/friendlistitem.h \
 134     ui/friendlistitemdelegate.h \
 135     ui/friendlistpanel.h \
 136     ui/friendlistview.h \
 137     ui/fullscreenbutton.h \
 138     ui/imagebutton.h \
 139     ui/indicatorbutton.h \
 140     ui/indicatorbuttonpanel.h \
 141     ui/listcommon.h \
 142     ui/listview.h \
 143     ui/listitem.h \
 144     ui/listitemdelegate.h \
 145     ui/locationlistitem.h \
 146     ui/locationlistview.h \
 147     ui/locationsearchpanel.h \
 148     ui/mainwindow.h \
 149     ui/mapscale.h \
 150     ui/panelbar.h \
 151     ui/panelbase.h \
 152     ui/panelcommon.h \
 153     ui/panelcontentstack.h \
 154     ui/panelcontextbuttonbar.h \
 155     ui/paneltab.h \
 156     ui/paneltabbar.h \
 157     ui/routingpanel.h \
 158     ui/routewaypointlistitem.h \
 159     ui/routewaypointlistview.h \
 160     ui/searchdialog.h \
 161     ui/searchhistorylistitem.h \
 162     ui/searchhistorylistview.h \
 163     ui/settingsdialog.h \
 164     ui/tabbedpanel.h \
 165     ui/textmodifier.h \
 166     ui/userinfo.h \
 167     ui/userinfopanel.h \
 168     ui/zoombutton.h \
 169     ui/zoombuttonpanel.h \
 170     user/user.h \
 171     ui/listitemcontextbuttonbar.h
 172 QT += network \
 173     webkit
 174 DEFINES += QT_NO_DEBUG_OUTPUT
 175
 176 simulator {
 177     SOURCES += network/networkhandlerprivatestub.cpp \
 178                gps/gpspositionprivate.cpp \
 179                engine/contactmanagerprivatestub.cpp \
 180                engine/mceprivatestub.cpp
 181     HEADERS += network/networkhandlerprivatestub.h \
 182                gps/gpspositionprivate.h \
 183                engine/contactmanagerprivatestub.h \
 184                engine/mceprivatestub.h
 185     CONFIG += mobility
 186     MOBILITY += location
 187 } else:maemo5 {
 188     armel {
 189         DEFINES += ARMEL
 190         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 191         SOURCES += network/networkhandlerprivate.cpp \
 192                    engine/mceprivate.cpp
 193         HEADERS += network/networkhandlerprivate.h \
 194                    engine/mceprivate.h
 195         QT += dbus xml
 196         CONFIG += icd2 qdbus
 197         SOURCES += gps/gpspositionprivateliblocation.cpp \
 198                    gps/liblocationwrapper.cpp \
 199                    gps/geopositioninfo.cpp
 200         HEADERS += gps/gpspositionprivateliblocation.h \
 201                    gps/liblocationwrapper.h \
 202                    gps/geopositioninfo.h
 203         CONFIG += link_pkgconfig
 204         PKGCONFIG += glib-2.0 liblocation mce gtk+-2.0 libosso-abook-1.0
 205         LIBS += -llocation
 206         SOURCES += engine/contactmanagerprivate.cpp \
 207                    ui/ossoabookdialog.cpp
 208         HEADERS += engine/contactmanagerprivate.h \
 209                    ui/ossoabookdialog.h
 210         CONFIG += mobility
 211         MOBILITY += contacts
 212     } else {
 213         SOURCES += gps/gpspositionprivatestub.cpp \
 214                    network/networkhandlerprivatestub.cpp \
 215                    engine/mceprivatestub.cpp
 216         HEADERS += gps/gpspositionprivatestub.h \
 217                    network/networkhandlerprivatestub.h \
 218                    engine/mceprivatestub.h
 219         SOURCES += engine/contactmanagerprivatestub.cpp
 220         HEADERS += engine/contactmanagerprivatestub.h
 221     }
 222
 223     QT += maemo5
 224
 225     message([QJson])
 226     message(Make sure you have QJson development headers installed)
 227     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 228     message(to Scratchbox's sources.list in /etc/apt)
 229     message(run: apt-get update)
 230     message(install headers with: apt-get install libqjson-dev)
 231     message([QtMobility])
 232     message(Make sure you have QtMobility development headers installed)
 233     message(install headers with: apt-get install libqtm-dev)
 234 } else {
 235     SOURCES += gps/gpspositionprivatestub.cpp \
 236                network/networkhandlerprivatestub.cpp \
 237                engine/mceprivatestub.cpp
 238     HEADERS += gps/gpspositionprivatestub.h \
 239                network/networkhandlerprivatestub.h \
 240                engine/mceprivatestub.h
 241     SOURCES += engine/contactmanagerprivatestub.cpp
 242     HEADERS += engine/contactmanagerprivatestub.h
 243     message(QJson built in)
 244     message(Make sure you have QJson development headers installed)
 245     message(install headers with: sudo apt-get install libqjson-dev)
 246 }
 247
 248 # -----------------------------------------------------------------
 249 # Debian packetizing additions
 250 # -----------------------------------------------------------------
 251 unix {
 252     # VARIABLES
 253     isEmpty(PREFIX):PREFIX = /usr
 254     BINDIR = $$PREFIX/bin
 255     DATADIR = $$PREFIX/share
 256     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 257         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 258
 259     # MAKE INSTALL
 260     desktop.path = $$DATADIR/applications/hildon
 261     desktop.files += situare.desktop
 262     INSTALLS += desktop
 263     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 264     icon48.files += ../res/icon/48x48/situare.png
 265     INSTALLS += icon48
 266     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 267     icon64.files += ../res/icon/64x64/situare.png
 268     INSTALLS += icon64
 269     target.path = $$BINDIR
 270     INSTALLS += target
 271 }