vcs.maemo.org Git - cinaest/blob - src/plugins/imdb-plugin.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 class IMDbPlugin : Plugin {
  23         private dynamic DBus.Object server;
  24         List<MovieSource> sources;
  25         private weak Osso.Context osso_context;
  26
  27         public override void hello (Gtk.Window window, Osso.Context context) {
  28                 string filename = Path.build_filename (Environment.get_user_cache_dir(),
  29                                                        "cinaest", "imdb.db", null);
  30                 stdout.printf ("IMDb Plugin Loaded. Cache Db: %s\n", filename);
  31
  32                 if (!FileUtils.test (filename, FileTest.EXISTS)) {
  33                         var note = new Note.confirmation (window, "There is no local copy of the Internet Movie Database (IMDb). Download it now?\n\nThis can be started later from the Settings dialog.");
  34
  35                         var response = note.run ();
  36                         note.destroy ();
  37
  38                         if (response == ResponseType.OK) {
  39                                 download_imdb (window, false);
  40                         }
  41                 }
  42
  43                 var source = new IMDBSource ();
  44
  45                 sources = new List<MovieSource> ();
  46                 sources.append (source);
  47
  48                 osso_context = context;
  49
  50                 // FIXME - this forces the inclusion of config.h
  51                 (void) Config.GETTEXT_PACKAGE;
  52         }
  53
  54         private void download_imdb (Gtk.Window window, bool plots) {
  55                 var picker = new PickerDialog (window);
  56                 var selector = new TouchSelector.text ();
  57                 string[] mirrors;
  58
  59                 try {
  60                         var conn = DBus.Bus.get (DBus.BusType.SESSION);
  61                         server = conn.get_object (IMDbDownloader.DBUS_SERVICE,
  62                                                   IMDbDownloader.DBUS_OBJECT,
  63                                                   IMDbDownloader.DBUS_IFACE);
  64
  65                         mirrors = server.get_mirrors ();
  66                 } catch (DBus.Error e) {
  67                         warning ("Failed connect to IMDb downloader: %s", e.message);
  68                         return;
  69                 }
  70
  71                 foreach (string mirror in mirrors) {
  72                         selector.append_text (mirror);
  73                 }
  74
  75                 picker.set_title ("Please select a source mirror");
  76                 picker.set_selector (selector);
  77
  78                 int res = picker.run();
  79                 string mirror = selector.get_current_text ();
  80                 picker.destroy();
  81
  82                 if (res == ResponseType.OK) {
  83                         var download = new IMDbDownloadDialog (window, plots);
  84                         download.run (server, mirror);
  85                         download.destroy ();
  86                 }
  87         }
  88
  89         public override unowned List<MovieSource> get_sources () {
  90                 return sources;
  91         }
  92
  93         public override List<MovieAction> get_actions (Movie movie, Gtk.Window window) {
  94                 List<MovieAction> list = null;
  95
  96                 if (movie.year > 0)
  97                         list.append (new MovieAction (_("IMDb page"), on_visit_imdb, movie, window));
  98                 else
  99                         list.append (new MovieAction (_("Lookup on IMDb"), on_visit_imdb, movie, window));
 100
 101                 return list;
 102         }
 103
 104         private void on_visit_imdb (Movie movie, Gtk.Window window) {
 105                 var url = "http://www.imdb.com/find?s=tt&q=" + movie.title.replace(" ", "+");
 106                 if (movie.year > 0)
 107                         url += "+(%d)".printf (movie.year);
 108
 109                 var status = osso_context.rpc_run_with_defaults ("osso_browser", "open_new_window", null, 's', url, 'b', false);
 110                 if (status != Osso.Status.OK) {
 111                         var banner = (Banner) Hildon.Banner.show_information_with_markup (window, null, "Failed to open browser.");
 112                         banner.set_timeout (1500);
 113                 }
 114         }
 115
 116         public override void settings_dialog (Gtk.Window window) {
 117                 var dialog = new Gtk.Dialog ();
 118                 dialog.set_transient_for (window);
 119                 dialog.set_title (_("IMDb plugin settings"));
 120
 121                 bool download_plots;
 122                 try {
 123                         var sqlite = new IMDbSqlite (Path.build_filename (Environment.get_user_cache_dir (),
 124                                                      "cinaest", "imdb.db", null));
 125                         download_plots = sqlite.has_plots ();
 126                 } catch (Error e) {
 127                         download_plots = false;
 128                 }
 129
 130                 var plots = new Hildon.CheckButton (SizeType.FINGER_HEIGHT);
 131                 plots.set_label (_("Download and store movie plots"));
 132                 plots.set_active (download_plots);
 133
 134                 string updated;
 135                 string filename = Path.build_filename (Environment.get_user_cache_dir(),
 136                                                        "cinaest", "imdb.db", null);
 137                 var file = File.new_for_path (filename);
 138                 try {
 139                         var info = file.query_info (FILE_ATTRIBUTE_TIME_MODIFIED, FileQueryInfoFlags.NONE, null);
 140                         TimeVal tv;
 141                         info.get_modification_time (out tv);
 142
 143                         var date = Date ();
 144                         date.set_time_val (tv);
 145                         char[] s = new char[64];
 146                         date.strftime (s, "%x");
 147                         updated = (string) s;
 148                 } catch (Error e) {
 149                         updated = _("unknown");
 150                 }
 151
 152                 var download = new Hildon.Button.with_text (SizeType.FINGER_HEIGHT, ButtonArrangement.VERTICAL, _("Download"), _("Last update: ") + updated);
 153
 154                 VBox content = (VBox) dialog.get_content_area ();
 155                 content.pack_start (plots, true, true, 0);
 156                 content.pack_start (download, true, true, 0);
 157
 158                 // Connect signals
 159                 plots.toggled.connect (() => {
 160                         if (download_plots != plots.get_active ())
 161                                 Hildon.Banner.show_information (window, null, _("Redownload the IMDb for this change to take effect."));
 162                 });
 163                 download.clicked.connect (() => {
 164                         download_imdb (window, plots.get_active ());
 165                 });
 166
 167                 dialog.show_all ();
 168                 dialog.run ();
 169                 dialog.destroy ();
 170         }
 171
 172         public override unowned string get_name () {
 173                 return "IMDb";
 174         }
 175 }
 176
 177 class IMDbMovie : Movie {
 178         public override string get_plot () {
 179                 var sqlite = new IMDbSqlite (Path.build_filename (Environment.get_user_cache_dir (),
 180                                              "cinaest", "imdb.db", null));
 181                 print ("IMDb get_plot(\"%s (%d)\")\n", title, year);
 182                 return sqlite.get_plot ("%s (%d)".printf (title, year));
 183         }
 184 }
 185
 186 class IMDBSource : MovieSource {
 187         public override bool active { get; set construct; }
 188
 189         public IMDBSource () {
 190                 GLib.Object (active: true);
 191         }
 192
 193         MovieSource.ReceiveMovieFunction _get_callback;
 194         public override async int get_movies (MovieFilter filter, MovieSource.ReceiveMovieFunction callback, int limit, Cancellable? cancellable) {
 195                 var sqlite = new IMDbSqlite (Path.build_filename (Environment.get_user_cache_dir (),
 196                                              "cinaest", "imdb.db", null));
 197
 198                 _get_callback = callback;
 199                 int n = yield sqlite.query (filter, receive_movie, limit, cancellable);
 200                 return n;
 201         }
 202
 203         private void receive_movie (string title, string? aka, int year, int rating, int genres) {
 204                 var movie = new IMDbMovie ();
 205                 movie.title = title;
 206                 movie.year = year;
 207                 movie.rating = rating;
 208                 movie.genres.field = genres;
 209                 // TODO - depending on settings, this could be something else, like director info or runtime
 210                 if (aka != null) {
 211                         movie.secondary = "aka \"%s\" - %s".printf (aka, movie.genres.to_string ());
 212                 } else {
 213                         movie.secondary = movie.genres.to_string ();
 214                 }
 215                 _get_callback (movie);
 216         }
 217
 218         public override void add_movie (Movie movie) {
 219         }
 220
 221         public override void delete_movie (Movie movie) {
 222         }
 223
 224         public override unowned string get_name () {
 225                 return "IMDb";
 226         }
 227
 228         public override unowned string get_description () {
 229                 return _("Movies on IMDb");
 230         }
 231
 232         public override bool get_editable () {
 233                 return false;
 234         }
 235 }
 236
 237 [ModuleInit]
 238 public Type register_plugin (TypeModule module) {
 239         // types are registered automatically
 240         return typeof (IMDbPlugin);
 241 }