vcs.maemo.org Git - oespirit1/blob - gtk+/gtk+.inc

   1 DESCRIPTION = "GTK+ is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
   2 set of widgets, GTK+ is suitable for projects ranging from small one-off projects to complete application suites."
   3 HOMEPAGE = "http://www.gtk.org"
   4 SECTION = "libs"
   5 LICENSE = "LGPL"
   6 PRIORITY = "optional"
   7 DEPENDS = "glib-2.0 tiff pango atk jpeg libpng3 libxext libxcursor gtk-doc libgcrypt cups \
   8            libxrandr libxdamage libxrender libxcomposite"
   9
  10 inherit autotools pkgconfig
  11
  12 LEAD_SONAME = "libgtk-x11-2.0.so"
  13
  14 FILES_${PN} = " ${bindir}/gtk-query-immodules-2.0 \
  15                 ${libdir}/lib*.so.* \
  16                 ${datadir}/themes ${sysconfdir} \
  17                 ${libdir}/gtk-2.0/${LIBV}/engines/libpixmap.so"
  18
  19 FILES_${PN}-dev += " \
  20         ${datadir}/gtk-2.0/include \
  21         ${libdir}/gtk-2.0/include \
  22         ${bindir}/gdk-pixbuf-csource \
  23         ${bindir}/gtk-builder-convert"
  24
  25 FILES_${PN}-dbg += " \
  26         ${libdir}/gtk-2.0/modules/.debug/* \
  27         ${libdir}/gtk-2.0/${LIBV}/loaders/.debug/* \
  28         ${libdir}/gtk-2.0/${LIBV}/immodules/.debug/* \
  29         ${libdir}/gtk-2.0/${LIBV}/engines/.debug/* \
  30         ${libdir}/gtk-2.0/${LIBV}/printbackends/.debug/*"
  31
  32 NEATSTUFF = " ttf-dejavu-sans gdk-pixbuf-loader-png gdk-pixbuf-loader-jpeg gdk-pixbuf-loader-gif gdk-pixbuf-loader-xpm "
  33
  34 RRECOMMENDS_${PN} = " ${NEATSTUFF} "
  35 RRECOMMENDS_${PN}_linux = " ${NEATSTUFF} glibc-gconv-iso8859-1 "
  36 RRECOMMENDS_${PN}_linux-gnueabi = " ${NEATSTUFF} glibc-gconv-iso8859-1"
  37
  38
  39
  40 do_stage () {
  41         oe_libinstall -so -C gtk libgtk-x11-2.0 ${STAGING_LIBDIR}
  42         oe_libinstall -so -C gdk libgdk-x11-2.0 ${STAGING_LIBDIR}
  43         oe_libinstall -so -C contrib/gdk-pixbuf-xlib libgdk_pixbuf_xlib-2.0 ${STAGING_LIBDIR}
  44         oe_libinstall -so -C gdk-pixbuf libgdk_pixbuf-2.0 ${STAGING_LIBDIR}
  45         if test -d modules/other/gail/libgail-util ; then
  46                 oe_libinstall -so -C modules/other/gail/libgail-util libgailutil ${STAGING_LIBDIR}
  47         fi
  48
  49         autotools_stage_includes
  50
  51         mkdir -p ${STAGING_LIBDIR}/gtk-2.0/include
  52         install -m 0644 gdk/gdkconfig.h ${STAGING_LIBDIR}/gtk-2.0/include/gdkconfig.h
  53         # Copy over all headers, since the maemo stuff needs access to the private api. *sigh*
  54         cp gtk/*.h ${STAGING_INCDIR}/gtk-2.0/gtk/
  55
  56         install -m 0644 m4macros/gtk-2.0.m4 ${STAGING_DATADIR}/aclocal/
  57 }
  58
  59 do_install_append () {
  60         install -d ${D}${sysconfdir}/gtk-2.0
  61         rm -f ${D}${libdir}/gtk-2.0/*/*.la ${D}${libdir}/gtk-2.0/${LIBV}/*/*.la
  62 }
  63
  64 postinst_prologue() {
  65 if [ "x$D" != "x" ]; then
  66   exit 1
  67 fi
  68
  69 }