vcs.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 VERSION = 0.5.1
   8 USE_RESOURCES = 0
   9
  10 QT += network
  11 CONFIG += qt
  12 #CONFIG += link_pkgconfig
  13
  14 lessThan(QT_MAJOR_VERSION, 5) {
  15     QT += webkit
  16     CONFIG += webkit mobility
  17     MOBILITY = location
  18 } else {
  19     QT += qml quick concurrent location webkitwidgets webkit
  20 }
  21
  22 contains(MEEGO_EDITION, harmattan) {
  23    CONFIG += harmattan
  24 }
  25
  26 sailfish {
  27     PLATFORM = sailfish
  28     DEFINES += TARGET_PLATFORM_SAILFISH
  29     # enable booster
  30 packagesExist(qdeclarative-boostable) {
  31     message("Building with qdeclarative-boostable support")
  32     DEFINES += HAS_BOOSTER
  33     PKGCONFIG += qdeclarative-boostable
  34 } else {
  35     warning("qdeclarative-boostable not available; startup times will be slower")
  36 }
  37     QMAKE_LFLAGS += -pie -rdynamic
  38     PLATFORM_SOURCES = view.cpp
  39     PLATFORM_HEADERS = view.h view_qt5.h
  40 }
  41 harmattan {
  42     QT += declarative
  43     PLATFORM = harmattan
  44     DEFINES += TARGET_PLATFORM_HARMATTAN
  45     # enable booster
  46     CONFIG += qdeclarative-boostable
  47     QMAKE_CXXFLAGS += -fPIC -fvisibility=hidden -fvisibility-inlines-hidden -Wno-psabi
  48     QMAKE_LFLAGS += -pie -rdynamic
  49     PLATFORM_SOURCES = view.cpp
  50     PLATFORM_HEADERS = view.h view_qt4.h
  51 }
  52 maemo5 {
  53     QT += maemo5
  54     PLATFORM = fremantle
  55     DEFINES += TARGET_PLATFORM_FREMANTLE
  56     PLATFORM_SOURCES = \
  57         app.cpp \
  58         stationlistview.cpp \
  59         stationview.cpp \
  60         settingsdialog.cpp \
  61         keypressforwarder.cpp
  62     PLATFORM_HEADERS= \
  63         app.h \
  64         stationlistview.h \
  65         keypressforwarder.h \
  66         settingsdialog.h \
  67         stationview.h
  68 }
  69 !sailfish:!harmattan:!maemo5 {
  70     PLATFORM = desktop
  71     DEFINES += TARGET_PLATFORM_DESKTOP
  72     PLATFORM_SOURCES = view.cpp
  73 }
  74
  75 message(Compiling For:    $$PLATFORM)
  76 message(Platform Sources: $$PLATFORM_SOURCES)
  77 message(Qt Version:       $$QT_MAJOR_VERSION"."$$QT_MINOR_VERSION)
  78 message(Qt Modules Used:  $$QT)
  79 message(Building version: $$VERSION)
  80
  81 TARGET = quandoparte
  82 TEMPLATE = app
  83 VERSION_STRING = '\\"$${VERSION}\\"'
  84 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  85
  86 contains(USE_RESOURCES, 1) {
  87     DEFINES += USE_RESOURCES=1
  88     CONFIG += resources
  89 }
  90
  91 !debug {
  92     DEFINES += QT_NO_DEBUG_OUTPUT
  93 }
  94
  95 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  96
  97 SOURCES += \
  98     $$PLATFORM_SOURCES \
  99     main.cpp \
 100     stationlistmodel.cpp \
 101     stationlistproxymodel.cpp \
 102     settings.cpp \
 103     dataprovider.cpp \
 104     stationschedulemodel.cpp \
 105     stationscheduleitem.cpp
 106
 107 HEADERS += \
 108     $$PLATFORM_HEADERS \
 109     stationlistmodel.h \
 110     stationlistproxymodel.h \
 111     settings.h \
 112     dataprovider.h \
 113     stationschedulemodel.h \
 114     stationscheduleitem.h
 115
 116 FORMS += \
 117     settingsdialog.ui \
 118     stationlistview.ui
 119
 120 QMLSOURCES = \
 121     resources/harmattan/qml/main.qml \
 122     resources/harmattan/qml/StationListPage.qml \
 123     resources/harmattan/qml/StationPage.qml \
 124     resources/harmattan/qml/SearchBar.qml \
 125     resources/harmattan/qml/PageHeader.qml \
 126     resources/harmattan/qml/PageHeader.js \
 127     resources/harmattan/qml/uiconstants.js \
 128     resources/harmattan/qml/StationListPage.js \
 129     resources/harmattan/qml/AboutPage.qml \
 130     resources/harmattan/qml/InfoBar.qml \
 131     resources/harmattan/qml/DroppedShadow.qml \
 132     resources/harmattan/qml/DelayIndicator.qml \
 133     resources/harmattan/qml/StationScheduleDelegate.qml \
 134     resources/sailfish/qml/main.qml \
 135     resources/sailfish/qml/pages/StationListPage.qml \
 136     resources/sailfish/qml/pages/StationPage.qml
 137
 138 OTHER_FILES += \
 139     resources/sailfish/applications/quandoparte.desktop \
 140     resources/harmattan/applications/quandoparte.desktop \
 141     resources/fremantle/applications/quandoparte.desktop \
 142     icons/48x48/quandoparte.png \
 143     icons/64x64/quandoparte.png \
 144     icons/80x80/quandoparte.png \
 145     icons/scalable/quandoparte.svg \
 146     icons/sailfish/90x90/quandoparte.svg \
 147     icons/sailfish/scalable/quandoparte.svg \
 148     icons/quandoparte.png \
 149     resources/quandoparte.css \
 150     resources/arrivals.css \
 151     resources/departures.css \
 152     $$replace(TRANSLATIONS, .ts, .qm) \
 153     resources/stations/stations.qpl \
 154     resources/stations/generatelist.xq \
 155     resources/stations/generateunclassifiedlist.xq \
 156     $$QMLSOURCES \
 157     resources/sailfish/qml/StationListPage.qml
 158
 159 isEmpty(PREFIX) {
 160     maemo5 {
 161         PREFIX=/opt/usr
 162     }
 163     harmattan {
 164         PREFIX=/opt/$${TARGET}
 165     }
 166     sailfish {
 167         PREFIX=/usr
 168     }
 169     !maemo5:!harmattan:!sailfish {
 170         PREFIX=/usr/local
 171     }
 172 }
 173 maemo5 {
 174     DESKTOPDIR=/usr/share/applications/hildon
 175 }
 176 harmattan {
 177     DESKTOPDIR=/usr/share/applications
 178 }
 179 sailfish {
 180     DESKTOPDIR=$$PREFIX/share/applications
 181 }
 182 desktop {
 183     DESKTOPDIR=$$PREFIX/share/applications
 184 }
 185 BINDIR=$$PREFIX/bin
 186 contains(USE_RESOURCES, 1) {
 187     DATADIR=":"
 188 } else {
 189     DATADIR=$$PREFIX/share/apps/$${TARGET}
 190 }
 191 DEFINES += DATADIR=\\\"$${DATADIR}\\\" PKGDATADIR=\\\"$${PKGDATADIR}\\\"
 192
 193 message(Installing to prefix $$PREFIX)
 194 message(Executable to $$BINDIR)
 195 message(Desktop file to $$DESKTOPDIR)
 196 message(Data to $$DATADIR)
 197 message(Extra defines $$DEFINES)
 198
 199 target.path = $$BINDIR
 200 INSTALLS += target
 201
 202 unix:sailfish {
 203     desktopfile.files = resources/$$PLATFORM/applications/$${TARGET}.desktop
 204     desktopfile.path = $$DESKTOPDIR
 205     INSTALLS += desktopfile
 206 }
 207
 208 unix:sailfish {
 209     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 210     stations.files = resources/stations/stations.qpl
 211
 212     i18n.path = $$DATADIR/i18n
 213     stations.path = $$DATADIR/stations
 214
 215     icon48.files = icons/48x48/$${TARGET}.png
 216     icon64.files = icons/64x64/$${TARGET}.png
 217     iconscalable.files = icons/scalable/$${TARGET}.svg
 218
 219     icon48.path = /usr/share/icons/hicolor/48x48/apps
 220     icon64.path = /usr/share/icons/hicolor/64x64/apps
 221     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 222
 223     INSTALLS += icon48
 224     INSTALLS += iconscalable
 225     INSTALLS += i18n
 226     INSTALLS += stations
 227 }
 228
 229 maemo5 {
 230     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 231     css.path = $$DATADIR/css
 232     !contains(USE_RESOURCES, 1) {
 233         INSTALLS += css
 234     }
 235 }
 236
 237 sailfish {
 238     icon90.files = icons/sailfish/90x90/$${TARGET}.png
 239     icon90.path = /usr/share/icons/hicolor/meegotouch/apps
 240     INSTALLS += icon90
 241 }
 242 harmattan {
 243     icon80.files = icons/80x80/$${TARGET}.png
 244     icon80.path = /usr/share/icons/hicolor/meegotouch/apps
 245     INSTALLS += icon80
 246 }
 247
 248 !contains(USE_RESOURCES, 1) {
 249     sailfish {
 250         qml.files = resources/sailfish/qml/*.qml \
 251                     resources/sailfish/qml/*.js \
 252                     resources/sailfish/qml/pages \
 253                     resources/sailfish/qml/cover
 254         qml.path = $$DATADIR/qml
 255         INSTALLS += qml
 256     }
 257     harmattan {
 258         qml.files = resources/harmattan/qml/*.qml resources/harmattan/qml/*.js
 259         qml.path = $$DATADIR/qml
 260         INSTALLS += qml
 261     }
 262 }
 263
 264 contains(USE_RESOURCES, 1) {
 265     RESOURCES += \
 266         quandoparte.qrc
 267 }
 268
 269 hack_to_fix_translations {
 270     SOURCES += $$QMLSOURCES
 271 }