vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [1])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58         want_config_output=no
  59         ;;
  60 #  NetBSD*)
  61 #    WANT_KVM=yes
  62 #    WANT_OSSLIB=yes
  63 #    ;;
  64
  65   OpenBSD*)
  66     WANT_KVM=yes
  67     WANT_OSSLIB=yes
  68     ;;
  69
  70 # Solaris doesn't work at all right now
  71 #  SunOS*)
  72 #    WANT_KSTAT=yes
  73 #    ;;
  74
  75   *)
  76     echo "Your operating system $uname isn't supported"
  77     echo "Feel free to help. :P"
  78     exit 1
  79     ;;
  80 esac
  81
  82 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  83 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  84 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  85 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  86 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  87
  88 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  89 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  90 AC_SUBST(BUILD_DATE)
  91 AC_SUBST(BUILD_ARCH)
  92
  93
  94 dnl
  95 dnl BUILD_CONFIG_OUTPUT option
  96 dnl
  97
  98 AC_ARG_ENABLE([config_output],
  99               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) Note: not available on FreeBSD @<:@default=yes@:>@]),
 100               [want_config_output="$enableval"], [want_config_output=yes])
 101
 102 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 103 AM_CONDITIONAL(BUILD_FOR_FOPENCOOKIE, test x$want_config_output = xyes)
 104 if test x$want_config_output = xyes; then
 105   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 106   AC_CHECK_FUNCS(fopencookie)
 107 fi
 108
 109 dnl
 110 dnl OWN_WINDOW option
 111 dnl
 112
 113 AC_ARG_ENABLE([own_window],
 114               AC_HELP_STRING([--disable-own-window],
 115                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 116               [dah="$enableval"], [dah=yes])
 117
 118 if test $dah != "no"; then
 119   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 120 fi
 121
 122
 123 dnl
 124 dnl Audacious Media Player
 125 dnl
 126
 127 AC_ARG_ENABLE([audacious],
 128               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 129                              [enable audacious player support @<:@default=no@:>@]),
 130               [want_audacious="$enableval"], [want_audacious=no])
 131
 132 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 133 if test x$want_audacious = xyes; then
 134       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 135       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 136       LIBS="$LIBS $Audacious_LIBS"
 137       save_CPPFLAGS="$CPPFLAGS"
 138       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 139       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 140                        [], AC_MSG_ERROR([required header(s) not found]))
 141       CPPFLAGS="$save_CPPFLAGS"
 142       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 143 else if test x$want_audacious = xlegacy; then
 144       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 145       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 146       LIBS="$LIBS $Audacious_LIBS"
 147       save_CPPFLAGS="$CPPFLAGS"
 148       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 149       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 150       CPPFLAGS="$save_CPPFLAGS"
 151       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 152       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 153       fi
 154 fi
 155
 156
 157 dnl
 158 dnl BMPx
 159 dnl
 160
 161 AC_ARG_ENABLE([bmpx],
 162               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 163               [want_bmpx="$enableval"], [want_bmpx=no])
 164
 165 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 166 if test x$want_bmpx = xyes; then
 167   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 168   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 169   LIBS="$LIBS $BMPx_LIBS"
 170   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 171 fi
 172
 173
 174 dnl
 175 dnl Support for IBM/Lenovo notebooks
 176 dnl
 177
 178 AC_ARG_ENABLE([ibm],
 179               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 180               [want_ibm="$enableval"], [want_ibm=no])
 181
 182 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 183 if test x$want_ibm = xyes; then
 184         if test x"$uname" != xLinux; then
 185                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 186                 want_ibm=no
 187         else
 188                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 189         fi
 190 fi
 191
 192
 193 dnl
 194 dnl Hddtemp
 195 dnl
 196
 197 AC_ARG_ENABLE([hddtemp],
 198               AC_HELP_STRING([--disable-hddtemp],
 199                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 200               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 201
 202 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 203 if test x$want_hddtemp = xyes; then
 204   if test x"$uname" != xLinux; then
 205       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 206       want_hddtemp=no
 207   else
 208       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 209   fi
 210 fi
 211
 212 dnl
 213 dnl Math
 214 dnl
 215
 216 AC_ARG_ENABLE([math],
 217               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 218               [want_math="$enableval"], [want_math=yes])
 219
 220 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 221 if test x$want_math = xyes; then
 222   LIBS="$LIBS -lm"
 223   AC_DEFINE(MATH, 1, [Define if you want math support])
 224 fi
 225
 226 dnl
 227 dnl MPD
 228 dnl
 229
 230 AC_ARG_ENABLE([mpd],
 231               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 232               [want_mpd="$enableval"], [want_mpd=yes])
 233
 234 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 235 if test x$want_mpd = xyes; then
 236   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 237 fi
 238
 239 dnl
 240 dnl MOC
 241 dnl
 242
 243 AC_ARG_ENABLE([moc],
 244               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 245               [want_moc="$enableval"], [want_moc=yes])
 246
 247 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 248 if test x$want_moc = xyes; then
 249   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 250 fi
 251
 252 dnl
 253 dnl XMMS2
 254 dnl
 255
 256 AC_ARG_ENABLE([xmms2],
 257               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 258               [want_xmms2="$enableval"], [want_xmms2=no])
 259
 260 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 261 if test x$want_xmms2 = xyes; then
 262   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 263     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 264     LIBS="$LIBS $XMMS2_LIBS"
 265     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 266 fi
 267
 268 dnl
 269 dnl EVE Skill Monitor
 270 dnl
 271
 272 AC_ARG_ENABLE([eve],
 273               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 274               [want_eve="$enableval"], [want_eve=no])
 275
 276 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 277 if test x$want_eve = xyes; then
 278         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 279         PKG_CHECK_MODULES([libcurl], libcurl)
 280         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 281         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 282         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 283         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 284         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 285         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 286         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 287 fi
 288
 289 dnl
 290 dnl RSS
 291 dnl
 292
 293 AC_ARG_ENABLE([rss],
 294               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 295               [want_rss="$enableval"], [want_rss=no])
 296 #
 297 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 298 if test x$want_rss = xyes; then
 299         WANT_GLIB=yes
 300         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 301         PKG_CHECK_MODULES([libcurl], libcurl)
 302         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 303         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 304         AC_DEFINE(RSS, 1, [Define if you want rss support])
 305 fi
 306
 307 dnl
 308 dnl Wireless extensions
 309 dnl
 310
 311 AC_ARG_ENABLE([wlan],
 312               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 313               [want_wlan="$enableval"], [want_wlan=no])
 314
 315 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 316 if test x$want_wlan = xyes; then
 317   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 318   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 319         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 320 fi
 321
 322 dnl
 323 dnl IMLIB2
 324 dnl
 325
 326 AC_ARG_ENABLE([imlib2],
 327                           AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 328                           [want_imlib2="$enableval"], [want_imlib2=no])
 329
 330 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 331 if test x$want_imlib2 = xyes; then
 332         PKG_CHECK_MODULES([Imlib2], [imlib2])
 333         CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 334         LIBS="$LIBS $Imlib2_LIBS"
 335         AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 336 fi
 337
 338
 339 dnl
 340 dnl PORT_MONITORS
 341 dnl
 342
 343 AC_ARG_ENABLE([portmon],
 344               AC_HELP_STRING([--disable-portmon],
 345                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 346               [want_portmon="$enableval"], [want_portmon=yes])
 347
 348 if test x"$want_portmon" = xyes; then
 349   if test x"$uname" != xLinux; then
 350       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 351       want_portmon=no
 352   else
 353         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 354         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 355            [PORT_MONITORS_MISSING=yes])
 356         if test x"$PORT_MONITORS_MISSING" = xyes; then
 357               AC_MSG_ERROR([missing a needed network header for port monitoring])
 358         fi
 359         WANT_GLIB=yes
 360         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 361   fi
 362 fi
 363 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 364
 365
 366 dnl
 367 dnl ICONV
 368 dnl
 369
 370 AM_ICONV
 371 if test "$am_cv_func_iconv" != yes; then
 372   AC_MSG_WARN([Could not find libiconv])
 373 else
 374   LIBS="$LIBS $LIBICONV"
 375 fi
 376
 377 dnl
 378 dnl X11
 379 dnl
 380
 381 AC_ARG_ENABLE([x11],
 382               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 383               [want_x11="$enableval"], [want_x11=yes])
 384
 385 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 386 if test "x$want_x11" = "xyes"; then
 387     if $PKG_CONFIG --exists x11; then
 388       PKG_CHECK_MODULES([X11], [x11])
 389       CFLAGS="$CFLAGS $X11_CFLAGS"
 390       LIBS="$LIBS $X11_LIBS"
 391     else
 392       dnl non-modular X11 installations
 393       AC_PATH_X
 394       AC_PATH_XTRA
 395       CFLAGS="$CFLAGS $X_CFLAGS"
 396       LIBS="$LIBS $X_LIBS"
 397       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 398       if test "x$no_x" = "xyes"; then
 399         AC_MSG_ERROR([Can't locate your X11 installation])
 400       fi
 401       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 402     fi
 403     AC_DEFINE(X11, 1, [Define if you want to use X11])
 404 fi
 405
 406
 407 dnl
 408 dnl Xext Double-buffering Extension
 409 dnl
 410
 411 AC_ARG_ENABLE([double_buffer],
 412               AC_HELP_STRING([--disable-double-buffer],
 413                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 414               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 415
 416 if test "x$want_double_buffer" = "xyes"; then
 417     if test "x$want_x11" != "xyes"; then
 418       dnl silently disable if no x11
 419       want_double_buffer=no
 420     else
 421       if $PKG_CONFIG --exists xext; then
 422         PKG_CHECK_MODULES([Xext],[xext])
 423         CFLAGS="$CFLAGS $Xext_CFLAGS"
 424         LIBS="$LIBS $Xext_LIBS"
 425       else
 426         dnl non-modular X11 installation
 427         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 428                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 429       fi
 430       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 431     fi
 432 fi
 433
 434
 435 dnl
 436 dnl Xdamage Extension
 437 dnl
 438
 439 AC_ARG_ENABLE([xdamage],
 440               AC_HELP_STRING([--disable-xdamage],
 441                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 442               [want_xdamage="$enableval"], [want_xdamage=yes])
 443
 444 if test "x$want_xdamage" = "xyes"; then
 445     if test "x$want_x11" != "xyes"; then
 446       dnl silently disable if no x11
 447       want_xdamage=no
 448     else
 449       if $PKG_CONFIG --exists xdamage; then
 450         PKG_CHECK_MODULES([XDamage],[xdamage])
 451         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 452         LIBS="$LIBS $XDamage_LIBS"
 453       else
 454         dnl non-modular X11 installation
 455         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 456                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 457       fi
 458       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 459     fi
 460 fi
 461
 462
 463 dnl
 464 dnl Xft
 465 dnl
 466
 467 AC_ARG_ENABLE([xft],
 468               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 469               [want_xft="$enableval"], [want_xft=yes])
 470
 471 if test x$want_xft = "xyes"; then
 472     if test "x$want_x11" != "xyes"; then
 473       dnl silently disable if no x11
 474       want_xft=no
 475     else
 476       PKG_CHECK_MODULES([Xft], [xft])
 477       CFLAGS="$CFLAGS $Xft_CFLAGS"
 478       LIBS="$LIBS $Xft_LIBS"
 479       AC_DEFINE(XFT, 1, [Define for Xft support])
 480     fi
 481 fi
 482
 483 dnl
 484 dnl NVIDIA libXNVCtrl support
 485 dnl
 486
 487 AC_ARG_ENABLE([nvidia],
 488                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 489                 [want_nvidia="$enableval"], [want_nvidia=no])
 490 if test x$want_nvidia = xyes; then
 491     if test "x$want_x11" != "xyes"; then
 492                 # do nada
 493                 want_nvidia=no
 494         else
 495                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 496 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 497 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 498 dnl ## am I Stupid ??
 499 dnl ## it won't find the lib for some reason!?
 500                 LIBS="$LIBS -lXNVCtrl"
 501                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 502         fi
 503 fi
 504 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 505
 506 dnl
 507 dnl GLIB
 508 dnl
 509
 510 if test x$WANT_GLIB = xyes; then
 511         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 512         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 513         LIBS="$LIBS $GLib2_LIBS"
 514 fi
 515
 516 dnl
 517 dnl KVM
 518 dnl
 519
 520 if test x$WANT_KVM = xyes; then
 521   AC_CHECK_LIB(kvm, kvm_open,
 522     LIBS="$LIBS -lkvm",
 523   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 524   )
 525 fi
 526
 527 dnl
 528 dnl devstat
 529 dnl
 530
 531 if test x$WANT_DEVSTAT = xyes; then
 532   AC_CHECK_LIB(devstat, devstat_getversion,
 533          LIBS="$LIBS -ldevstat",
 534          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 535   )
 536 fi
 537
 538 dnl
 539 dnl OSSLIB for NetBSD/OpenBSD
 540 dnl
 541
 542 if test x$WANT_OSSLIB = xyes; then
 543     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 544   LIBS="$LIBS -lossaudio",
 545   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 546     )
 547 fi
 548
 549 dnl
 550 dnl ALSA for Linux
 551 dnl
 552 AC_ARG_ENABLE([alsa],
 553               AC_HELP_STRING([--disable-alsa], [disable if you do not
 554   want ALSA support @<:@default=yes@:>@]),
 555               [want_alsa="$enableval"], [want_alsa=yes])
 556
 557 if test x$want_alsa = xyes; then
 558     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 559 fi
 560 if test x$want_alsa = xyes; then
 561     AC_CHECK_LIB(asound, snd_pcm_open,LIBS="$LIBS -lasound", want_alsa=no)
 562 fi
 563 if test x$want_alsa = xyes; then
 564 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 565 fi
 566 dnl
 567 dnl Some headers
 568 dnl
 569
 570 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 571       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 572 AC_CHECK_HEADERS([sys/mount.h], [], [],
 573      [#ifdef HAVE_SYS_PARAM_H
 574       #include <sys/param.h>
 575       #endif
 576       ])
 577
 578 dnl
 579 dnl Some defines
 580 dnl
 581
 582 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 583 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 584 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 585 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 586 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 587
 588 dnl
 589 dnl Some functions
 590 dnl
 591
 592 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 593 AC_SEARCH_LIBS(clock_gettime, [rt],
 594                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 595                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 596
 597 dnl
 598 dnl Structure checks
 599 dnl
 600
 601 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 602                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 603                  [],
 604                  [#include <sys/statfs.h>])
 605
 606 dnl
 607 dnl Check for zlib
 608 dnl
 609
 610 AC_CHECK_HEADER(zlib.h,
 611                 [],
 612                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 613
 614
 615 dnl
 616 dnl Check for OpenMP support
 617 dnl
 618
 619 AX_OPENMP([
 620   AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 621   CFLAGS="$CFLAGS $OPENMP_CFLAGS"
 622 ])
 623
 624 dnl
 625 dnl Check doc stuff
 626 dnl
 627
 628 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 629 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 630 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 631 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 632   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 633 else
 634   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 635 fi
 636
 637 dnl
 638 dnl kstat in Solaris
 639 dnl
 640
 641 if test x$WANT_KSTAT = xyes; then
 642   dah=no
 643   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 644
 645   if test x$dah = xyes; then
 646     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 647     LDFLAGS="$LDFLAGS -lkstat"
 648   fi
 649 fi
 650
 651 AC_DEFUN([AM_LANGINFO_CODESET],
 652 [
 653   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 654     [AC_TRY_LINK([#include <langinfo.h>],
 655       [char* cs = nl_langinfo(CODESET);],
 656       am_cv_langinfo_codeset=yes,
 657       am_cv_langinfo_codeset=no)
 658     ])
 659   if test $am_cv_langinfo_codeset = yes; then
 660     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 661       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 662   fi
 663 ])
 664
 665
 666 dnl ************************
 667 dnl * Linker optimizations *
 668 dnl ************************
 669 AC_MSG_CHECKING([if $LD accepts -O1])
 670 case `$LD -O1 -v 2>&1 </dev/null` in
 671 *GNU* | *BSD*)
 672   LDFLAGS="$LDFLAGS -Wl,-O1"
 673   AC_MSG_RESULT([yes])
 674   ;;
 675 *)
 676   AC_MSG_RESULT([no])
 677   ;;
 678 esac
 679
 680 dnl Solve multiple definitions (only necessary when gnulib is used)
 681 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 682
 683 dnl
 684 dnl Da.
 685 dnl
 686
 687 CFLAGS="$CFLAGS -Wall -W"
 688
 689 dnl
 690 dnl debug
 691 dnl
 692
 693 AC_ARG_ENABLE([debug],
 694               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 695               [want_debug="$enableval"], [want_debug=no])
 696
 697 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 698   CFLAGS="$CFLAGS -g3"
 699   AC_DEFINE([DEBUG], 1, [Define for debugging])
 700 fi
 701
 702 dnl
 703 dnl testing
 704 dnl
 705
 706 AC_ARG_ENABLE([testing],
 707               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 708               [want_testing="$enableval"], [want_testing=no])
 709
 710 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 711   if test "x$want_debug" = "xyes"; then
 712     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 713     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 714   else
 715     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 716     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 717   fi
 718 fi
 719
 720 AC_SUBST(CFLAGS)
 721 AC_SUBST(X11_LIBS)
 722
 723 AC_OUTPUT
 724
 725 dnl
 726 dnl Print summary
 727 dnl
 728 cat << EOF
 729
 730 $PACKAGE $VERSION configured successfully:
 731
 732  Installing into:   $prefix
 733  System config dir: $sysconfdir
 734  C compiler flags:  $CFLAGS
 735  Linker flags:      $LDFLAGS
 736  Libraries:         $LIBS
 737
 738  * X11:
 739   X11 support:      $want_x11
 740   XDamage support:  $want_xdamage
 741   XDBE support:     $want_double_buffer
 742   Xft support:      $want_xft
 743
 744  * Music detection:
 745   Audacious:        $want_audacious
 746   BMPx:             $want_bmpx
 747   MPD:              $want_mpd
 748   MOC:              $want_moc
 749   XMMS2:            $want_xmms2
 750
 751  * General:
 752   math:             $want_math
 753   hddtemp:          $want_hddtemp
 754   portmon:          $want_portmon
 755   RSS:              $want_rss
 756   wireless:         $want_wlan
 757   IBM:              $want_ibm
 758   nvidia:           $want_nvidia
 759   eve-online:       $want_eve
 760   config-output:    $want_config_output
 761   IMLIB2:           $want_imlib2
 762   ALSA mixer:       $want_alsa
 763 EOF