vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [2])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58     ;;
  59 #  NetBSD*)
  60 #    WANT_KVM=yes
  61 #    WANT_OSSLIB=yes
  62 #    ;;
  63
  64   OpenBSD*)
  65     WANT_KVM=yes
  66     WANT_OSSLIB=yes
  67     ;;
  68
  69 # Solaris doesn't work at all right now
  70 #  SunOS*)
  71 #    WANT_KSTAT=yes
  72 #    ;;
  73
  74   *)
  75     echo "Your operating system $uname isn't supported"
  76     echo "Feel free to help. :P"
  77     exit 1
  78     ;;
  79 esac
  80
  81 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  82 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  83 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  84 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  85 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  86
  87 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  88 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  89 AC_SUBST(BUILD_DATE)
  90 AC_SUBST(BUILD_ARCH)
  91
  92
  93 dnl
  94 dnl BUILD_CONFIG_OUTPUT option
  95 dnl
  96
  97 AC_ARG_ENABLE([config_output],
  98               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) @<:@default=yes@:>@]),
  99               [want_config_output="$enableval"], [want_config_output=yes])
 100
 101 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 102 AM_CONDITIONAL(BUILD_FOR_FOPENCOOKIE, test x$want_config_output = xyes)
 103 if test x$want_config_output = xyes; then
 104   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 105   AC_CHECK_FUNCS(fopencookie)
 106 fi
 107
 108 dnl
 109 dnl OWN_WINDOW option
 110 dnl
 111
 112 AC_ARG_ENABLE([own_window],
 113               AC_HELP_STRING([--disable-own-window],
 114                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 115               [dah="$enableval"], [dah=yes])
 116
 117 if test $dah != "no"; then
 118   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 119 fi
 120
 121
 122 dnl
 123 dnl Audacious Media Player
 124 dnl
 125
 126 AC_ARG_ENABLE([audacious],
 127               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 128                              [enable audacious player support @<:@default=no@:>@]),
 129               [want_audacious="$enableval"], [want_audacious=no])
 130
 131 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 132 if test x$want_audacious = xyes; then
 133       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 134       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 135       LIBS="$LIBS $Audacious_LIBS"
 136       save_CPPFLAGS="$CPPFLAGS"
 137       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 138       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 139                        [], AC_MSG_ERROR([required header(s) not found]))
 140       CPPFLAGS="$save_CPPFLAGS"
 141       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 142 else if test x$want_audacious = xlegacy; then
 143       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 144       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 145       LIBS="$LIBS $Audacious_LIBS"
 146       save_CPPFLAGS="$CPPFLAGS"
 147       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 148       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 149       CPPFLAGS="$save_CPPFLAGS"
 150       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 151       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 152       fi
 153 fi
 154
 155
 156 dnl
 157 dnl BMPx
 158 dnl
 159
 160 AC_ARG_ENABLE([bmpx],
 161               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 162               [want_bmpx="$enableval"], [want_bmpx=no])
 163
 164 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 165 if test x$want_bmpx = xyes; then
 166   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 167   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 168   LIBS="$LIBS $BMPx_LIBS"
 169   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 170 fi
 171
 172
 173 dnl
 174 dnl Support for IBM/Lenovo notebooks
 175 dnl
 176
 177 AC_ARG_ENABLE([ibm],
 178               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 179               [want_ibm="$enableval"], [want_ibm=no])
 180
 181 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 182 if test x$want_ibm = xyes; then
 183         if test x"$uname" != xLinux; then
 184                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 185                 want_ibm=no
 186         else
 187                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 188         fi
 189 fi
 190
 191
 192 dnl
 193 dnl Hddtemp
 194 dnl
 195
 196 AC_ARG_ENABLE([hddtemp],
 197               AC_HELP_STRING([--disable-hddtemp],
 198                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 199               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 200
 201 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 202 if test x$want_hddtemp = xyes; then
 203   if test x"$uname" != xLinux; then
 204       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 205       want_hddtemp=no
 206   else
 207       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 208   fi
 209 fi
 210
 211
 212 dnl
 213 dnl Apcupsd
 214 dnl
 215
 216 AC_ARG_ENABLE([apcupsd],
 217               AC_HELP_STRING([--disable-apcupsd],
 218                              [disable if you do not want apcupsd support @<:@default=yes@:>@]),
 219               [want_apcupsd="$enableval"], [want_apcupsd=yes])
 220
 221 if test x$want_apcupsd = xyes; then
 222   if test x"$uname" != xLinux; then
 223       AC_MSG_NOTICE([apcupsd not supported on $uname... disabling])
 224       want_apcupsd=no
 225   else
 226       AC_DEFINE(APCUPSD, 1, [Define if you want apcupsd support])
 227   fi
 228 fi
 229 AM_CONDITIONAL(BUILD_APCUPSD, test x$want_apcupsd = xyes)
 230
 231
 232 dnl
 233 dnl Math
 234 dnl
 235
 236 AC_ARG_ENABLE([math],
 237               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 238               [want_math="$enableval"], [want_math=yes])
 239
 240 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 241 if test x$want_math = xyes; then
 242   LIBS="$LIBS -lm"
 243   AC_DEFINE(MATH, 1, [Define if you want math support])
 244 fi
 245
 246 dnl
 247 dnl MPD
 248 dnl
 249
 250 AC_ARG_ENABLE([mpd],
 251               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 252               [want_mpd="$enableval"], [want_mpd=yes])
 253
 254 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 255 if test x$want_mpd = xyes; then
 256   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 257 fi
 258
 259 dnl
 260 dnl MOC
 261 dnl
 262
 263 AC_ARG_ENABLE([moc],
 264               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 265               [want_moc="$enableval"], [want_moc=yes])
 266
 267 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 268 if test x$want_moc = xyes; then
 269   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 270 fi
 271
 272 dnl
 273 dnl XMMS2
 274 dnl
 275
 276 AC_ARG_ENABLE([xmms2],
 277               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 278               [want_xmms2="$enableval"], [want_xmms2=no])
 279
 280 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 281 if test x$want_xmms2 = xyes; then
 282   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 283     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 284     LIBS="$LIBS $XMMS2_LIBS"
 285     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 286 fi
 287
 288 dnl
 289 dnl EVE Skill Monitor
 290 dnl
 291
 292 AC_ARG_ENABLE([eve],
 293               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 294               [want_eve="$enableval"], [want_eve=no])
 295
 296 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 297 if test x$want_eve = xyes; then
 298         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 299         PKG_CHECK_MODULES([libcurl], libcurl)
 300         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 301         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 302         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 303         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 304         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 305         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 306         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 307 fi
 308
 309 dnl
 310 dnl RSS
 311 dnl
 312
 313 AC_ARG_ENABLE([rss],
 314               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 315               [want_rss="$enableval"], [want_rss=no])
 316 #
 317 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 318 if test x$want_rss = xyes; then
 319         WANT_GLIB=yes
 320         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 321         PKG_CHECK_MODULES([libcurl], libcurl)
 322         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 323         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 324         AC_DEFINE(RSS, 1, [Define if you want rss support])
 325 fi
 326
 327 dnl
 328 dnl Lua
 329 dnl
 330
 331 AC_ARG_ENABLE([lua],
 332               AC_HELP_STRING([--enable-lua], [enable if you want Lua scripting support @<:@default=yes@:>@]),
 333               [want_lua="$enableval"], [want_lua=yes])
 334 #
 335 AM_CONDITIONAL(BUILD_LUA, test x$want_lua = xyes)
 336 if test x$want_lua = xyes; then
 337         PKG_CHECK_MODULES(LUA, lua >= 5.1, [ ],[
 338                 PKG_CHECK_MODULES(LUA51, lua-5.1 >= 5.1, [ ],[
 339                         PKG_CHECK_MODULES(LUA51, lua5.1 >= 5.1)
 340                 ])
 341         ])
 342         CFLAGS="$CFLAGS $LUA_CFLAGS $LUA51_CFLAGS"
 343         LIBS="$LIBS $LUA_LIBS $LUA51_LIBS"
 344         AC_DEFINE(HAVE_LUA, 1, [Define if you want Lua scripting support])
 345 fi
 346
 347 dnl
 348 dnl Wireless extensions
 349 dnl
 350
 351 AC_ARG_ENABLE([wlan],
 352               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 353               [want_wlan="$enableval"], [want_wlan=no])
 354
 355 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 356 if test x$want_wlan = xyes; then
 357   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 358   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 359         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 360 fi
 361
 362 dnl
 363 dnl PORT_MONITORS
 364 dnl
 365
 366 AC_ARG_ENABLE([portmon],
 367               AC_HELP_STRING([--disable-portmon],
 368                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 369               [want_portmon="$enableval"], [want_portmon=yes])
 370
 371 if test x"$want_portmon" = xyes; then
 372   if test x"$uname" != xLinux; then
 373       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 374       want_portmon=no
 375   else
 376         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 377         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 378            [PORT_MONITORS_MISSING=yes])
 379         if test x"$PORT_MONITORS_MISSING" = xyes; then
 380               AC_MSG_ERROR([missing a needed network header for port monitoring])
 381         fi
 382         WANT_GLIB=yes
 383         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 384   fi
 385 fi
 386 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 387
 388
 389 dnl
 390 dnl ICONV
 391 dnl
 392
 393 AM_ICONV
 394 if test "$am_cv_func_iconv" != yes; then
 395   AC_MSG_WARN([Could not find libiconv])
 396 else
 397   LIBS="$LIBS $LIBICONV"
 398 fi
 399
 400 dnl
 401 dnl X11
 402 dnl
 403
 404 AC_ARG_ENABLE([x11],
 405               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 406               [want_x11="$enableval"], [want_x11=yes])
 407
 408 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 409 if test "x$want_x11" = "xyes"; then
 410     if $PKG_CONFIG --exists x11; then
 411       PKG_CHECK_MODULES([X11], [x11])
 412       CFLAGS="$CFLAGS $X11_CFLAGS"
 413       LIBS="$LIBS $X11_LIBS"
 414     else
 415       dnl non-modular X11 installations
 416       AC_PATH_X
 417       AC_PATH_XTRA
 418       CFLAGS="$CFLAGS $X_CFLAGS"
 419       LIBS="$LIBS $X_LIBS"
 420       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 421       if test "x$no_x" = "xyes"; then
 422         AC_MSG_ERROR([Can't locate your X11 installation])
 423       fi
 424       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 425     fi
 426     AC_DEFINE(X11, 1, [Define if you want to use X11])
 427 fi
 428
 429
 430 dnl
 431 dnl Xext Double-buffering Extension
 432 dnl
 433
 434 AC_ARG_ENABLE([double_buffer],
 435               AC_HELP_STRING([--disable-double-buffer],
 436                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 437               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 438
 439 if test "x$want_double_buffer" = "xyes"; then
 440     if test "x$want_x11" != "xyes"; then
 441       dnl silently disable if no x11
 442       want_double_buffer=no
 443     else
 444       if $PKG_CONFIG --exists xext; then
 445         PKG_CHECK_MODULES([Xext],[xext])
 446         CFLAGS="$CFLAGS $Xext_CFLAGS"
 447         LIBS="$LIBS $Xext_LIBS"
 448       else
 449         dnl non-modular X11 installation
 450         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 451                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 452       fi
 453       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 454     fi
 455 fi
 456
 457
 458 dnl
 459 dnl Xdamage Extension
 460 dnl
 461
 462 AC_ARG_ENABLE([xdamage],
 463               AC_HELP_STRING([--disable-xdamage],
 464                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 465               [want_xdamage="$enableval"], [want_xdamage=yes])
 466
 467 if test "x$want_xdamage" = "xyes"; then
 468     if test "x$want_x11" != "xyes"; then
 469       dnl silently disable if no x11
 470       want_xdamage=no
 471     else
 472       if $PKG_CONFIG --exists xdamage; then
 473         PKG_CHECK_MODULES([XDamage],[xdamage])
 474         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 475         LIBS="$LIBS $XDamage_LIBS"
 476       else
 477         dnl non-modular X11 installation
 478         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 479                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 480       fi
 481       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 482     fi
 483 fi
 484
 485
 486 dnl
 487 dnl Xft
 488 dnl
 489
 490 AC_ARG_ENABLE([xft],
 491               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 492               [want_xft="$enableval"], [want_xft=yes])
 493
 494 if test x$want_xft = "xyes"; then
 495     if test "x$want_x11" != "xyes"; then
 496       dnl silently disable if no x11
 497       want_xft=no
 498     else
 499       PKG_CHECK_MODULES([Xft], [xft])
 500       CFLAGS="$CFLAGS $Xft_CFLAGS"
 501       LIBS="$LIBS $Xft_LIBS"
 502       AC_DEFINE(XFT, 1, [Define for Xft support])
 503     fi
 504 fi
 505
 506 dnl
 507 dnl IMLIB2
 508 dnl
 509
 510 AC_ARG_ENABLE([imlib2],
 511                           AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 512                           [want_imlib2="$enableval"], [want_imlib2=no])
 513 if test x$want_imlib2 = xyes; then
 514         if test "x$want_x11" != "xyes"; then
 515                 dnl silently disable if no x11
 516                 want_imlib2=no
 517         else
 518                 PKG_CHECK_MODULES([Imlib2], [imlib2])
 519                 CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 520                 LIBS="$LIBS $Imlib2_LIBS"
 521                 AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 522         fi
 523 fi
 524 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 525
 526 dnl
 527 dnl NVIDIA libXNVCtrl support
 528 dnl
 529
 530 AC_ARG_ENABLE([nvidia],
 531                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 532                 [want_nvidia="$enableval"], [want_nvidia=no])
 533 if test x$want_nvidia = xyes; then
 534     if test "x$want_x11" != "xyes"; then
 535                 # do nada
 536                 want_nvidia=no
 537         else
 538                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 539 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 540 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 541 dnl ## am I Stupid ??
 542 dnl ## it won't find the lib for some reason!?
 543                 LIBS="$LIBS -lXNVCtrl"
 544                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 545         fi
 546 fi
 547 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 548
 549 dnl
 550 dnl GLIB
 551 dnl
 552
 553 if test x$WANT_GLIB = xyes; then
 554         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 555         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 556         LIBS="$LIBS $GLib2_LIBS"
 557 fi
 558
 559 dnl
 560 dnl KVM
 561 dnl
 562
 563 if test x$WANT_KVM = xyes; then
 564   AC_CHECK_LIB(kvm, kvm_open,
 565     LIBS="$LIBS -lkvm",
 566   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 567   )
 568 fi
 569
 570 dnl
 571 dnl devstat
 572 dnl
 573
 574 if test x$WANT_DEVSTAT = xyes; then
 575   AC_CHECK_LIB(devstat, devstat_getversion,
 576          LIBS="$LIBS -ldevstat",
 577          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 578   )
 579 fi
 580
 581 dnl
 582 dnl OSSLIB for NetBSD/OpenBSD
 583 dnl
 584
 585 if test x$WANT_OSSLIB = xyes; then
 586     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 587   LIBS="$LIBS -lossaudio",
 588   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 589     )
 590 fi
 591
 592 dnl
 593 dnl ALSA for Linux
 594 dnl
 595 AC_ARG_ENABLE([alsa],
 596               AC_HELP_STRING([--disable-alsa], [disable if you do not
 597   want ALSA support @<:@default=yes@:>@]),
 598               [want_alsa="$enableval"], [want_alsa=yes])
 599
 600 if test x$want_alsa = xyes; then
 601     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 602 fi
 603 if test x$want_alsa = xyes; then
 604     AC_CHECK_LIB(asound, snd_pcm_open,LIBS="$LIBS -lasound", want_alsa=no)
 605 fi
 606 if test x$want_alsa = xyes; then
 607 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 608 fi
 609 dnl
 610 dnl Some headers
 611 dnl
 612
 613 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 614       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 615 AC_CHECK_HEADERS([sys/mount.h], [], [],
 616      [#ifdef HAVE_SYS_PARAM_H
 617       #include <sys/param.h>
 618       #endif
 619       ])
 620 # check if we have inotify support
 621 AC_CHECK_HEADERS([sys/inotify.h])
 622
 623 dnl
 624 dnl Some defines
 625 dnl
 626
 627 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 628 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 629 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 630 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 631 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 632
 633 dnl
 634 dnl Some functions
 635 dnl
 636
 637 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 638 AC_SEARCH_LIBS(clock_gettime, [rt],
 639                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 640                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 641
 642 dnl
 643 dnl Structure checks
 644 dnl
 645
 646 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 647                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 648                  [],
 649                  [#include <sys/statfs.h>])
 650
 651 dnl
 652 dnl Check for zlib
 653 dnl
 654
 655 AC_CHECK_HEADER(zlib.h,
 656                 [],
 657                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 658
 659
 660 dnl
 661 dnl Check for OpenMP support
 662 dnl
 663
 664 AC_ARG_ENABLE([openmp],
 665               AC_HELP_STRING([--enable-openmp], [enable if you want OpenMP support @<:@default=no@:>@]),
 666               [want_openmp="$enableval"], [want_openmp=no])
 667
 668 if test x$want_openmp = xyes; then
 669         AX_OPENMP([
 670           gcc_version=`$CC -dumpversion`
 671           gcc_major=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 672           gcc_minor=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 673           dnl check that the gcc version is >=4.3, if we're using gcc
 674           if test ! "x$GCC" = "xyes" -o $gcc_major -ge 4 -a $gcc_minor -ge 3; then
 675             AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 676             CFLAGS="$CFLAGS $OPENMP_CFLAGS"
 677           else
 678             want_openmp=no
 679           fi
 680
 681         ])
 682 fi
 683
 684 dnl
 685 dnl Check doc stuff
 686 dnl
 687
 688 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 689 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 690 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 691 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 692   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 693 else
 694   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 695 fi
 696
 697 dnl
 698 dnl kstat in Solaris
 699 dnl
 700
 701 if test x$WANT_KSTAT = xyes; then
 702   dah=no
 703   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 704
 705   if test x$dah = xyes; then
 706     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 707     LDFLAGS="$LDFLAGS -lkstat"
 708   fi
 709 fi
 710
 711 AC_DEFUN([AM_LANGINFO_CODESET],
 712 [
 713   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 714     [AC_TRY_LINK([#include <langinfo.h>],
 715       [char* cs = nl_langinfo(CODESET);],
 716       am_cv_langinfo_codeset=yes,
 717       am_cv_langinfo_codeset=no)
 718     ])
 719   if test $am_cv_langinfo_codeset = yes; then
 720     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 721       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 722   fi
 723 ])
 724
 725
 726 dnl ************************
 727 dnl * Linker optimizations *
 728 dnl ************************
 729 AC_MSG_CHECKING([if $LD accepts -O1])
 730 case `$LD -O1 -v 2>&1 </dev/null` in
 731 *GNU* | *BSD*)
 732   LDFLAGS="$LDFLAGS -Wl,-O1"
 733   AC_MSG_RESULT([yes])
 734   ;;
 735 *)
 736   AC_MSG_RESULT([no])
 737   ;;
 738 esac
 739
 740 dnl Solve multiple definitions (only necessary when gnulib is used)
 741 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 742
 743 dnl
 744 dnl Da.
 745 dnl
 746
 747 CFLAGS="$CFLAGS -Wall -W"
 748
 749 dnl
 750 dnl debug
 751 dnl
 752
 753 AC_ARG_ENABLE([debug],
 754               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 755               [want_debug="$enableval"], [want_debug=no])
 756
 757 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 758   CFLAGS="$CFLAGS -g3"
 759   AC_DEFINE([DEBUG], 1, [Define for debugging])
 760 fi
 761
 762 dnl
 763 dnl testing
 764 dnl
 765
 766 AC_ARG_ENABLE([testing],
 767               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 768               [want_testing="$enableval"], [want_testing=no])
 769
 770 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 771   if test "x$want_debug" = "xyes"; then
 772     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 773     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 774   else
 775     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 776     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 777   fi
 778 fi
 779
 780 AC_SUBST(CFLAGS)
 781 AC_SUBST(X11_LIBS)
 782
 783 AC_OUTPUT
 784
 785 dnl
 786 dnl Print summary
 787 dnl
 788 cat << EOF
 789
 790 $PACKAGE $VERSION configured successfully:
 791
 792  Installing into:   $prefix
 793  System config dir: $sysconfdir
 794  C compiler flags:  $CFLAGS
 795  Linker flags:      $LDFLAGS
 796  Libraries:         $LIBS
 797
 798  * X11:
 799   X11 support:      $want_x11
 800   XDamage support:  $want_xdamage
 801   XDBE support:     $want_double_buffer
 802   Xft support:      $want_xft
 803
 804  * Music detection:
 805   Audacious:        $want_audacious
 806   BMPx:             $want_bmpx
 807   MPD:              $want_mpd
 808   MOC:              $want_moc
 809   XMMS2:            $want_xmms2
 810
 811  * General:
 812   OpenMP:           $want_openmp
 813   math:             $want_math
 814   hddtemp:          $want_hddtemp
 815   portmon:          $want_portmon
 816   RSS:              $want_rss
 817   Lua:              $want_lua
 818   wireless:         $want_wlan
 819   IBM:              $want_ibm
 820   nvidia:           $want_nvidia
 821   eve-online:       $want_eve
 822   config-output:    $want_config_output
 823   Imlib2:           $want_imlib2
 824   ALSA mixer:       $want_alsa
 825   apcupsd:          $want_apcupsd
 826 EOF