vcs.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml sql network
   2
   3 INCLUDEPATH += $$PWD \
   4     $$PWD/model \
   5     $$PWD/widgets
   6
   7 SOURCES += \
   8     main.cpp \
   9     mainwindow.cpp \
  10     bookview.cpp \
  11     model/unzip/unzip.c \
  12     model/unzip/ioapi.c \
  13     model/extractzip.cpp \
  14     model/library.cpp \
  15     model/book.cpp \
  16     librarydialog.cpp \
  17     devtools.cpp \
  18     infodialog.cpp \
  19     widgets/translucentbutton.cpp \
  20     settingswindow.cpp \
  21     model/settings.cpp \
  22     bookmarksdialog.cpp \
  23     model/sortedlibrary.cpp \
  24     bookmarkinfodialog.cpp \
  25     widgets/dyalog.cpp \
  26     chaptersdialog.cpp \
  27     fullscreenwindow.cpp \
  28     trace.cpp \
  29     widgets/toolbuttonbox.cpp \
  30     model/bookfinder.cpp \
  31     widgets/listwindow.cpp \
  32     widgets/progress.cpp \
  33     adopterwindow.cpp \
  34     platform.cpp \
  35     model/bookdb.cpp \
  36     searchdialog.cpp \
  37     search.cpp \
  38     widgets/flickable.cpp \
  39     searchresultsdialog.cpp \
  40     searchresultinfodialog.cpp \
  41     widgets/progressdialog.cpp \
  42     widgets/splash.cpp
  43
  44 HEADERS += \
  45     mainwindow.h \
  46     bookview.h \
  47     model/opshandler.h \
  48     model/unzip/unzip.h \
  49     model/unzip/ioapi.h \
  50     model/extractzip.h \
  51     model/library.h \
  52     model/book.h \
  53     librarydialog.h \
  54     devtools.h \
  55     infodialog.h \
  56     widgets/translucentbutton.h \
  57     settingswindow.h \
  58     model/settings.h \
  59     bookmarksdialog.h \
  60     model/xmlerrorhandler.h \
  61     model/containerhandler.h \
  62     model/sortedlibrary.h \
  63     model/ncxhandler.h \
  64     bookmarkinfodialog.h \
  65     widgets/dyalog.h \
  66     chaptersdialog.h \
  67     fullscreenwindow.h \
  68     trace.h \
  69     widgets/toolbuttonbox.h \
  70     model/bookfinder.h \
  71     widgets/listwindow.h \
  72     widgets/progress.h \
  73     adopterwindow.h \
  74     model/xmlhandler.h \
  75     platform.h \
  76     model/bookdb.h \
  77     searchdialog.h \
  78     search.h \
  79     widgets/flickable.h \
  80     searchresultsdialog.h \
  81     searchresultinfodialog.h \
  82     widgets/progressdialog.h \
  83     widgets/splash.h
  84
  85 RESOURCES += \
  86     dorian.qrc
  87
  88 OTHER_FILES += \
  89     TODO.txt \
  90     pkg/acknowledgements.txt \
  91     pkg/maemo/postinst \
  92     pkg/maemo/dorian.desktop \
  93     pkg/maemo/control \
  94     pkg/maemo/changelog \
  95     pkg/maemo/build.sh \
  96     styles/night.css \
  97     pkg/changelog \
  98     pkg/maemo/build-scratchbox.sh \
  99     styles/sand.css \
 100     styles/default.css \
 101     pkg/version.txt \
 102     styles/sand.js \
 103     styles/night.js \
 104     styles/default.js \
 105     styles/day.js \
 106     www/index.html \
 107     pkg/maemo/autobuild.sh \
 108     pkg/maemo/autobuild-scratchbox.sh \
 109     LICENSE.txt \
 110     pkg/symbian/book.svg
 111
 112 DEFINES += \
 113     USE_FILE32API
 114
 115 !symbian {
 116     DEFINES += DORIAN_TEST_MODEL
 117     include(model/modeltest/modeltest.pri)
 118 }
 119
 120 unix {
 121     symbian {
 122     } else {
 123         LIBS += -lz
 124     }
 125 }
 126
 127 win32 {
 128     DEFINES += ZLIB_WINAPI
 129     INCLUDEPATH += $$PWD/model/zlib
 130     LIBS += pkg/win32/zlibstat.lib
 131 }
 132
 133 symbian {
 134     TARGET = Dorian
 135     TARGET.UID3 = 0xA89FC85B
 136     TARGET.CAPABILITY = UserEnvironment NetworkServices ReadUserData \
 137         WriteUserData
 138     TARGET.EPOCHEAPSIZE = 0x080000 0x4000000
 139     ICON = $$PWD/pkg/symbian/book.svg
 140     # packageheader = "$${LITERAL_HASH}{\"Dorian\"}, (0xA89FC85B), 0, 3, 6"
 141     # my_deployment.pkg_prerules = packageheader
 142     # DEPLOYMENT += my_deployment
 143
 144     INCLUDEPATH += $(QTDIR)/src/3rdparty/zlib
 145     HEADERS += \
 146         widgets/flickcharm.h \
 147         widgets/mediakeysobserver.h
 148     SOURCES += \
 149         widgets/flickcharm.cpp \
 150         widgets/mediakeysobserver.cpp
 151     LIBS += -lremconinterfacebase -lremconcoreapi
 152 }
 153
 154 maemo5 {
 155     QT += maemo5 dbus
 156     isEmpty(PREFIX) {
 157         PREFIX = /usr
 158     }
 159     BINDIR = $$PREFIX/bin
 160     DATADIR =$$PREFIX/share
 161     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 162
 163     # For "make install"
 164
 165     INSTALLS += target desktop icon48 iconscalable
 166
 167     target.path = $$BINDIR
 168
 169     desktop.path = $$DATADIR/applications/hildon
 170     desktop.files += pkg/maemo/dorian.desktop
 171
 172     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 173     icon48.files += pkg/maemo/icon-48/dorian.png
 174
 175     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 176     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 177 }