vcs.maemo.org Git - modest/blob - configure.ac

   1 # Copyright (c) 2006,2007 Nokia Corporation
   2 # All rights reserved.
   3 #
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7 #
   8 # * Redistributions of source code must retain the above copyright
   9 #   notice, this list of conditions and the following disclaimer.
  10 # * Redistributions in binary form must reproduce the above copyright
  11 #   notice, this list of conditions and the following disclaimer in the
  12 #   documentation and/or other materials provided with the distribution.
  13 # * Neither the name of the Nokia Corporation nor the names of its
  14 #   contributors may be used to endorse or promote products derived from
  15 #   this software without specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
  18 # IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  19 # TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
  20 # PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER
  21 # OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  22 # EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  23 # PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  24 # PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  25 # LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  26 # NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  27 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28
  29 AC_INIT([modest],[3.90],[http://maemo.org])
  30 AC_CONFIG_HEADERS([config.h])
  31
  32 m4_define([modest_api_major_version], [1])
  33 m4_define([modest_api_minor_version], [99])
  34 m4_define([modest_api_micro_version], [0])
  35 m4_define([modest_api_version], [modest_api_major_version.modest_api_minor_version.modest_api_micro_version])
  36
  37
  38 AC_CONFIG_SRCDIR(src/modest-main.c)
  39 AM_INIT_AUTOMAKE([dist-bzip2])
  40
  41 # Support silent build rules, requires at least automake-1.11. Disable
  42 # by either passing --disable-silent-rules to configure or passing V=1
  43 # to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45
  46 MODEST_API_MAJOR_VERSION=modest_api_major_version
  47 MODEST_API_MINOR_VERSION=modest_api_minor_version
  48 MODEST_API_MICRO_VERSION=modest_api_micro_version
  49 MODEST_API_VERSION=modest_api_version
  50 AC_SUBST(MODEST_API_MAJOR_VERSION)
  51 AC_SUBST(MODEST_API_MINOR_VERSION)
  52 AC_SUBST(MODEST_API_MICRO_VERSION)
  53 AC_SUBST(MODEST_API_VERSION)
  54
  55 ALL_LINGUAS="en_GB"
  56
  57 MODEST_LOCALE_DIR='$prefix/${DATADIRNAME}/locale'
  58 AM_GLIB_DEFINE_LOCALEDIR([MODEST_LOCALE_DIR])
  59 AM_GLIB_GNU_GETTEXT
  60
  61 if test x$prefix = xNONE; then
  62    prefix=/usr/local
  63 fi
  64 AC_SUBST(prefix)
  65
  66 AC_PROG_CC
  67 AC_PROG_CXX
  68 AM_PROG_CC_STDC
  69 AM_PROG_CC_C_O
  70 AC_HEADER_STDC
  71 AC_PROG_LIBTOOL
  72
  73
  74 # Option to enable debugging
  75 AC_ARG_ENABLE(debug,
  76               [AC_HELP_STRING([--enable-debug],[Debugging (default=no)])],
  77               [with_debug=yes], [with_debug=no])
  78
  79 if test "x$with_debug" == "xyes" ; then
  80         CFLAGS="$CFLAGS -ggdb -O0 -DDEBUG -Wall"
  81 else
  82         CFLAGS="$CFLAGS -O2 -Wall"
  83 fi
  84
  85 # Option to enable debugging
  86 AC_ARG_ENABLE(gcov,
  87               [AC_HELP_STRING([--enable-gcov],[Coverage reporting (default=no)])],
  88               [with_gcov=yes], [with_gcov=no])
  89
  90 if test "x$with_gcov" == "xyes" ; then
  91         CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
  92         LDFLAGS="$LDFLAGS -lgcov"
  93 fi
  94
  95 dnl ------
  96 dnl WebKit
  97 dnl ------
  98
  99 # Option to enable debugging
 100 with_webkit=no
 101 AC_ARG_ENABLE(webkit,
 102               [AC_HELP_STRING([--enable-webkit],[Enable webkit support (default=no)])],
 103               [with_webkit=yes], [with_webkit=no])
 104
 105 if test "x$with_webkit" == "xyes" ; then
 106 PKG_CHECK_MODULES(MODEST_WEBKIT,webkit-1.0,have_webkit=true,have_webkit=false)
 107 MODEST_USE_WEBKIT=1
 108 AC_SUBST(MODEST_WEBKIT_CFLAGS)
 109 AC_SUBST(MODEST_WEBKIT_LIBS)
 110 AC_DEFINE_UNQUOTED(MODEST_USE_WEBKIT, 1, ["Whether modest is being build with webkit support."])
 111 AC_SUBST(MODEST_USE_WEBKIT)
 112 fi
 113
 114 dnl -------
 115 dnl GtkHTML
 116 dnl -------
 117
 118 AC_MSG_CHECKING(for installed version of libgtkhtml3)
 119 pkg-config --exists libgtkhtml-3.14
 120 retval=$?
 121 gtk_html_found=false
 122 if test $retval -eq 0 ; then
 123     gtk_html_found=true
 124     gtk_html_version=3.14
 125 else
 126     pkg-config --exists libgtkhtml-3.8
 127     retval=$?
 128     if test $retval -eq 0 ; then
 129       gtk_html_found=true
 130       gtk_html_version=3.8
 131     else
 132           if [ $gui = "true" ]; then
 133             AC_MSG_RESULT(libgtkhtml 3.4 or higher is not found!)
 134           fi
 135     fi
 136 fi
 137
 138 if [ $gtk_html_found = "true" ]; then
 139    version=`pkg-config --modversion libgtkhtml-${gtk_html_version}`
 140    AC_MSG_RESULT(found version $version)
 141 else
 142    AC_MSG_ERROR([install gtkhtml 3.8 or newer])
 143 fi
 144
 145 dnl # GLib/Gobject/Gtk/Gconf => mandatory
 146
 147 PKG_CHECK_MODULES(MODEST_GSTUFF,glib-2.0 >= 2.6 gobject-2.0 gtk+-2.0 >= 2.6 gconf-2.0 gnome-vfs-2.0 libgtkhtml-${gtk_html_version} libtinymail-1.0 libtinymail-camel-1.0 libtinymail-gnomevfs-1.0 libtinymailui-1.0 libtinymailui-gtk-1.0)
 148 AC_SUBST(MODEST_GSTUFF_CFLAGS)
 149 AC_SUBST(MODEST_GSTUFF_LIBS)
 150
 151 modest_save_cflags="$CFLAGS"
 152 modest_save_libs="$LIBS"
 153 PKG_CHECK_MODULES(MODEST_GTKHTML,libgtkhtml-${gtk_html_version})
 154 AC_SUBST(MODEST_GTKHTML_CFLAGS)
 155 AC_SUBST(MODEST_GTKHTML_LIBS)
 156 CFLAGS="$MODEST_GTKHTML_CFLAGS"
 157 LIBS="$MODEST_GTKHTML_LIBS"
 158 AC_CHECK_DECLS([gtk_widget_tap_and_hold_setup],[],[], [#include <gtk/gtk.h>])
 159 AC_CHECK_FUNCS(gtk_html_set_max_image_size)
 160 AC_SUBST(HAVE_GTK_HTML_SET_MAX_IMAGE_SIZE)
 161 AC_CHECK_FUNCS(gtk_html_get_selection_area)
 162 AC_SUBST(HAVE_GTK_HTML_GET_SELECTION_AREA)
 163 AC_CHECK_FUNCS(gtk_html_set_allow_dnd)
 164 AC_SUBST(HAVE_GTK_HTML_SET_ALLOW_DND)
 165 AC_CHECK_FUNCS(gtk_html_set_default_engine)
 166 AC_SUBST(HAVE_GTK_HTML_SET_DEFAULT_ENGINE)
 167 AC_CHECK_FUNCS(gtk_html_set_word_char_wrapping)
 168 AC_SUBST(HAVE_GTK_HTML_SET_WORD_CHAR_WRAPPING)
 169 AC_CHECK_FUNCS(gtk_tree_view_column_get_cell_data_hint)
 170 AC_SUBST(HAVE_GTK_TREE_VIEW_COLUMN_GET_CELL_DATA_HINT)
 171 CFLAGS="$modest_save_cflags"
 172 LIBS="$modest_save_libs"
 173
 174 dnl --------------- PLATFORM -----------
 175 PKG_CHECK_MODULES(MODEST_MAEMO_LIBS,conic,[detected_platform=maemo],[detected_platform=gnome])
 176
 177 AC_ARG_WITH(platform, [
 178 Target platform:
 179   --with-platform=detect  detect target platform (default)
 180   --with-platform=gnome   build for Gnome
 181   --with-platform=maemo   build for Maemo
 182 ],
 183 [case "${with_platform}" in
 184        gnome|maemo|detect)    MODEST_PLATFORM=${with_platform};;
 185        *)        AC_MSG_ERROR([Unknown platform selected]);;
 186 esac], [MODEST_PLATFORM=detect])
 187
 188 if test "$MODEST_PLATFORM" = "detect"; then
 189         MODEST_PLATFORM="$detected_platform"
 190         with_platform=$detected_platform
 191 fi
 192
 193 if test "$with_platform" = "maemo"; then
 194         MODEST_PLUGIN_DEFINES=" -DMODEST_PLATFORM_MAEMO -DMODEST_API_VERSION=${MODEST_API_VERSION}"
 195         PKG_CHECK_MODULES(LIBMODEST_DBUS_CLIENT,libmodest-dbus-client-1.0 >= 3.2.0)
 196 elif test "$with_platform" = "gnome"; then
 197         MODEST_PLUGIN_DEFINES=" -DMODEST_PLATFORM_GNOME -DMODEST_API_VERSION=${MODEST_API_VERSION}"
 198 fi
 199 AC_SUBST(MODEST_PLUGIN_DEFINES)
 200
 201 dnl ---------- PLATFORM: *DBUS API* -----------
 202 if test "x$with_platform" == "xgnome"; then
 203    PKG_CHECK_MODULES(MODEST_PLATFORM,libtinymail-gnome-desktop-1.0 glib-2.0 >= 2.8 libnotify)
 204    AC_DEFINE_UNQUOTED(MODEST_PLATFORM_GNOME, 1, ["Whether modest is being built for the GNOME platform."])
 205 else
 206    have_dbusapi=true
 207    PKG_CHECK_MODULES(MODEST_PLATFORM,libosso dbus-1 libtinymail-maemo-1.0 libebook-1.2 )
 208    AC_DEFINE_UNQUOTED(MODEST_PLATFORM_MAEMO, 1, ["Whether modest is being built for the MAEMO platform."])
 209 fi
 210 AM_CONDITIONAL(MODEST_HAVE_DBUS_API,test "x$have_dbusapi" == "xtrue")
 211 AC_SUBST(MODEST_PLATFORM)
 212
 213
 214 dnl --------------- TOOLKIT SELECTION -----------
 215 AC_ARG_WITH(toolkit, [
 216 Target toolkit:
 217   --with-toolkit=detect  detect target toolkit (default)
 218   --with-toolkit=gtk   build for Gnome
 219   --with-toolkit=hildon2   build for Hildon 2.x
 220 ],
 221 [case "${with_toolkit}" in
 222        gtk|hildon2|detect)    MODEST_TOOLKIT=${with_toolkit};;
 223        *)        AC_MSG_ERROR([Unknown toolkit selected]);;
 224 esac], [MODEST_TOOLKIT=detect])
 225
 226 have_hildon2=false
 227 have_gtk=false
 228
 229 if test "$MODEST_TOOLKIT" = "detect"; then
 230    PKG_CHECK_EXISTS(hildon-1 >= 2.1.0 hildon-fm-2, have_hildon2=true, have_hildon2=false)
 231    PKG_CHECK_EXISTS(glib-2.0 >= 2.8 gtk+-2.0 >= 2.10 libnotify, have_gtk=true, have_gtk=false)
 232    if test "x$have_hildon2" = "xtrue"; then
 233       detected_toolkit=hildon2
 234       hildon_api=`$PKG_CONFIG --modversion hildon-1 | cut -d. -f1`
 235       echo "DETECTED HILDON 2 $have_hildon2 (API is $hildon_api)."
 236    elif test "x$have_gtk" == "xtrue"; then
 237       detected_toolkit=gtk
 238       echo "DETECTED GTK."
 239    fi
 240    MODEST_TOOLKIT="$detected_toolkit"
 241    with_toolkit=$detected_toolkit
 242 fi
 243
 244 dnl -------- TOOLKIT SELECTION: *HILDON API* -----------
 245 if test "x$with_toolkit" == "xhildon2"; then
 246    hildonpkgs="hildon-1 hildon-fm-2"
 247    hildon_api=`$PKG_CONFIG --modversion hildon-1 | cut -d. -f1`
 248    AC_DEFINE_UNQUOTED(MODEST_HILDON_API, $hildon_api, ["the API version of hildon"])
 249    MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_HILDON_API=$hildon_api"
 250    MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_HILDON2"
 251 elif test "x$with_toolkit" == "xgtk"; then
 252      MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_GTK"
 253 fi
 254
 255 dnl -------- TOOLKIT SELECTION: *TOOLKIT DIR* -----------
 256 if test "x$with_toolkit" == "xgtk"; then
 257    PKG_CHECK_MODULES(MODEST_TOOLKIT,glib-2.0 >= 2.8 gtk+-2.0 >= 2.10 libnotify)
 258    AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_GTK, 1, ["Whether modest is being build for the gtk toolkit."])
 259    MODEST_TOOLKIT_DIR=gtk
 260 elif test "$with_toolkit" = "hildon2"; then
 261    AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_HILDON2, 1, ["Whether modest is being build for the hildon2 toolkit."])
 262    MODEST_TOOLKIT_DIR=hildon2
 263 fi
 264 AC_SUBST(MODEST_TOOLKIT)
 265 AC_SUBST(MODEST_TOOLKIT_DIR)
 266
 267
 268 dnl --------------- HILDON & PLUGIN PKGS -----------
 269 pluginpkgs=$hildonpkgs
 270 dnl echo "Plugin Packages $pluginpkgs"
 271 AC_SUBST(pluginpkgs)
 272
 273 use_profile_data=false
 274 # Plugin packages must not include libcanberra and libprofile
 275 if test "x$with_platform" == "xmaemo"; then
 276    hildonpkgs="$hildonpkgs libcanberra"
 277    AC_CHECK_HEADER([profiled/keys_nokia.h], use_profile_data=true, use_profile_data=false)
 278    if test "$use_profile_data" = "true"; then
 279       hildonpkgs="$hildonpkgs profile"
 280       AC_DEFINE_UNQUOTED(MODEST_USE_PROFILE, 1, ["Use the Profile data include"])
 281 dnl      echo "HILDON 2 PACKAGES $hildonpkgs"
 282    fi
 283 fi
 284 AC_SUBST(hildonpkgs)
 285 PKG_CHECK_MODULES(MODEST_TOOLKIT,$hildonpkgs)
 286
 287 dnl -------------------- MAEMO LAUNCHER STUFF ------------
 288 AC_ARG_ENABLE([maemo-launcher],
 289               [AS_HELP_STRING([--enable-maemo-launcher],
 290                               [build with maemo-launcher support])],
 291                               [case "${enableval}" in
 292                                yes) maemo_launcher=true ;;
 293                                no)  maemo_launcher=false ;;
 294                                *) AC_MSG_ERROR([bad value ${enableval} for --enable-maemo-launcher]) ;;
 295                                esac], [maemo_launcher=false])
 296 if test x$maemo_launcher = xtrue
 297 then
 298         PKG_CHECK_MODULES(MAEMO_LAUNCHER, [maemo-launcher-app])
 299         AC_SUBST(MAEMO_LAUNCHER_CFLAGS)
 300         AC_SUBST(MAEMO_LAUNCHER_LIBS)
 301         MAEMO_LAUNCHER_MODEST_LDFLAGS="-shared "
 302 else
 303         MAEMO_LAUNCHER_MODEST_LDFLAGS="-export-dynamic "
 304 fi
 305 AC_SUBST(MAEMO_LAUNCHER_MODEST_LDFLAGS)
 306
 307 dnl --------------- EDITOR -----------
 308 PKG_CHECK_MODULES(MODEST_WPEDITOR,wpeditor,have_wpeditor=true,have_wpeditor=false)
 309 if test "x$have_wpeditor" == "xfalse"; then
 310    PKG_CHECK_MODULES(MODEST_WPEDITOR,libwpeditor-plus,have_libwpeditorplus=true,have_libwpeditorplus=false)
 311    if test "x$have_libwpeditorplus" == "xtrue"; then
 312       wpeditor="libwpeditor-plus"
 313       AC_DEFINE_UNQUOTED(MODEST_HAVE_LIBWPEDITOR_PLUS, 1, ["Whether libwpeditor-plus is used."])
 314    else
 315       AC_MSG_ERROR([you need to have either wpeditor or libwpeditor-plus installed])
 316    fi
 317 else
 318    wpeditor="wpeditor"
 319    AC_DEFINE_UNQUOTED(MODEST_HAVE_WPEDITOR, 1, ["Whether wpeditor is used."])
 320 fi
 321
 322 dnl --------------- LIBALARM -----------
 323 if test "x$with_platform" == "xmaemo"; then
 324    PKG_CHECK_MODULES(MODEST_LIBALARM, alarm, have_libalarm=true,have_libalarm=false)
 325    if test "x$have_libalarm" == "xtrue"; then
 326       AC_DEFINE_UNQUOTED(MODEST_HAVE_LIBALARM, 1, ["Whether libalarm is used."])
 327       AC_SUBST(MODEST_LIBALARM_CFLAGS)
 328       AC_SUBST(MODEST_LIBALARM_LIBS)
 329    fi
 330 fi
 331
 332 dnl --------------- MCE -----------
 333 if test "x$with_platform" == "xmaemo"; then
 334 PKG_CHECK_MODULES(MODEST_MCE,mce,have_mce=true,have_mce=false)
 335 if test "x$have_mce" == "xtrue"; then
 336    mce="mce"
 337    AC_DEFINE_UNQUOTED(MODEST_HAVE_MCE, 1, ["Whether mce is used."])
 338    AC_SUBST(MODEST_MCE_CFLAGS)
 339    AC_SUBST(MODEST_MCE_LIBS)
 340 else
 341    mce=""
 342 fi
 343 fi
 344
 345 dnl --------------- LIBCONIC -----------
 346 dnl check for libconic; this is a trick to check whether we run on a
 347 dnl 'real' maemo platform, or on, say, ubuntu embedded. This determines
 348 dnl whether we build with the non-hildon GTK+
 349
 350 if test "x$with_platform" == "xmaemo"; then
 351 PKG_CHECK_MODULES(MODEST_LIBCONIC,conic,have_libconic=true,have_libconic=false)
 352 if test "x$have_libconic" == "xtrue"; then
 353    AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_GTK,1,["Whether modest is being built with Hildon/Gtk"])
 354    AC_DEFINE_UNQUOTED(MODEST_HAVE_CONIC,1,["Whether modest has conic available"])
 355    AC_SUBST(MODEST_LIBCONIC_CLAGS)
 356    AC_SUBST(MODEST_LIBCONIC_LIBS)
 357 else
 358 # if we define this, tinymail will not try to #include conic headers
 359    CFLAGS="$CFLAGS -DLIBTINYMAIL_MAEMO_WITHOUT_CONIC"
 360 fi
 361 fi
 362
 363 if test "x$with_toolkit" != "xgtk"; then
 364 MODEST_TOOLKIT_CFLAGS="$MODEST_TOOLKIT_CFLAGS -DMAEMO_CHANGES"
 365 fi
 366
 367 dnl --------------- NOTIFICATION STUFF -----------
 368 if test "x$with_toolkit" != "xgtk"; then
 369    PKG_CHECK_MODULES(MODEST_HILDON_NOTIFY,hildon-notify libnotify,have_hildon_notify=true,have_hildon_notify=false)
 370    if test "x$have_hildon_notify" == "xtrue"; then
 371       AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_NOTIFY, 1, ["Whether hildon-notify is available"])
 372    fi
 373 fi
 374
 375 dnl --------------- URI/MIME STUFF -----------
 376 if test "x$with_toolkit" != "xgtk"; then
 377    PKG_CHECK_MODULES(MODEST_HILDON_MIME,libhildonmime,have_hildonmime=true,have_hildonmime=false)
 378    if test "x$have_hildonmime" == "xtrue"; then
 379      mimelib="hildon-mime"
 380      AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_MIME, 1, ["Whether hildon-mime is used."])
 381    fi
 382 fi
 383
 384 dnl --------------- ADDRESSBOOK --------------
 385 if test "x$with_platform" == "xmaemo"; then
 386    PKG_CHECK_MODULES(MODEST_ABOOK, libosso-abook-1.0,have_abook=true,have_abook=false)
 387
 388    if test "x$have_abook" == "xtrue"; then
 389
 390      abook_api=`$PKG_CONFIG --modversion libosso-abook-1.0 | cut -d. -f1`
 391      AC_SUBST(MODEST_ABOOK_CFLAGS)
 392      AC_SUBST(MODEST_ABOOK_LIBS)
 393
 394      modest_save_cflags="$CFLAGS"
 395      modest_save_libs="$LIBS"
 396      CFLAGS="$MODEST_ABOOK_CFLAGS"
 397      LIBS="$MODEST_ABOOK_LIBS"
 398      AC_CHECK_FUNCS(osso_abook_contact_chooser_set_visible_func)
 399      AC_SUBST(HAVE_OSSO_ABOOK_CONTACT_CHOOSER_SET_VISIBLE_FUNC)
 400      CFLAGS="$modest_save_cflags"
 401      LIBS="$modest_save_libs"
 402
 403      AC_DEFINE_UNQUOTED(OSSO_ABOOK_ENABLE_DEPRECATED, 1, ["use deprecated addressbook API"])
 404      AC_DEFINE_UNQUOTED(MODEST_ABOOK_API, $abook_api, ["the API version of osso-addressbook"])
 405      AC_DEFINE_UNQUOTED(MODEST_HAVE_ABOOK, 1, ["whether we have osso-addressbook"])
 406    fi
 407
 408    # Check the presence of the calendar widgets
 409    PKG_CHECK_MODULES(MODEST_CALENDAR_WIDGETS,calendar-ui-widgets,have_calendar_widgets=true,have_calendar_widgets=false)
 410    AC_SUBST(MODEST_CALENDAR_WIDGETS_CFLAGS)
 411    AC_SUBST(MODEST_CALENDAR_WIDGETS_LIBS)
 412    if test "x$have_calendar_widgets" == "xtrue"; then
 413       AC_DEFINE_UNQUOTED(MODEST_USE_CALENDAR_WIDGETS, 1, ["Use the Calendar color widgets"])
 414    fi
 415 fi
 416
 417 AM_CONDITIONAL(MODEST_USE_DUMMY_ADDRESS_BOOK,test "x$have_abook" != "xtrue")
 418
 419 dnl --------------- LIBTIME --------------
 420 AC_CHECK_HEADERS([clockd/libtime.h], have_libtime=true, have_libtime=false)
 421
 422 if test "x$have_libtime" == "xtrue"; then
 423    AC_DEFINE_UNQUOTED(MODEST_USE_LIBTIME, 1, ["use libtime API"])
 424    MODEST_LIBTIME_LIBS=-ltime
 425 else
 426    MODEST_LIBTIME_LIBS=
 427 fi
 428 AC_SUBST(MODEST_LIBTIME_LIBS)
 429
 430 dnl --------------- IPHB --------------
 431 AC_CHECK_HEADERS([iphbd/libiphb.h], have_libiphb=true, have_libiphb=false)
 432
 433 if test "x$have_libiphb" == "xtrue"; then
 434    AC_DEFINE_UNQUOTED(MODEST_USE_IPHB, 1, ["use IP Heartbeat API"])
 435    MODEST_LIBIPHB_LIBS=-liphb
 436 else
 437    MODEST_LIBIPHB_LIBS=
 438 fi
 439 AC_SUBST(MODEST_LIBIPHB_LIBS)
 440
 441
 442 dnl --------------- GETTEXT --------------
 443 AM_GLIB_GNU_GETTEXT
 444 IT_PROG_INTLTOOL([0.35.0])
 445
 446 GETTEXT_PACKAGE=modest
 447 AC_SUBST(GETTEXT_PACKAGE)
 448 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", ["gettext package"])
 449
 450
 451 dnl --------------- SETTINGS FOR MAEMO --------------
 452 if test "x$with_platform" == "xmaemo"; then
 453
 454   # warnings are errors, but don't check format errors, because
 455   # it breaks with logical ids
 456   CFLAGS="$CFLAGS -Wno-format-extra-args -Werror"
 457
 458    desktopentrydir=`$PKG_CONFIG osso-af-settings --variable=desktopentrydir`
 459    serviceentrydir=`$PKG_CONFIG dbus-glib-1 --variable=prefix`/share/dbus-1/services
 460    localedir=`$PKG_CONFIG osso-af-settings --variable=localedir`
 461    backupsettingsdir=/etc/osso-backup/applications
 462    prebackupdir=/etc/osso-backup/pre-backup.d/
 463    restoredir=/etc/osso-backup/restore.d/always/
 464    ossocudscriptsdir=/etc/osso-cud-scripts
 465    pixmapdir=`$PKG_CONFIG osso-af-settings --variable=hildonpixmapdir`
 466    icon_26x26dir=$datadir/icons/hicolor/26x26/hildon
 467    icon_34x34dir=$datadir/icons/hicolor/34x34/hildon
 468    icon_40x40dir=$datadir/icons/hicolor/40x40/hildon
 469    icon_50x50dir=$datadir/icons/hicolor/50x50/hildon
 470    icon_scalabledir=$datadir/icons/hicolor/scalable/hildon
 471    pluginlibdir=`$PKG_CONFIG hildon-control-panel --variable=plugindir`
 472    plugindesktopentrydir=`$PKG_CONFIG hildon-control-panel --variable=plugindesktopentrydir`
 473
 474    dbus_api="dbus_api"
 475    AC_SUBST(dbus_api)
 476
 477    # Define as variables in Makefiles
 478    AC_SUBST(desktopentrydir)
 479    AC_SUBST(serviceentrydir)
 480    AC_SUBST(backupsettingsdir)
 481    AC_SUBST(prebackupdir)
 482    AC_SUBST(restoredir)
 483    AC_SUBST(ossocudscriptsdir)
 484    AC_SUBST(localedir)
 485    AC_SUBST(pixmapdir)
 486    AC_SUBST(icon_26x26dir)
 487    AC_SUBST(icon_34x34dir)
 488    AC_SUBST(icon_40x40dir)
 489    AC_SUBST(icon_50x50dir)
 490    AC_SUBST(icon_scalabledir)
 491    AC_SUBST(pluginlibdir)
 492    AC_SUBST(plugindesktopentrydir)
 493
 494 fi
 495
 496 dnl --------------- TESTING -------------------
 497 build_tests=false
 498 AC_ARG_ENABLE(tests,
 499 AC_HELP_STRING([--enable-tests],
 500         [Build tests (no, yes)]),
 501 [case "${enableval}" in
 502       yes)
 503         build_tests=true ;;
 504       *) build_tests=false ;;
 505 esac],[build_tests=false])
 506 AM_CONDITIONAL(BUILD_TESTS, test x$build_tests = xtrue)
 507
 508 if test x$build_tests = xtrue; then
 509    PKG_CHECK_MODULES(CHECK, check >= 0.9.4 glib-2.0)
 510 fi
 511
 512 dnl ------------ TESTING: GTK-DOC ----------
 513 build_docs=false
 514 AC_ARG_ENABLE(docs,
 515 AC_HELP_STRING([--enable-docs],
 516         [Build documentation (yes, no)]),
 517 [case "${enableval}" in
 518       yes)
 519         build_docs=true ;;
 520       *) build_docs=false ;;
 521 esac],[build_docs=false])
 522 AM_CONDITIONAL(BUILD_DOCS, test x$build_docs = xtrue)
 523
 524 GTK_DOC_CHECK([1.0])
 525
 526 dnl ---------------- OUTPUT --------------
 527 AC_OUTPUT([
 528 po/Makefile.in
 529 Makefile
 530 man/Makefile
 531 src/Makefile
 532 src/modest-plugin-1.0.pc
 533 src/dbus_api/Makefile
 534 src/gtk/Makefile
 535 src/hildon2/Makefile
 536 src/widgets/Makefile
 537 docs/Makefile
 538 docs/reference/Makefile
 539 tests/Makefile
 540 tests/dbus_api/Makefile
 541 src/hildon2/modest.desktop
 542 src/hildon2/com.nokia.modest.service
 543 ])
 544
 545
 546 echo
 547 echo "modest configure results"
 548 echo "-----------------------------------"
 549 echo "Platform         : $with_platform"
 550 echo "Toolkit          : $with_toolkit"
 551 echo "Prefix           : ${prefix}"
 552 echo "Build tests      : $build_tests"
 553 echo "Build docs       : $build_docs"
 554 echo "Gettext Package  : $GETTEXT_PACKAGE"
 555
 556 if test "x$with_platform" == "xmaemo"; then
 557    echo "Maemo Launcher   : $maemo_launcher"
 558    echo "Editor lib       : $wpeditor"
 559    echo "Addressbook      : $have_abook"
 560    echo "libconic support : $have_libconic"
 561    echo "Alarm            : $have_libalarm"
 562    echo "MCE              : $have_mce"
 563    echo "Hildon-Notify    : $have_hildon_notify"
 564    echo "Calendar widgets : $have_calendar_widgets"
 565 fi
 566
 567 if [ $gtk_html_found = "true" ]; then
 568    echo "GtkHTML version  : $gtk_html_version"
 569 fi
 570 echo "Libtime          : $have_libtime"
 571
 572 echo "CFLAGS           : $CFLAGS"
 573 echo "Debug version    : $with_debug"
 574 echo ""
 575 echo "NOTE: you should do a 'make clean' after changing architecture or platform (--with-platform=)"
 576 echo ""