vcs.maemo.org Git - cinaest/blob - src/movie-list-window.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListWindow : StackableWindow {
  23         private MovieListMenu menu;
  24         private Hildon.EditToolbar edit_toolbar;
  25         private Hildon.Entry search_field;
  26         private Toolbar search_bar;
  27         private uint source_id;
  28         private MovieListView movie_list;
  29         private MovieFilter filter;
  30         private MovieListStore store;
  31         private Label no_movies;
  32         private bool search_bar_visible;
  33         private MovieWindow movie_window;
  34         private Alignment alignment;
  35         private int count;
  36         private MovieSource source;
  37         private bool portrait_mode;
  38
  39         public MovieListWindow (MovieSource source_) {
  40                 source = source_;
  41                 set_title (source.get_name ());
  42
  43                 // View menu
  44                 menu = new MovieListMenu (this);
  45                 menu.source = source;
  46
  47                 set_main_menu (menu);
  48
  49                 // Search bar
  50                 search_field = new Hildon.Entry (SizeType.FINGER_HEIGHT);
  51
  52                 var search_field_item = new ToolItem ();
  53                 search_field_item.set_expand (true);
  54                 search_field_item.add (search_field);
  55
  56                 var icon_theme = Gtk.IconTheme.get_default ();
  57                 var pixbuf = icon_theme.load_icon ("general_close",
  58                                                    48,
  59                                                    Gtk.IconLookupFlags.NO_SVG);
  60                 var close_image = new Image.from_pixbuf (pixbuf);
  61                 var close_button = new ToolButton (close_image, _("Close"));
  62
  63                 search_bar = new Toolbar ();
  64                 search_bar.insert (search_field_item, 0);
  65                 search_bar.insert (close_button, 1);
  66                 search_bar.show_all ();
  67
  68                 add_toolbar (search_bar);
  69
  70                 // Movie list - connected to menu for sorting
  71                 movie_list = new MovieListView (this, source.get_name () == _("Watched movies"));
  72                 menu.store = movie_list.store;
  73                 store = movie_list.store;
  74                 store.source = source;
  75
  76                 no_movies = new Label (_("No movies"));
  77                 Hildon.helper_set_logical_font (no_movies, "LargeSystemFont");
  78                 Hildon.helper_set_logical_color (no_movies, RcFlags.FG, StateType.NORMAL, "SecondaryTextColor");
  79                 no_movies.set_size_request (-1, 6 * 70);
  80                 no_movies.set_alignment ((float) 0.5, (float) 0.42);
  81
  82                 var vbox = new VBox (false, 0);
  83                 vbox.pack_start (movie_list, true, true, 0);
  84                 vbox.pack_start (no_movies, false, false, 0);
  85
  86                 alignment = new Alignment (0.0f, 0.0f, 1.0f, 1.0f);
  87                 alignment.top_padding = MARGIN_HALF;
  88
  89                 // Reduced padding in portrait mode to fit 3 posters in width
  90                 int padding = portrait_mode ? MARGIN_DEFAULT : MARGIN_DOUBLE;
  91                 alignment.left_padding = padding;
  92                 alignment.right_padding = padding;
  93
  94                 alignment.add (vbox);
  95                 add (alignment);
  96
  97                 edit_toolbar = new Hildon.EditToolbar.with_text (_("Select movies"), _("Delete"));
  98                 set_edit_toolbar (edit_toolbar);
  99
 100                 // Connect signals
 101                 menu.filter_changed.connect (on_filter_changed);
 102                 edit_toolbar.button_clicked.connect (on_delete_button_clicked);
 103                 edit_toolbar.arrow_clicked.connect (leave_edit_mode);
 104                 search_field.changed.connect (on_search_field_changed);
 105                 close_button.clicked.connect (on_close_button_clicked);
 106                 key_press_event.connect (on_key_press_event);
 107                 movie_list.movie_activated.connect (on_movie_activated);
 108                 store.row_deleted.connect (on_row_deleted);
 109                 store.row_inserted.connect (on_row_inserted);
 110                 Gdk.Screen.get_default ().size_changed.connect (on_orientation_changed);
 111                 store.search_finished.connect (on_search_finished);
 112
 113                 store.notify["update-running"].connect (on_update_running_changed);
 114
 115                 search_field.set_flags (WidgetFlags.CAN_DEFAULT);
 116                 search_field.grab_default ();
 117
 118                 alignment.show_all ();
 119                 edit_toolbar.hide ();
 120                 search_bar_visible = false;
 121                 search_bar.hide ();
 122
 123                 filter = new MovieFilter ();
 124                 menu.filter = filter;
 125                 filter.title = "";
 126                 if (SourceFlags.NOEMPTY in source.get_flags ()) {
 127                         no_movies.hide ();
 128                         search_bar_visible = true;
 129                         search_bar.show ();
 130                         search_field.grab_focus ();
 131                         return;
 132                 }
 133                 if (store.start_search (filter)) {
 134                         no_movies.hide ();
 135                 } else {
 136                         movie_list.hide ();
 137                 }
 138         }
 139
 140         private void on_filter_changed () {
 141                 var markup = new StringBuilder ();
 142                 if (filter.year_min != 0 || filter.year_max != 0)
 143                         markup.append (_(" - years"));
 144                 if (filter.rating_min != 0)
 145                         markup.append (_(" - rating"));
 146                 if (filter.genres.field != 0)
 147                         markup.append (_(" - genres"));
 148                 if (markup.str.length > 0) {
 149                         Gdk.Color color;
 150                         this.ensure_style ();
 151                         if (this.style.lookup_color ("ActiveTextColor", out color)) {
 152                                 markup.prepend ("<span fgcolor=\"%s\">".printf (color.to_string ()));
 153                                 markup.append ("</span>");
 154                         }
 155                         markup.prepend (source.get_name ());
 156                         set_markup (markup.str);
 157                 } else {
 158                         set_markup (source.get_name ());
 159                 }
 160
 161                 start_search ();
 162         }
 163
 164         public void on_delete_movies_clicked () {
 165                 fullscreen ();
 166                 edit_toolbar.show ();
 167                 movie_list.set_hildon_ui_mode (UIMode.EDIT);
 168
 169                 movie_list.unselect_all ();
 170         }
 171
 172         private void on_delete_button_clicked () {
 173                 var movies = movie_list.get_selected_movies ();
 174                 int count = (int) movies.length ();
 175                 if (count == 0) {
 176                         Banner.show_information (this, null, _("No movies selected"));
 177                         leave_edit_mode ();
 178                         return;
 179                 }
 180
 181                 var dialog = new Note.confirmation (this,
 182                                                     ngettext ("Delete %d movie?",
 183                                                               "Delete %d movies?",
 184                                                               count).printf (count));
 185                 var res = dialog.run ();
 186
 187                 if (res == Gtk.ResponseType.OK) {
 188                         // Remove selected movies
 189                         foreach (Movie movie in movies) {
 190                                 store.remove (movie);
 191                         }
 192
 193                         // Switch to "No movies" label if the store is emptied
 194                         TreeIter iter;
 195                         if (!store.get_iter_first (out iter)) {
 196                                 movie_list.hide ();
 197                                 no_movies.show ();
 198                         }
 199                 }
 200                 dialog.destroy ();
 201                 leave_edit_mode ();
 202         }
 203
 204         private void leave_edit_mode () {
 205                 movie_list.set_hildon_ui_mode (UIMode.NORMAL);
 206                 edit_toolbar.hide ();
 207                 unfullscreen ();
 208         }
 209
 210         private void on_close_button_clicked () {
 211                 search_field.set_text ("");
 212                 search_bar_visible = false;
 213                 search_bar.hide ();
 214         }
 215
 216         private bool on_key_press_event (Widget widget, Gdk.EventKey event) {
 217                 if (event.str != "") {
 218                         if (!search_bar_visible) {
 219                                 search_bar_visible = true;
 220                                 search_bar.show ();
 221                         }
 222                         search_field.grab_focus ();
 223                 }
 224
 225                 return false;
 226         }
 227
 228         private void on_search_field_changed () {
 229                 // With every change we reset the timer to 500ms
 230                 if (source_id != 0) {
 231                         Source.remove (source_id);
 232                 }
 233                 source_id = Timeout.add (500, start_search);
 234         }
 235
 236         private bool start_search () {
 237                 filter.title = search_field.get_text ();
 238                 if (store.start_search (filter)) {
 239                         movie_list.show ();
 240                         no_movies.hide ();
 241                 }
 242
 243                 // One-shot only
 244                 return false;
 245         }
 246
 247         private void on_orientation_changed (Gdk.Screen screen) {
 248                 if (CinaestProgram.orientation.portrait == portrait_mode)
 249                         return;
 250
 251                 portrait_mode = CinaestProgram.orientation.portrait;
 252
 253                 // Reduced padding in portrait mode to fit 3 posters in width
 254                 int padding = portrait_mode ? MARGIN_DEFAULT : MARGIN_DOUBLE;
 255                 alignment.left_padding = padding;
 256
 257                 // Make space for the pannable area's scroll position indicator
 258                 if (count > movies_per_screen ())
 259                         padding -= MARGIN_DEFAULT;
 260                 alignment.right_padding = padding;
 261         }
 262
 263         private void on_search_finished (int movies) {
 264                 int padding = portrait_mode ? MARGIN_DEFAULT : MARGIN_DOUBLE;
 265
 266                 // Make space for the pannable area's scroll position indicator
 267                 if (count > movies_per_screen ())
 268                         padding -= MARGIN_DEFAULT;
 269                 alignment.right_padding = padding;
 270         }
 271
 272         private int movies_per_screen () {
 273                 if (portrait_mode) {
 274                         // 3x3 full posters or 10 full list items,
 275                         // 10 full list items in list mode without search bar
 276                         return (search_bar_visible || movie_list.poster_mode) ? 9 : 10;
 277                 } else {
 278                         if (search_bar_visible) {
 279                                 // 5x1 full posters or 5 list items
 280                                 return 5;
 281                         } else {
 282                                 // 5x2 posters or 6 list items
 283                                 return movie_list.poster_mode ? 10 : 6;
 284                         }
 285                 }
 286         }
 287
 288         private void on_movie_activated (Movie movie) {
 289                 if (movie_window != null)
 290                         return;
 291
 292                 movie_window = new MovieWindow.with_movie (movie, store);
 293                 movie_window.destroy.connect (() => { movie_window = null; });
 294                 get_stack ().push_1 (movie_window);
 295         }
 296
 297         private void on_row_deleted (TreePath path) {
 298                 if (--count == 0) {
 299                         no_movies.show ();
 300                         movie_list.hide ();
 301                 }
 302         }
 303
 304         private void on_row_inserted (TreePath path, TreeIter iter) {
 305                 if (count++ == 0) {
 306                         no_movies.hide ();
 307                         movie_list.show ();
 308                 }
 309         }
 310
 311         private void on_update_running_changed (GLib.Object source, ParamSpec spec) {
 312                 TreeIter iter;
 313
 314                 Hildon.gtk_window_set_progress_indicator (this, (int) store.update_running);
 315                 // Update finished, but store still empty?
 316                 if (!store.update_running && !store.get_iter_first (out iter)) {
 317                         movie_list.hide ();
 318                         no_movies.show ();
 319                 }
 320         }
 321
 322         public unowned MovieListView get_movie_list_view () {
 323                 return movie_list;
 324         }
 325 }
 326