vcs.maemo.org Git - gnuplot/blob - demo/world2.dem

   1 #
   2 # Plot of location on globe,
   3 # this time with labels color-coded by explicit 4th input column
   4 # Requires EAM_DATASTRINGS
   5 #
   6 set dummy u,v
   7 set angles degrees
   8 set parametric
   9 set view 60, 136, 1.22, 1.26
  10 set samples 64,64
  11 set isosamples 13,13
  12 set mapping spherical
  13 unset xtics
  14 unset ytics
  15 unset ztics
  16 set border 0
  17 set title "Labels colored by GeV plotted in spherical coordinate system"
  18 set urange [ -90.0000 : 90.0000 ] noreverse nowriteback
  19 set vrange [ 0.00000 : 360.000 ] noreverse nowriteback
  20 set cblabel "GeV"
  21 set cbrange [0:8]
  22 set colorb vert user size 0.02, 0.75
  23 unset hidden
  24 splot cos(u)*cos(v),cos(u)*sin(v),sin(u) notitle with lines lt 5, \
  25       'world.dat' notitle with lines lt 2, \
  26       'srl.dat' using 3:2:(1):1:4 with labels notitle point pt 6 lw .1 left offset 1,0 font "Helvetica,7" tc pal
  27 pause -1 "Same plot with hidden line removal"
  28 set title "Labels with hidden line removal"
  29 set hidden nooffset
  30 replot
  31 pause -1 "Hit return to continue"