vcs.maemo.org Git - cuteexplorer/blob - cuteexplorer/src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-01-13T19:38:20
   3 # -------------------------------------------------
   4 TARGET = cuteexplorer
   5 TEMPLATE = app
   6 QT += dbus
   7 SOURCES += main.cpp \
   8     mainwindow.cpp \
   9     filelistwidget.cpp \
  10     searchdialog.cpp
  11 HEADERS += mainwindow.h \
  12     filelistwidget.h \
  13     searchdialog.h
  14 FORMS += mainwindow.ui \
  15     searchdialog.ui
  16 TRANSLATIONS += cuteexplorertranslation_fi_FI.ts
  17 RESOURCES += i18n.qrc
  18 DEFINES += CUTE_VERSION=\\\"1.2\\\"
  19 maemo5 {
  20     # VARIABLES
  21     CONFIG += link_pkgconfig
  22     PKGCONFIG += dbus-1 \
  23         gnome-vfs-2.0
  24     LIBS += -lhildonmime \
  25         -ldbus-1
  26     isEmpty(PREFIX):PREFIX = /usr
  27     BINDIR = $$PREFIX/bin
  28     DATADIR = $$PREFIX/share
  29     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  30         PKGDATADIR=\\\"$$PKGDATADIR\\\"
  31
  32     # MAKE INSTALL
  33     INSTALLS += target \
  34         desktop \
  35         icon \
  36         icon64
  37     target.path = $$BINDIR
  38     desktop.path = $$DATADIR/applications/hildon
  39     desktop.files += $${TARGET}.desktop
  40     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
  41     icon64.files += $${TARGET}_icon64.png
  42     icon.path = $$DATADIR/icons/hicolor/scalable/apps
  43     icon.files += $${TARGET}_icon.svg
  44 }