vcs.maemo.org Git - ptas/blob - zouba/qt4-maemo5/mkspecs/features/win32/qaxcontainer.prf

   1 !debug_and_release|build_pass {
   2    CONFIG(debug, debug|release) {
   3       LIBS += -lQAxContainerd
   4    } else {
   5       LIBS += -lQAxContainer
   6    }
   7 } else {
   8    LIBS += -lQAxContainer
   9 }
  10
  11 isEmpty(QMAKE_DUMPCPP) {
  12     win32:QMAKE_DUMPCPP = $$[QT_INSTALL_BINS]\dumpcpp.exe
  13 }
  14
  15 dumpcpp_decl.commands = $$QMAKE_DUMPCPP ${QMAKE_FILE_IN} -o ${QMAKE_FILE_BASE}
  16 qaxcontainer_compat: dumpcpp_decl.commands += -compat
  17 dumpcpp_decl.output = ${QMAKE_FILE_BASE}.h
  18 dumpcpp_decl.input = TYPELIBS
  19 dumpcpp_decl.variable_out = HEADERS
  20 dumpcpp_decl.name = DUMP
  21 dumpcpp_decl.CONFIG += no_link
  22 dumpcpp_decl.depends = $$QMAKE_DUMPCPP
  23
  24 QMAKE_EXTRA_COMPILERS += dumpcpp_decl
  25
  26
  27 dumpcpp_impl.commands = $$QMAKE_DUMPCPP -donothing
  28 dumpcpp_impl.output = ${QMAKE_FILE_BASE}.cpp
  29 dumpcpp_impl.input = TYPELIBS
  30 dumpcpp_impl.variable_out = SOURCES
  31 dumpcpp_impl.name = CPP
  32 dumpcpp_impl.depends = $$QMAKE_DUMPCPP ${QMAKE_FILE_BASE}.h
  33
  34 QMAKE_EXTRA_COMPILERS += dumpcpp_impl