vcs.maemo.org Git - gnuplot/blob - demo/gnuplot.rot

   1 # A generic rotation routine for the gnuplot view.  In the commands
   2 # that load this file, the following should be defined:
   3 #
   4 # iteration_count:  set iteration_count=0
   5 #
   6 # limit_iterations:  if set to a nonzero value, it'll stop after that
   7 #     many iterations; if zero value, continues indefinitely
   8 #
   9 # xrot:  the initial x rotation of the view
  10 #
  11 # xrot_delta:  the amount to increment the x rotation for each new plot
  12 #
  13 # xview:  function for generating x view value; for example
  14 #     xview(xrot)=(50.+30.*sin((xrot%180)/180.*pi))
  15 #
  16 # zrot:  the initial z rotation of the view
  17 #
  18 # zrot_delta:  the amount to increment the z rotation for each new plot
  19 #
  20 # zview:  function for generating z view value; for example
  21 #     zview(zrot)=(60.+45.*sin(zrot/180.*pi))
  22 #
  23 # History:
  24 #   - 1. 1. 2006 Dan Sebald:  Made more generic so other demos could use
  25 #   - ?. ?. ?    Hans-Bernhard Broeker:  Used to just turn round and round
  26 #                by somewhat large steps. Now, it tumbles back and forth
  27 #                smoothly.
  28 #   - ?. ?. ?    ?:  Initial recursive script
  29
  30 iteration_count=iteration_count+1
  31 if ((!limit_iterations) || (iteration_count<=limit_iterations)) \
  32   set view xview(xrot),zview(zrot); \
  33   replot; \
  34   zrot=(zrot+zrot_delta)%360; \
  35   xrot=(xrot+xrot_delta)%360; \
  36   reread