vcs.maemo.org Git - oespirit1/blob - glib-2.0/glib.inc

   1 DESCRIPTION = "GLib is a general-purpose utility library, \
   2 which provides many useful data types, macros, \
   3 type conversions, string utilities, file utilities, a main \
   4 loop abstraction, and so on. It works on many \
   5 UNIX-like platforms, Windows, OS/2 and BeOS."
   6 LICENSE = "LGPL"
   7 SECTION = "libs"
   8 PRIORITY = "optional"
   9 DEPENDS += "glib-2.0-native gtk-doc"
  10 DEPENDS += "virtual/libiconv virtual/libintl"
  11 PACKAGES =+ "gobject-2.0 gmodule-2.0 gthread-2.0 gio-2.0 glib-2.0-utils "
  12
  13 PR = "r4"
  14
  15 LEAD_SONAME = "libglib-2.0.*"
  16 FILES_glib-2.0-utils = "${bindir}/*"
  17 FILES_${PN} = "${libdir}/lib*so.* ${libdir}/gio/modules/*.so"
  18 FILES_${PN}-dev += "${libdir}/glib-2.0 ${datadir}/glib-2.0 ${libdir}/gio/modules/*.la"
  19 FILES_${PN}-dbg += "${libdir}/gio/modules/.debug"
  20 FILES_gmodule-2.0 = "${libdir}/libgmodule-2.0.so.*"
  21 FILES_gobject-2.0 = "${libdir}/libgobject-2.0.so.*"
  22 FILES_gio-2.0 = "${libdir}/libgio-2.0.so.*"
  23 FILES_gthread-2.0 = "${libdir}/libgthread-2.0.so.*"
  24
  25 # Let the gthread library end up in glib package
  26 # for compatibility.
  27 FILES_gthread-2.0_chinook-compat = ""
  28
  29 EXTRA_OECONF = "--disable-debug "
  30
  31 # Add and entry for your favourite arch if your (g)libc has a sane printf
  32 EXTRA_OECONF_append_glibc_arm = "  --enable-included-printf=no "
  33
  34 S = "${WORKDIR}/glib-${PV}"
  35
  36 inherit autotools pkgconfig gettext
  37
  38 require glib-2.0.inc
  39
  40 acpaths = ""
  41 do_configure_prepend () {
  42         install -m 0644 ${WORKDIR}/glibconfig-sysdefs.h .
  43 }
  44
  45 do_install_append() {
  46         sed -i -e s:${STAGING_BINDIR_NATIVE}:${bindir}:g ${D}${bindir}/glib-mkenums || true
  47 }
  48
  49 do_stage () {
  50         autotools_stage_all
  51         install -d ${STAGING_INCDIR}/glib-2.0/glib
  52         install -m 0755 ${S}/glibconfig.h ${STAGING_INCDIR}/glib-2.0/glibconfig.h
  53         install -d ${STAGING_DATADIR}/aclocal
  54         install -m 0644 ${S}/m4macros/glib-2.0.m4 ${STAGING_DATADIR}/aclocal/glib-2.0.m4
  55         install -m 0644 ${S}/m4macros/glib-gettext.m4 ${STAGING_DATADIR}/aclocal/glib-gettext.m4
  56 }