vcs.maemo.org Git - ptas/blob - zouba/qt4-maemo5/mkspecs/features/symbian/application_icon.prf

   1 load(data_caging_paths)
   2
   3 # If no_icon keyword exist, the S60 UI app is just made hidden. This because S60 app FW
   4 # requires the registration resource file to exist always
   5 contains( CONFIG, no_icon ) {
   6     symbian:RSS_RULES ="hidden = KAppIsHidden;"
   7     CONFIG -= no_icon
   8 } else {
   9 # There is no point in compiling the MIF icon if no_icon CONFIGS is set
  10     !isEmpty(ICON) {
  11
  12         !count(ICON, 1) {
  13             ICON = $$first(ICON)
  14             warning("Only first icon specified in ICON variable is used: $$ICON")
  15         }
  16
  17         # Try to produce indentical string to fixedTarget in SymbianMakefileGenerator, replaced chars taken
  18         # from SymbianMakefileGenerator::removeSpecialCharacters.
  19         #
  20         # Note: it is not a major problem even baseTarget is not 100% identical to fixedTarget since qmake
  21         # only uses filename from RSS_RULES.icon_file when referring to icon file name.
  22         baseTarget = $$basename(TARGET)
  23         baseTarget = $$replace(baseTarget, /,_)
  24         baseTarget = $$replace(baseTarget, \\,_)
  25         baseTarget = $$replace(baseTarget, -,_)
  26         baseTarget = $$replace(baseTarget, :,_)
  27         baseTarget = $$replace(baseTarget, \.,_)
  28         baseTarget = $$replace(baseTarget, " ",_)
  29
  30         # Note: symbian-sbsv2 builds can't utilize extra compiler for mifconv, so ICON handling is done in code
  31         symbian-abld {
  32             #Makefile: requires paths with backslash
  33             ICON = $$replace( ICON, /, \\)
  34
  35             # Extra compiler rules for mifconv
  36             mifconv.output = ${ZDIR}$$APP_RESOURCE_DIR/$${baseTarget}.mif
  37             # Based on: http://www.forum.nokia.com/document/Cpp_Developers_Library
  38             # svg-t icons should always use /c32 depth
  39             mifconv.commands = mifconv ${QMAKE_FILE_OUT} /c32 ${QMAKE_FILE_IN}
  40             mifconv.input = ICON
  41             mifconv.CONFIG = no_link combine
  42             # target_predeps together with combine seems not to work correctly, lets define it by ourselves
  43             PRE_TARGETDEPS += $$mifconv.output
  44             QMAKE_EXTRA_COMPILERS += mifconv
  45         }
  46         # Rules to use generated MIF file from symbian resources
  47         RSS_RULES.number_of_icons = $$size(ICON)
  48         RSS_RULES.icon_file = $$APP_RESOURCE_DIR/$${baseTarget}.mif
  49     }
  50 }
  51