vcs.maemo.org Git - cinaest/blob - src/movie-list-window.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListWindow : StackableWindow {
  23         private MovieListMenu menu;
  24         private Hildon.EditToolbar edit_toolbar;
  25         private Hildon.Entry search_field;
  26         private Toolbar search_bar;
  27         private uint source_id;
  28         private MovieListView movie_list;
  29         private MovieFilter filter;
  30         private MovieListStore store;
  31         private Label no_movies;
  32         private bool search_bar_visible;
  33         private MovieWindow movie_window;
  34         private Alignment alignment;
  35
  36         public MovieListWindow (MovieSource source) {
  37                 set_title (source.get_description ());
  38
  39                 // View menu
  40                 menu = new MovieListMenu (this);
  41                 menu.source = source;
  42
  43                 set_main_menu (menu);
  44
  45                 // Search bar
  46                 search_field = new Hildon.Entry (SizeType.FINGER_HEIGHT);
  47
  48                 var search_field_item = new ToolItem ();
  49                 search_field_item.set_expand (true);
  50                 search_field_item.add (search_field);
  51
  52                 var icon_theme = Gtk.IconTheme.get_default ();
  53                 var pixbuf = icon_theme.load_icon ("general_close",
  54                                                    48,
  55                                                    Gtk.IconLookupFlags.NO_SVG);
  56                 var close_image = new Image.from_pixbuf (pixbuf);
  57                 var close_button = new ToolButton (close_image, _("Close"));
  58
  59                 search_bar = new Toolbar ();
  60                 search_bar.insert (search_field_item, 0);
  61                 search_bar.insert (close_button, 1);
  62                 search_bar.show_all ();
  63
  64                 add_toolbar (search_bar);
  65
  66                 // Movie list - connected to menu for sorting
  67                 movie_list = new MovieListView (this);
  68                 menu.sortable = movie_list.sorted_store;
  69                 store = movie_list.store;
  70                 store.source = source;
  71
  72                 no_movies = new Label (_("No movies"));
  73                 Hildon.helper_set_logical_font (no_movies, "LargeSystemFont");
  74                 Hildon.helper_set_logical_color (no_movies, RcFlags.FG, StateType.NORMAL, "SecondaryTextColor");
  75                 no_movies.set_size_request (-1, 6 * 70);
  76                 no_movies.set_alignment ((float) 0.5, (float) 0.42);
  77
  78                 var vbox = new VBox (false, 0);
  79                 vbox.pack_start (movie_list, true, true, 0);
  80                 vbox.pack_start (no_movies, false, false, 0);
  81
  82                 alignment = new Alignment (0.0f, 0.0f, 1.0f, 1.0f);
  83                 alignment.top_padding = MARGIN_HALF;
  84                 alignment.left_padding = MARGIN_DOUBLE;
  85                 alignment.right_padding = MARGIN_DOUBLE;
  86
  87                 alignment.add (vbox);
  88                 add (alignment);
  89
  90                 edit_toolbar = new Hildon.EditToolbar.with_text (_("Select movies"), _("Delete"));
  91                 set_edit_toolbar (edit_toolbar);
  92
  93                 // Connect signals
  94                 menu.filter_changed.connect (() => { start_search (); });
  95                 edit_toolbar.button_clicked.connect (on_delete_button_clicked);
  96                 edit_toolbar.arrow_clicked.connect (leave_edit_mode);
  97                 search_field.changed.connect (on_search_field_changed);
  98                 close_button.clicked.connect (on_close_button_clicked);
  99                 key_press_event.connect (on_key_press_event);
 100                 movie_list.movie_activated.connect (on_movie_activated);
 101                 store.search_finished.connect (on_search_finished);
 102
 103                 store.notify["update-running"].connect (on_update_running_changed);
 104
 105                 search_field.set_flags (WidgetFlags.CAN_DEFAULT);
 106                 search_field.grab_default ();
 107
 108                 alignment.show_all ();
 109                 edit_toolbar.hide ();
 110                 search_bar_visible = false;
 111                 search_bar.hide ();
 112
 113                 filter = new MovieFilter ();
 114                 menu.filter = filter;
 115                 filter.title = "";
 116                 if (store.start_search (filter)) {
 117                         no_movies.hide ();
 118                 } else {
 119                         movie_list.hide ();
 120                 }
 121         }
 122
 123         public void on_delete_movies_clicked () {
 124                 fullscreen ();
 125                 edit_toolbar.show ();
 126                 movie_list.set_hildon_ui_mode (UIMode.EDIT);
 127
 128                 var selection = movie_list.get_selection ();
 129                 selection.unselect_all ();
 130         }
 131
 132         private void on_delete_button_clicked () {
 133                 var selection = movie_list.get_selection ();
 134                 int count = selection.count_selected_rows ();
 135                 if (count == 0) {
 136                         Banner.show_information (this, null, _("No movies selected"));
 137                         leave_edit_mode ();
 138                         return;
 139                 }
 140
 141                 var dialog = new Note.confirmation (this, _("Delete %d movies?").printf (count));
 142                 var res = dialog.run ();
 143
 144                 if (res == Gtk.ResponseType.OK) {
 145                         weak TreeModel model;
 146                         var rows = selection.get_selected_rows (out model);
 147
 148                         var movies = new List<Movie> ();
 149
 150                         // get selected movies from the store
 151                         foreach (TreePath path in rows) {
 152                                 TreeIter iter;
 153
 154                                 if (model.get_iter (out iter, path)) {
 155                                         Movie movie;
 156
 157                                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 158                                         if (movie != null) {
 159                                                 movies.append (movie);
 160                                         }
 161                                 }
 162                         }
 163                         // and remove them
 164                         foreach (Movie movie in movies) {
 165                                 store.remove (movie);
 166                         }
 167
 168                         // Switch to "No movies" label if the store is emptied
 169                         TreeIter iter;
 170                         if (!store.get_iter_first (out iter)) {
 171                                 movie_list.hide ();
 172                                 no_movies.show ();
 173                         }
 174                 }
 175                 dialog.destroy ();
 176                 leave_edit_mode ();
 177         }
 178
 179         private void leave_edit_mode () {
 180                 movie_list.set_hildon_ui_mode (UIMode.NORMAL);
 181                 edit_toolbar.hide ();
 182                 unfullscreen ();
 183         }
 184
 185         private void on_close_button_clicked () {
 186                 search_field.set_text ("");
 187                 search_bar_visible = false;
 188                 search_bar.hide ();
 189         }
 190
 191         private bool on_key_press_event (Widget widget, Gdk.EventKey event) {
 192                 if (event.str != "") {
 193                         if (!search_bar_visible) {
 194                                 search_bar_visible = true;
 195                                 search_bar.show ();
 196                         }
 197                         search_field.grab_focus ();
 198                 }
 199
 200                 return false;
 201         }
 202
 203         private void on_search_field_changed () {
 204                 // With every change we reset the timer to 500ms
 205                 if (source_id != 0) {
 206                         Source.remove (source_id);
 207                 }
 208                 source_id = Timeout.add (500, start_search);
 209         }
 210
 211         private bool start_search () {
 212                 filter.title = search_field.get_text ();
 213                 if (store.start_search (filter)) {
 214                         movie_list.show ();
 215                         no_movies.hide ();
 216                 }
 217
 218                 // One-shot only
 219                 return false;
 220         }
 221
 222         private void on_search_finished (int movies) {
 223                 if (movies > 6)
 224                         alignment.right_padding = MARGIN_DEFAULT;
 225                 else
 226                         alignment.right_padding = MARGIN_DOUBLE;
 227                 if (movies > 100) {
 228                         Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 229                 }
 230         }
 231
 232         private void on_movie_activated (Movie movie) {
 233                 if (movie_window != null)
 234                         return;
 235
 236                 movie_window = new MovieWindow.with_movie (movie, store);
 237                 movie_window.destroy.connect (() => { movie_window = null; });
 238                 movie_window.show ();
 239         }
 240
 241         private void on_update_running_changed (GLib.Object source, ParamSpec spec) {
 242                 TreeIter iter;
 243
 244                 Hildon.gtk_window_set_progress_indicator (this, (int) store.update_running);
 245                 // Update finished, but store still empty?
 246                 if (!store.update_running && !store.get_iter_first (out iter)) {
 247                         movie_list.hide ();
 248                         no_movies.show ();
 249                 }
 250         }
 251 }
 252