vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         IconView icons;
  26
  27         private bool more_movies_available;
  28         private CellRendererText title_renderer;
  29         private CellRendererText secondary_renderer;
  30         private CellRendererText rating_renderer;
  31         private CellRendererText date_renderer;
  32         private MoviePoster.Factory poster_factory;
  33         private int last_a = -1;
  34         private int last_b = -1;
  35
  36         private bool poster_mode_;
  37         public bool poster_mode {
  38                 get {
  39                         return poster_mode_;
  40                 }
  41                 set {
  42                         if (value & !poster_mode_) {
  43                                 remove (tree);
  44                                 tree.set_model (null);
  45                                 icons.set_model (store);
  46                                 store.view = (Widget) icons;
  47                                 add (icons);
  48                         } else if (!value & poster_mode_) {
  49                                 remove (icons);
  50                                 icons.set_model (null);
  51                                 tree.set_model (store);
  52                                 store.view = (Widget) tree;
  53                                 add (tree);
  54                         }
  55                         if (value != poster_mode_) {
  56                                 poster_mode_ = value;
  57                                 last_a = -1;
  58                                 last_b = -1;
  59
  60                                 // FIXME - just calling on_adjustment_value_changed () here doesn't work
  61                                 // because icons.get_visible_range () returns wrong paths.
  62                                 check_posters (0, 10);
  63                                 jump_to (0, 0);
  64                         }
  65                 }
  66         }
  67
  68         public signal void movie_activated (Movie movie);
  69
  70         private Gtk.TreeView create_treeview (Gtk.Window window, bool show_date) {
  71                 // Tree View
  72                 var tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, store);
  73                 tree.set_headers_visible (false);
  74                 tree.set_rules_hint (true);
  75
  76                 // Tree selection object
  77                 var selection = tree.get_selection ();
  78                 selection.set_mode (SelectionMode.SINGLE);
  79
  80                 // Title column with poster
  81                 var title_column = new TreeViewColumn ();
  82                 title_column.set_title (_("Movie"));
  83                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  84                 title_column.set_reorderable (false);
  85                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  86                 title_column.set_expand (true);
  87
  88                 // Add poster icon to column
  89                 var pixbuf_renderer = new CellRendererPixbuf ();
  90                 pixbuf_renderer.width = 64;
  91                 pixbuf_renderer.xalign = 0.0f;
  92                 title_column.pack_start (pixbuf_renderer, false);
  93                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.ICON);
  94
  95                 // Add text to column
  96                 var vbox_renderer = new CellRendererVBox ();
  97
  98                 title_renderer = new CellRendererText ();
  99                 title_renderer.yalign = 1.0f;
 100                 title_renderer.ellipsize = Pango.EllipsizeMode.END;
 101
 102                 vbox_renderer.append (title_renderer, true);
 103
 104                 // Add secondary text to column (Genres, Director, etc.)
 105                 secondary_renderer = new CellRendererText ();
 106                 secondary_renderer.yalign = 0;
 107                 secondary_renderer.ellipsize = Pango.EllipsizeMode.END;
 108                 secondary_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
 109
 110                 vbox_renderer.append (secondary_renderer, true);
 111
 112                 title_column.pack_start (vbox_renderer, true);
 113                 title_column.set_cell_data_func (vbox_renderer, title_data_func);
 114
 115                 tree.append_column (title_column);
 116
 117                 // Year column
 118                 var year_column = new TreeViewColumn ();
 119                 year_column.set_title (_("Year"));
 120                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 121                 year_column.set_reorderable (false);
 122                 year_column.set_sort_order (SortType.DESCENDING);
 123                 tree.append_column (year_column);
 124
 125                 // Rating column
 126                 var rating_column = new TreeViewColumn ();
 127                 rating_column.set_title (_("Rating"));
 128                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 129                 rating_column.set_reorderable (false);
 130                 rating_column.set_sort_order (SortType.DESCENDING);
 131                 rating_column.xalign = 1.0f;
 132
 133                 vbox_renderer = new CellRendererVBox ();
 134
 135                 rating_renderer = new CellRendererText ();
 136                 rating_renderer.xalign = 1.0f;
 137                 if (show_date)
 138                         rating_renderer.yalign = 1.0f;
 139
 140                 vbox_renderer.append (rating_renderer, true);
 141
 142                 date_renderer = new CellRendererText ();
 143                 date_renderer.yalign = 0;
 144                 date_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
 145
 146                 if (show_date)
 147                         vbox_renderer.append (date_renderer, true);
 148
 149                 rating_column.pack_start (vbox_renderer, true);
 150                 rating_column.set_cell_data_func (vbox_renderer, rating_data_func);
 151
 152                 tree.append_column (rating_column);
 153                 tree.show ();
 154                 return tree;
 155         }
 156
 157         private Gtk.IconView create_iconview () {
 158                 var iconview = (Gtk.IconView) Hildon.gtk_icon_view_new (Hildon.UIMode.NORMAL);
 159                 iconview.set_column_spacing (0);
 160                 iconview.set_pixbuf_column (MovieListStore.Columns.POSTER);
 161                 iconview.margin = 0;
 162                 iconview.item_width = Poster.SMALL_WIDTH;
 163                 iconview.column_spacing = Hildon.MARGIN_HALF;
 164                 iconview.row_spacing = Hildon.MARGIN_HALF;
 165                 iconview.show ();
 166
 167                 return iconview;
 168         }
 169
 170         public MovieListView (Gtk.Window window, bool show_date = false) {
 171                 store = new MovieListStore ();
 172
 173                 // Sort by title
 174                 store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 175
 176                 Gdk.Color color;
 177                 window.ensure_style ();
 178                 if (window.style.lookup_color ("SecondaryTextColor", out color)) {
 179                         store.year_markup = "<span size=\"small\" fgcolor=\"%s\">(%%d)</span>".printf (color.to_string ());
 180                 }
 181
 182                 tree = create_treeview (window, show_date);
 183                 store.view = (Widget) tree;
 184
 185                 icons = create_iconview ();
 186
 187                 add (tree);
 188
 189                 // Connect signals
 190                 get_vadjustment ().value_changed.connect (on_adjustment_value_changed);
 191                 tree.row_activated.connect (on_row_activated);
 192                 icons.item_activated.connect (on_item_activated);
 193                 store.row_changed.connect (on_row_changed);
 194                 store.search_finished.connect (on_search_finished);
 195         }
 196
 197         construct {
 198                 hscrollbar_policy = Gtk.PolicyType.NEVER;
 199
 200                 poster_factory = MoviePoster.Factory.get_instance ();
 201         }
 202
 203         public void set_hildon_ui_mode (UIMode mode) {
 204                 var selection = tree.get_selection ();
 205
 206                 if (mode == UIMode.NORMAL) {
 207                         selection.set_mode (SelectionMode.NONE);
 208                         icons.set_selection_mode (SelectionMode.NONE);
 209                 }
 210                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 211                 Hildon.gtk_icon_view_set_ui_mode (icons, mode);
 212                 if (mode == UIMode.EDIT) {
 213                         selection.set_mode (SelectionMode.MULTIPLE);
 214                         icons.set_selection_mode (SelectionMode.MULTIPLE);
 215                 }
 216         }
 217
 218         private Pango.AttrList get_attributes (Gtk.Window window, string font_name, string color_name) {
 219                 Pango.AttrList attr_list = new Pango.AttrList ();
 220                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), font_name, null, typeof (void));
 221                 if (style != null) {
 222                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
 223                         attr_list.insert ((owned) attr_font_desc);
 224                 }
 225                 Gdk.Color color;
 226                 window.ensure_style ();
 227                 if (window.style.lookup_color (color_name, out color)) {
 228                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
 229                         attr_list.insert ((owned) attr_color);
 230                 }
 231                 return attr_list;
 232         }
 233
 234         public void unselect_all () {
 235                 tree.get_selection ().unselect_all ();
 236                 icons.unselect_all ();
 237         }
 238
 239         public List<Movie> get_selected_movies () {
 240                 var movies = new List<Movie> ();
 241                 List<TreePath> paths;
 242
 243                 if (poster_mode_)
 244                         paths = icons.get_selected_items ();
 245                 else
 246                         paths = tree.get_selection ().get_selected_rows (null);
 247
 248                 // get selected movies from the store
 249                 foreach (TreePath path in paths) {
 250                         TreeIter iter;
 251
 252                         if (store.get_iter (out iter, path)) {
 253                                 Movie movie;
 254
 255                                 store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 256                                 if (movie != null) {
 257                                         movies.append (movie);
 258                                 }
 259                         }
 260                 }
 261
 262                 return movies;
 263         }
 264
 265         // TODO: after scrolling down 80% of the list, load more
 266         //       results if available.
 267         private void on_adjustment_value_changed () {
 268                 if (more_movies_available) {
 269                         var vadj = get_vadjustment ();
 270                         if (vadj.value > 0.8 * vadj.upper) {
 271                                 Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 272                                 more_movies_available = false;
 273                         }
 274                 }
 275
 276                 TreePath a_;
 277                 TreePath b_;
 278                 bool range;
 279                 if (poster_mode_) {
 280                         range = icons.get_visible_range (out a_, out b_);
 281                 } else {
 282                         range = tree.get_visible_range (out a_, out b_);
 283                 }
 284                 if (range) {
 285                         // We know the list store is flat
 286                         int a = a_.get_indices ()[0];
 287                         int b = b_.get_indices ()[0];
 288                         assert (a <= b);
 289
 290                         if (a == last_a && b == last_b)
 291                                 return;
 292
 293                         if (a > last_b || b < last_a) {
 294                                 check_posters (a, b);
 295                         } else if (a >= last_a && b > last_b) {
 296                                 check_posters (last_b + 1, b);
 297                         } else if (b <= last_b && a < last_a) {
 298                                 check_posters (a, last_a - 1);
 299                         }
 300
 301                         last_a = a;
 302                         last_b = b;
 303                 }
 304         }
 305
 306         private void check_posters (int a, int b) {
 307                 for (int i = a; i <= b; i++) {
 308                         var path = new TreePath.from_indices (i);
 309                         TreeIter iter;
 310                         if (store.get_iter (out iter, path)) {
 311                                 Movie movie;
 312                                 store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 313                                 if (movie != null) {
 314                                         if (poster_mode_) {
 315                                                 if (movie.poster == null || movie.poster.small == null) try {
 316                                                         poster_factory.queue_thumbnail (movie, Poster.SMALL_WIDTH, Poster.SMALL_HEIGHT, false, receive_poster_small);
 317                                                 } catch (Error e) {
 318                                                         warning ("Failed to queue poster request: %s\n", e.message);
 319                                                 }
 320                                         } else {
 321                                                 if (movie.poster == null || movie.poster.icon == null) try {
 322                                                         poster_factory.queue_thumbnail (movie, Poster.ICON_WIDTH, Poster.ICON_HEIGHT, false, receive_poster_icon);
 323                                                 } catch (Error e) {
 324                                                         warning ("Failed to queue poster request: %s\n", e.message);
 325                                                 }
 326                                         }
 327                                 }
 328                         }
 329                 }
 330         }
 331
 332         private void on_row_activated (TreeView tree, TreePath path, TreeViewColumn column) {
 333                 on_item_activated (path);
 334         }
 335
 336         private void on_item_activated (TreePath path) {
 337                 TreeIter iter;
 338
 339                 if (store.get_iter (out iter, path)) {
 340                         Movie movie;
 341                         store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 342                         movie_activated (movie);
 343                 }
 344         }
 345
 346         private void on_row_changed (TreePath path, TreeIter iter) {
 347                 TreePath a;
 348                 TreePath b;
 349                 bool range;
 350
 351                 if (poster_mode_) {
 352                         range = icons.get_visible_range (out a, out b);
 353                 } else {
 354                         range = tree.get_visible_range (out a, out b);
 355                 }
 356                 if (!range ||
 357                     (range && path.compare (a) >= 0 && path.compare (b) <= 0)) {
 358                         Movie movie;
 359
 360                         store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 361                         if (movie == null)
 362                                 return;
 363
 364                         int i = path.get_indices ()[0];
 365                         check_posters (i, i);
 366                 }
 367         }
 368
 369         private void receive_poster_small (Gdk.Pixbuf pixbuf, Movie movie) {
 370                 Poster poster;
 371                 if (movie.poster != null)
 372                         poster = movie.poster;
 373                 else
 374                         poster = new Poster ();
 375                 poster.small = pixbuf;
 376                 movie.poster = poster;
 377         }
 378
 379         private void receive_poster_icon (Gdk.Pixbuf pixbuf, Movie movie) {
 380                 Poster poster;
 381                 if (movie.poster != null)
 382                         poster = movie.poster;
 383                 else
 384                         poster = new Poster ();
 385                 poster.icon = pixbuf;
 386                 movie.poster = poster;
 387         }
 388
 389         private void on_search_finished (int movies) {
 390                 more_movies_available = (movies > 100); // FIXME
 391         }
 392
 393         private void title_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 394                 Movie movie;
 395                 string markup;
 396
 397                 model.get (iter, MovieListStore.Columns.MOVIE, out movie,
 398                                  MovieListStore.Columns.MARKUP, out markup);
 399                 title_renderer.markup = markup;
 400                 secondary_renderer.text = movie.secondary;
 401         }
 402
 403         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 404                 string rating;
 405                 Movie movie;
 406
 407                 model.get (iter, MovieListStore.Columns.RATING, out rating,
 408                                  MovieListStore.Columns.MOVIE, out movie);
 409                 rating_renderer.text = rating;
 410                 if (movie.julian_date != 0) {
 411                         var date = Date ();
 412                         date.set_julian (movie.julian_date);
 413                         var s = new char[64];
 414                         date.strftime (s, "%x");
 415                         date_renderer.text = (string) s;
 416                 } else {
 417                         date_renderer.text = "";
 418                 }
 419         }
 420 }