vcs.maemo.org Git - qcpufreq/blob - src/src.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-06-19T23:26:05
   4 #
   5 #-------------------------------------------------
   6
   7 QT       += core gui maemo5
   8
   9 TARGET = QCPUFreq
  10 TEMPLATE = app
  11
  12
  13 SOURCES += main.cpp\
  14         mainwindow.cpp \
  15     helpwindow.cpp \
  16     settings.cpp \
  17     loadpreset.cpp
  18
  19 HEADERS  += mainwindow.h \
  20     helpwindow.h \
  21     settings.h \
  22     loadpreset.h
  23
  24 FORMS    += mainwindow.ui \
  25     helpwindow.ui \
  26     settings.ui \
  27     loadpreset.ui
  28
  29 TRANSLATIONS = de.ts zh.ts
  30
  31 CONFIG += mobility
  32 MOBILITY =
  33
  34 symbian {
  35     TARGET.UID3 = 0xeb3802d4
  36     # TARGET.CAPABILITY +=
  37     TARGET.EPOCSTACKSIZE = 0x14000
  38     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  39 }
  40
  41 unix {
  42         #VARIABLES
  43         isEmpty(PREFIX) {
  44                 PREFIX = /opt/usr
  45         }
  46         BINDIR = $$PREFIX/bin
  47         DATADIR =$$PREFIX/share
  48
  49         DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  50
  51         #MAKE INSTALL
  52
  53         INSTALLS += target helper sudoers desktop icon48 icon64 locale_de locale_zh
  54         target.path =$$BINDIR
  55
  56         desktop.path = /usr/share/applications/hildon
  57         desktop.files += data/$${TARGET}.desktop
  58
  59         icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
  60         icon48.files += data/48x48/qcpufreq.png
  61
  62         icon64.path = $$DATADIR/icons/hicolor/64x64/hildon
  63         icon64.files += data/48x48/qcpufreq.png
  64
  65         helper.path = $$BINDIR/
  66         helper.files += data/scripts/QCPUFreq.helper
  67         helper.permissions = 755
  68
  69         sudoers.path = /etc/sudoers.d/
  70         sudoers.files += data/sudoers/qcpufreq.sudoers
  71
  72         locale_de.path = /opt/usr/share/qcpufreq
  73         locale_de.files += de.qm
  74
  75         locale_zh.path = /opt/usr/share/qcpufreq
  76         locale_zh.files += zh.qm
  77
  78 }
  79
  80 RESOURCES += \
  81     resources.qrc