vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         private bool more_movies_available;
  28         private CellRendererText title_renderer;
  29         private CellRendererText secondary_renderer;
  30         private CellRendererText rating_renderer;
  31         private CellRendererText date_renderer;
  32
  33         public signal void movie_activated (Movie movie);
  34
  35         public MovieListView (Gtk.Window window, bool show_date = false) {
  36                 store = new MovieListStore ();
  37
  38                 // Add filter wrapper
  39                 var filtered_store = new TreeModelFilter (store, null);
  40
  41                 // Add sort wrapper
  42                 sorted_store = new TreeModelSort.with_model (filtered_store);
  43
  44                 // Tree View
  45                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  46                 tree.set_headers_visible (false);
  47
  48                 add (tree);
  49
  50                 tree.set_rules_hint (true);
  51
  52                 // Tree selection object
  53                 var selection = tree.get_selection ();
  54                 selection.set_mode (SelectionMode.SINGLE);
  55
  56                 // Title column with poster
  57                 var title_column = new TreeViewColumn ();
  58                 title_column.set_title (_("Movie"));
  59                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  60                 title_column.set_reorderable (false);
  61                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  62                 title_column.set_expand (true);
  63
  64                 // Add poster icon to column
  65                 var pixbuf_renderer = new CellRendererPixbuf ();
  66                 pixbuf_renderer.width = 64;
  67                 pixbuf_renderer.xalign = 0.0f;
  68                 title_column.pack_start (pixbuf_renderer, false);
  69                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  70
  71                 // Add text to column
  72                 var vbox_renderer = new CellRendererVBox ();
  73
  74                 title_renderer = new CellRendererText ();
  75                 title_renderer.yalign = 1.0f;
  76                 title_renderer.ellipsize = Pango.EllipsizeMode.END;
  77
  78                 vbox_renderer.append (title_renderer, true);
  79
  80                 // Add secondary text to column (Genres, Director, etc.)
  81                 secondary_renderer = new CellRendererText ();
  82                 secondary_renderer.yalign = 0;
  83                 secondary_renderer.ellipsize = Pango.EllipsizeMode.END;
  84                 secondary_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
  85
  86                 vbox_renderer.append (secondary_renderer, true);
  87
  88                 title_column.pack_start (vbox_renderer, true);
  89                 title_column.set_cell_data_func (vbox_renderer, title_data_func);
  90
  91                 tree.append_column (title_column);
  92
  93                 // Sort by title
  94                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
  95
  96                 // Year column
  97                 var renderer = new CellRendererText ();
  98                 var year_column = new TreeViewColumn ();
  99                 year_column.set_title (_("Rating"));
 100                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 101                 year_column.set_reorderable (false);
 102                 year_column.set_sort_order (SortType.DESCENDING);
 103                 year_column.pack_start (renderer, true);
 104                 year_column.set_cell_data_func (renderer, year_data_func);
 105                 tree.append_column (year_column);
 106
 107                 // Rating column
 108                 var rating_column = new TreeViewColumn ();
 109                 rating_column.set_title (_("Rating"));
 110                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 111                 rating_column.set_reorderable (false);
 112                 rating_column.set_sort_order (SortType.DESCENDING);
 113                 rating_column.xalign = 1.0f;
 114
 115                 vbox_renderer = new CellRendererVBox ();
 116
 117                 rating_renderer = new CellRendererText ();
 118                 rating_renderer.xalign = 1.0f;
 119                 if (show_date)
 120                         rating_renderer.yalign = 1.0f;
 121
 122                 vbox_renderer.append (rating_renderer, true);
 123
 124                 date_renderer = new CellRendererText ();
 125                 date_renderer.yalign = 0;
 126                 date_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
 127
 128                 if (show_date)
 129                         vbox_renderer.append (date_renderer, true);
 130
 131                 rating_column.pack_start (vbox_renderer, true);
 132                 rating_column.set_cell_data_func (vbox_renderer, rating_data_func);
 133
 134                 tree.append_column (rating_column);
 135
 136                 // Connect signals
 137                 get_vadjustment ().value_changed.connect (on_adjustment_value_changed);
 138                 tree.row_activated.connect (on_row_activated);
 139                 store.search_finished.connect (on_search_finished);
 140         }
 141
 142         public void set_hildon_ui_mode (UIMode mode) {
 143                 var selection = tree.get_selection ();
 144
 145                 if (mode == UIMode.NORMAL) {
 146                         selection.set_mode (SelectionMode.NONE);
 147                 }
 148                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 149                 if (mode == UIMode.EDIT) {
 150                         selection.set_mode (SelectionMode.MULTIPLE);
 151                 }
 152         }
 153
 154         public unowned TreeSelection get_selection () {
 155                 return tree.get_selection ();
 156         }
 157
 158         private Pango.AttrList get_attributes (Gtk.Window window, string font_name, string color_name) {
 159                 Pango.AttrList attr_list = new Pango.AttrList ();
 160                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), font_name, null, typeof (void));
 161                 if (style != null) {
 162                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
 163                         attr_list.insert ((owned) attr_font_desc);
 164                 }
 165                 Gdk.Color color;
 166                 window.ensure_style ();
 167                 if (window.style.lookup_color (color_name, out color)) {
 168                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
 169                         attr_list.insert ((owned) attr_color);
 170                 }
 171                 return attr_list;
 172         }
 173
 174         // TODO: after scrolling down 80% of the list, load more
 175         //       results if available.
 176         private void on_adjustment_value_changed () {
 177                 if (more_movies_available) {
 178                         var vadj = get_vadjustment ();
 179                         if (vadj.value > 0.8 * vadj.upper) {
 180                                 Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 181                                 more_movies_available = false;
 182                         }
 183                 }
 184         }
 185
 186         private void on_row_activated (TreeView tree, TreePath path, TreeViewColumn column) {
 187                 TreeModel model = tree.model;
 188                 TreeIter iter;
 189
 190                 if (model.get_iter (out iter, path)) {
 191                         Movie movie;
 192                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 193                         movie_activated (movie);
 194                 }
 195         }
 196
 197         private void on_search_finished (int movies) {
 198                 more_movies_available = (movies > 100); // FIXME
 199         }
 200
 201         private void title_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 202                 Movie movie;
 203
 204                 model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 205                 title_renderer.text = movie.title;
 206                 secondary_renderer.text = movie.secondary;
 207         }
 208
 209         private void year_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 210                 int year;
 211
 212                 model.get (iter, MovieListStore.Columns.YEAR, out year);
 213                 ((CellRendererText) cell).text = (year > 0) ? year.to_string () : "";
 214         }
 215
 216         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 217                 int rating;
 218                 Movie movie;
 219
 220                 model.get (iter, MovieListStore.Columns.RATING, out rating,
 221                                  MovieListStore.Columns.MOVIE, out movie);
 222                 rating_renderer.text = (rating > 0) ? "%d.%d".printf (rating / 10, rating % 10) : "";
 223                 if (movie.julian_date != 0) {
 224                         var date = Date ();
 225                         date.set_julian (movie.julian_date);
 226                         var s = new char[64];
 227                         date.strftime (s, "%x");
 228                         date_renderer.text = (string) s;
 229                 } else {
 230                         date_renderer.text = "";
 231                 }
 232         }
 233 }