vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [2])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58         want_config_output=no
  59         ;;
  60 #  NetBSD*)
  61 #    WANT_KVM=yes
  62 #    WANT_OSSLIB=yes
  63 #    ;;
  64
  65   OpenBSD*)
  66     WANT_KVM=yes
  67     WANT_OSSLIB=yes
  68     ;;
  69
  70 # Solaris doesn't work at all right now
  71 #  SunOS*)
  72 #    WANT_KSTAT=yes
  73 #    ;;
  74
  75   *)
  76     echo "Your operating system $uname isn't supported"
  77     echo "Feel free to help. :P"
  78     exit 1
  79     ;;
  80 esac
  81
  82 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  83 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  84 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  85 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  86 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  87
  88 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  89 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  90 AC_SUBST(BUILD_DATE)
  91 AC_SUBST(BUILD_ARCH)
  92
  93
  94 dnl
  95 dnl BUILD_CONFIG_OUTPUT option
  96 dnl
  97
  98 AC_ARG_ENABLE([config_output],
  99               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) Note: not available on FreeBSD @<:@default=yes@:>@]),
 100               [want_config_output="$enableval"], [want_config_output=yes])
 101
 102 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 103 AM_CONDITIONAL(BUILD_FOR_FOPENCOOKIE, test x$want_config_output = xyes)
 104 if test x$want_config_output = xyes; then
 105   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 106   AC_CHECK_FUNCS(fopencookie)
 107 fi
 108
 109 dnl
 110 dnl OWN_WINDOW option
 111 dnl
 112
 113 AC_ARG_ENABLE([own_window],
 114               AC_HELP_STRING([--disable-own-window],
 115                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 116               [dah="$enableval"], [dah=yes])
 117
 118 if test $dah != "no"; then
 119   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 120 fi
 121
 122
 123 dnl
 124 dnl Audacious Media Player
 125 dnl
 126
 127 AC_ARG_ENABLE([audacious],
 128               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 129                              [enable audacious player support @<:@default=no@:>@]),
 130               [want_audacious="$enableval"], [want_audacious=no])
 131
 132 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 133 if test x$want_audacious = xyes; then
 134       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 135       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 136       LIBS="$LIBS $Audacious_LIBS"
 137       save_CPPFLAGS="$CPPFLAGS"
 138       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 139       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 140                        [], AC_MSG_ERROR([required header(s) not found]))
 141       CPPFLAGS="$save_CPPFLAGS"
 142       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 143 else if test x$want_audacious = xlegacy; then
 144       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 145       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 146       LIBS="$LIBS $Audacious_LIBS"
 147       save_CPPFLAGS="$CPPFLAGS"
 148       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 149       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 150       CPPFLAGS="$save_CPPFLAGS"
 151       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 152       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 153       fi
 154 fi
 155
 156
 157 dnl
 158 dnl BMPx
 159 dnl
 160
 161 AC_ARG_ENABLE([bmpx],
 162               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 163               [want_bmpx="$enableval"], [want_bmpx=no])
 164
 165 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 166 if test x$want_bmpx = xyes; then
 167   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 168   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 169   LIBS="$LIBS $BMPx_LIBS"
 170   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 171 fi
 172
 173
 174 dnl
 175 dnl Support for IBM/Lenovo notebooks
 176 dnl
 177
 178 AC_ARG_ENABLE([ibm],
 179               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 180               [want_ibm="$enableval"], [want_ibm=no])
 181
 182 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 183 if test x$want_ibm = xyes; then
 184         if test x"$uname" != xLinux; then
 185                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 186                 want_ibm=no
 187         else
 188                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 189         fi
 190 fi
 191
 192
 193 dnl
 194 dnl Hddtemp
 195 dnl
 196
 197 AC_ARG_ENABLE([hddtemp],
 198               AC_HELP_STRING([--disable-hddtemp],
 199                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 200               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 201
 202 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 203 if test x$want_hddtemp = xyes; then
 204   if test x"$uname" != xLinux; then
 205       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 206       want_hddtemp=no
 207   else
 208       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 209   fi
 210 fi
 211
 212 dnl
 213 dnl Math
 214 dnl
 215
 216
 217 dnl
 218 dnl Apcupsd
 219 dnl
 220
 221 AC_ARG_ENABLE([apcupsd],
 222               AC_HELP_STRING([--disable-apcupsd],
 223                              [disable if you do not want apcupsd support @<:@default=yes@:>@]),
 224               [want_apcupsd="$enableval"], [want_apcupsd=yes])
 225
 226 AM_CONDITIONAL(BUILD_APCUPSD, test x$want_apcupsd = xyes)
 227 if test x$want_apcupsd = xyes; then
 228   if test x"$uname" != xLinux; then
 229       AC_MSG_NOTICE([apcupsd not supported on $uname... disabling])
 230       want_apcupsd=no
 231   else
 232       AC_DEFINE(APCUPSD, 1, [Define if you want apcupsd support])
 233   fi
 234 fi
 235
 236 AC_ARG_ENABLE([math],
 237               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 238               [want_math="$enableval"], [want_math=yes])
 239
 240 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 241 if test x$want_math = xyes; then
 242   LIBS="$LIBS -lm"
 243   AC_DEFINE(MATH, 1, [Define if you want math support])
 244 fi
 245
 246 dnl
 247 dnl MPD
 248 dnl
 249
 250 AC_ARG_ENABLE([mpd],
 251               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 252               [want_mpd="$enableval"], [want_mpd=yes])
 253
 254 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 255 if test x$want_mpd = xyes; then
 256   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 257 fi
 258
 259 dnl
 260 dnl MOC
 261 dnl
 262
 263 AC_ARG_ENABLE([moc],
 264               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 265               [want_moc="$enableval"], [want_moc=yes])
 266
 267 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 268 if test x$want_moc = xyes; then
 269   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 270 fi
 271
 272 dnl
 273 dnl XMMS2
 274 dnl
 275
 276 AC_ARG_ENABLE([xmms2],
 277               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 278               [want_xmms2="$enableval"], [want_xmms2=no])
 279
 280 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 281 if test x$want_xmms2 = xyes; then
 282   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 283     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 284     LIBS="$LIBS $XMMS2_LIBS"
 285     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 286 fi
 287
 288 dnl
 289 dnl EVE Skill Monitor
 290 dnl
 291
 292 AC_ARG_ENABLE([eve],
 293               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 294               [want_eve="$enableval"], [want_eve=no])
 295
 296 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 297 if test x$want_eve = xyes; then
 298         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 299         PKG_CHECK_MODULES([libcurl], libcurl)
 300         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 301         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 302         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 303         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 304         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 305         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 306         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 307 fi
 308
 309 dnl
 310 dnl RSS
 311 dnl
 312
 313 AC_ARG_ENABLE([rss],
 314               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 315               [want_rss="$enableval"], [want_rss=no])
 316 #
 317 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 318 if test x$want_rss = xyes; then
 319         WANT_GLIB=yes
 320         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 321         PKG_CHECK_MODULES([libcurl], libcurl)
 322         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 323         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 324         AC_DEFINE(RSS, 1, [Define if you want rss support])
 325 fi
 326
 327 dnl
 328 dnl Lua
 329 dnl
 330
 331 AC_ARG_ENABLE([lua],
 332               AC_HELP_STRING([--enable-lua], [enable if you want Lua scripting support @<:@default=no@:>@]),
 333               [want_lua="$enableval"], [want_lua=no])
 334 #
 335 AM_CONDITIONAL(BUILD_LUA, test x$want_lua = xyes)
 336 if test x$want_lua = xyes; then
 337         PKG_CHECK_MODULES(LUA, lua >= 5.1, [ ],[
 338                 PKG_CHECK_MODULES(LUA51, lua5.1 >= 5.1, [ ])
 339         ])
 340         CFLAGS="$CFLAGS $LUA_CFLAGS $LUA51_CFLAGS"
 341         LIBS="$LIBS $LUA_LIBS $LUA51_LIBS"
 342         AC_DEFINE(HAVE_LUA, 1, [Define if you want Lua scripting support])
 343 fi
 344
 345 dnl
 346 dnl Wireless extensions
 347 dnl
 348
 349 AC_ARG_ENABLE([wlan],
 350               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 351               [want_wlan="$enableval"], [want_wlan=no])
 352
 353 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 354 if test x$want_wlan = xyes; then
 355   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 356   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 357         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 358 fi
 359
 360 dnl
 361 dnl PORT_MONITORS
 362 dnl
 363
 364 AC_ARG_ENABLE([portmon],
 365               AC_HELP_STRING([--disable-portmon],
 366                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 367               [want_portmon="$enableval"], [want_portmon=yes])
 368
 369 if test x"$want_portmon" = xyes; then
 370   if test x"$uname" != xLinux; then
 371       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 372       want_portmon=no
 373   else
 374         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 375         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 376            [PORT_MONITORS_MISSING=yes])
 377         if test x"$PORT_MONITORS_MISSING" = xyes; then
 378               AC_MSG_ERROR([missing a needed network header for port monitoring])
 379         fi
 380         WANT_GLIB=yes
 381         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 382   fi
 383 fi
 384 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 385
 386
 387 dnl
 388 dnl ICONV
 389 dnl
 390
 391 AM_ICONV
 392 if test "$am_cv_func_iconv" != yes; then
 393   AC_MSG_WARN([Could not find libiconv])
 394 else
 395   LIBS="$LIBS $LIBICONV"
 396 fi
 397
 398 dnl
 399 dnl X11
 400 dnl
 401
 402 AC_ARG_ENABLE([x11],
 403               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 404               [want_x11="$enableval"], [want_x11=yes])
 405
 406 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 407 if test "x$want_x11" = "xyes"; then
 408     if $PKG_CONFIG --exists x11; then
 409       PKG_CHECK_MODULES([X11], [x11])
 410       CFLAGS="$CFLAGS $X11_CFLAGS"
 411       LIBS="$LIBS $X11_LIBS"
 412     else
 413       dnl non-modular X11 installations
 414       AC_PATH_X
 415       AC_PATH_XTRA
 416       CFLAGS="$CFLAGS $X_CFLAGS"
 417       LIBS="$LIBS $X_LIBS"
 418       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 419       if test "x$no_x" = "xyes"; then
 420         AC_MSG_ERROR([Can't locate your X11 installation])
 421       fi
 422       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 423     fi
 424     AC_DEFINE(X11, 1, [Define if you want to use X11])
 425 fi
 426
 427
 428 dnl
 429 dnl Xext Double-buffering Extension
 430 dnl
 431
 432 AC_ARG_ENABLE([double_buffer],
 433               AC_HELP_STRING([--disable-double-buffer],
 434                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 435               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 436
 437 if test "x$want_double_buffer" = "xyes"; then
 438     if test "x$want_x11" != "xyes"; then
 439       dnl silently disable if no x11
 440       want_double_buffer=no
 441     else
 442       if $PKG_CONFIG --exists xext; then
 443         PKG_CHECK_MODULES([Xext],[xext])
 444         CFLAGS="$CFLAGS $Xext_CFLAGS"
 445         LIBS="$LIBS $Xext_LIBS"
 446       else
 447         dnl non-modular X11 installation
 448         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 449                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 450       fi
 451       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 452     fi
 453 fi
 454
 455
 456 dnl
 457 dnl Xdamage Extension
 458 dnl
 459
 460 AC_ARG_ENABLE([xdamage],
 461               AC_HELP_STRING([--disable-xdamage],
 462                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 463               [want_xdamage="$enableval"], [want_xdamage=yes])
 464
 465 if test "x$want_xdamage" = "xyes"; then
 466     if test "x$want_x11" != "xyes"; then
 467       dnl silently disable if no x11
 468       want_xdamage=no
 469     else
 470       if $PKG_CONFIG --exists xdamage; then
 471         PKG_CHECK_MODULES([XDamage],[xdamage])
 472         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 473         LIBS="$LIBS $XDamage_LIBS"
 474       else
 475         dnl non-modular X11 installation
 476         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 477                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 478       fi
 479       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 480     fi
 481 fi
 482
 483
 484 dnl
 485 dnl Xft
 486 dnl
 487
 488 AC_ARG_ENABLE([xft],
 489               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 490               [want_xft="$enableval"], [want_xft=yes])
 491
 492 if test x$want_xft = "xyes"; then
 493     if test "x$want_x11" != "xyes"; then
 494       dnl silently disable if no x11
 495       want_xft=no
 496     else
 497       PKG_CHECK_MODULES([Xft], [xft])
 498       CFLAGS="$CFLAGS $Xft_CFLAGS"
 499       LIBS="$LIBS $Xft_LIBS"
 500       AC_DEFINE(XFT, 1, [Define for Xft support])
 501     fi
 502 fi
 503
 504 dnl
 505 dnl IMLIB2
 506 dnl
 507
 508 AC_ARG_ENABLE([imlib2],
 509                           AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 510                           [want_imlib2="$enableval"], [want_imlib2=no])
 511 if test x$want_imlib2 = xyes; then
 512         if test "x$want_x11" != "xyes"; then
 513                 dnl silently disable if no x11
 514                 want_imlib2=no
 515         else
 516                 PKG_CHECK_MODULES([Imlib2], [imlib2])
 517                 CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 518                 LIBS="$LIBS $Imlib2_LIBS"
 519                 AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 520         fi
 521 fi
 522 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 523
 524 dnl
 525 dnl NVIDIA libXNVCtrl support
 526 dnl
 527
 528 AC_ARG_ENABLE([nvidia],
 529                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 530                 [want_nvidia="$enableval"], [want_nvidia=no])
 531 if test x$want_nvidia = xyes; then
 532     if test "x$want_x11" != "xyes"; then
 533                 # do nada
 534                 want_nvidia=no
 535         else
 536                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 537 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 538 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 539 dnl ## am I Stupid ??
 540 dnl ## it won't find the lib for some reason!?
 541                 LIBS="$LIBS -lXNVCtrl"
 542                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 543         fi
 544 fi
 545 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 546
 547 dnl
 548 dnl GLIB
 549 dnl
 550
 551 if test x$WANT_GLIB = xyes; then
 552         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 553         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 554         LIBS="$LIBS $GLib2_LIBS"
 555 fi
 556
 557 dnl
 558 dnl KVM
 559 dnl
 560
 561 if test x$WANT_KVM = xyes; then
 562   AC_CHECK_LIB(kvm, kvm_open,
 563     LIBS="$LIBS -lkvm",
 564   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 565   )
 566 fi
 567
 568 dnl
 569 dnl devstat
 570 dnl
 571
 572 if test x$WANT_DEVSTAT = xyes; then
 573   AC_CHECK_LIB(devstat, devstat_getversion,
 574          LIBS="$LIBS -ldevstat",
 575          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 576   )
 577 fi
 578
 579 dnl
 580 dnl OSSLIB for NetBSD/OpenBSD
 581 dnl
 582
 583 if test x$WANT_OSSLIB = xyes; then
 584     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 585   LIBS="$LIBS -lossaudio",
 586   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 587     )
 588 fi
 589
 590 dnl
 591 dnl ALSA for Linux
 592 dnl
 593 AC_ARG_ENABLE([alsa],
 594               AC_HELP_STRING([--disable-alsa], [disable if you do not
 595   want ALSA support @<:@default=yes@:>@]),
 596               [want_alsa="$enableval"], [want_alsa=yes])
 597
 598 if test x$want_alsa = xyes; then
 599     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 600 fi
 601 if test x$want_alsa = xyes; then
 602     AC_CHECK_LIB(asound, snd_pcm_open,LIBS="$LIBS -lasound", want_alsa=no)
 603 fi
 604 if test x$want_alsa = xyes; then
 605 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 606 fi
 607 dnl
 608 dnl Some headers
 609 dnl
 610
 611 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 612       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 613 AC_CHECK_HEADERS([sys/mount.h], [], [],
 614      [#ifdef HAVE_SYS_PARAM_H
 615       #include <sys/param.h>
 616       #endif
 617       ])
 618 # check if we have inotify support
 619 AC_CHECK_HEADERS([sys/inotify.h])
 620
 621 dnl
 622 dnl Some defines
 623 dnl
 624
 625 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 626 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 627 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 628 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 629 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 630
 631 dnl
 632 dnl Some functions
 633 dnl
 634
 635 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 636 AC_SEARCH_LIBS(clock_gettime, [rt],
 637                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 638                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 639
 640 dnl
 641 dnl Structure checks
 642 dnl
 643
 644 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 645                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 646                  [],
 647                  [#include <sys/statfs.h>])
 648
 649 dnl
 650 dnl Check for zlib
 651 dnl
 652
 653 AC_CHECK_HEADER(zlib.h,
 654                 [],
 655                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 656
 657
 658 dnl
 659 dnl Check for OpenMP support
 660 dnl
 661
 662 AC_ARG_ENABLE([openmp],
 663               AC_HELP_STRING([--enable-openmp], [enable if you want OpenMP support @<:@default=no@:>@]),
 664               [want_openmp="$enableval"], [want_openmp=no])
 665
 666 if test x$want_openmp = xyes; then
 667         AX_OPENMP([
 668           gcc_version=`$CC -dumpversion`
 669           gcc_major=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 670           gcc_minor=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 671           dnl check that the gcc version is >=4.3, if we're using gcc
 672           if test ! "x$GCC" = "xyes" -o $gcc_major -ge 4 -a $gcc_minor -ge 3; then
 673             AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 674             CFLAGS="$CFLAGS $OPENMP_CFLAGS"
 675           else
 676             want_openmp=no
 677           fi
 678
 679         ])
 680 fi
 681
 682 dnl
 683 dnl Check doc stuff
 684 dnl
 685
 686 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 687 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 688 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 689 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 690   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 691 else
 692   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 693 fi
 694
 695 dnl
 696 dnl kstat in Solaris
 697 dnl
 698
 699 if test x$WANT_KSTAT = xyes; then
 700   dah=no
 701   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 702
 703   if test x$dah = xyes; then
 704     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 705     LDFLAGS="$LDFLAGS -lkstat"
 706   fi
 707 fi
 708
 709 AC_DEFUN([AM_LANGINFO_CODESET],
 710 [
 711   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 712     [AC_TRY_LINK([#include <langinfo.h>],
 713       [char* cs = nl_langinfo(CODESET);],
 714       am_cv_langinfo_codeset=yes,
 715       am_cv_langinfo_codeset=no)
 716     ])
 717   if test $am_cv_langinfo_codeset = yes; then
 718     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 719       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 720   fi
 721 ])
 722
 723
 724 dnl ************************
 725 dnl * Linker optimizations *
 726 dnl ************************
 727 AC_MSG_CHECKING([if $LD accepts -O1])
 728 case `$LD -O1 -v 2>&1 </dev/null` in
 729 *GNU* | *BSD*)
 730   LDFLAGS="$LDFLAGS -Wl,-O1"
 731   AC_MSG_RESULT([yes])
 732   ;;
 733 *)
 734   AC_MSG_RESULT([no])
 735   ;;
 736 esac
 737
 738 dnl Solve multiple definitions (only necessary when gnulib is used)
 739 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 740
 741 dnl
 742 dnl Da.
 743 dnl
 744
 745 CFLAGS="$CFLAGS -Wall -W"
 746
 747 dnl
 748 dnl debug
 749 dnl
 750
 751 AC_ARG_ENABLE([debug],
 752               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 753               [want_debug="$enableval"], [want_debug=no])
 754
 755 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 756   CFLAGS="$CFLAGS -g3"
 757   AC_DEFINE([DEBUG], 1, [Define for debugging])
 758 fi
 759
 760 dnl
 761 dnl testing
 762 dnl
 763
 764 AC_ARG_ENABLE([testing],
 765               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 766               [want_testing="$enableval"], [want_testing=no])
 767
 768 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 769   if test "x$want_debug" = "xyes"; then
 770     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 771     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 772   else
 773     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 774     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 775   fi
 776 fi
 777
 778 AC_SUBST(CFLAGS)
 779 AC_SUBST(X11_LIBS)
 780
 781 AC_OUTPUT
 782
 783 dnl
 784 dnl Print summary
 785 dnl
 786 cat << EOF
 787
 788 $PACKAGE $VERSION configured successfully:
 789
 790  Installing into:   $prefix
 791  System config dir: $sysconfdir
 792  C compiler flags:  $CFLAGS
 793  Linker flags:      $LDFLAGS
 794  Libraries:         $LIBS
 795
 796  * X11:
 797   X11 support:      $want_x11
 798   XDamage support:  $want_xdamage
 799   XDBE support:     $want_double_buffer
 800   Xft support:      $want_xft
 801
 802  * Music detection:
 803   Audacious:        $want_audacious
 804   BMPx:             $want_bmpx
 805   MPD:              $want_mpd
 806   MOC:              $want_moc
 807   XMMS2:            $want_xmms2
 808
 809  * General:
 810   OpenMP:           $want_openmp
 811   math:             $want_math
 812   hddtemp:          $want_hddtemp
 813   portmon:          $want_portmon
 814   RSS:              $want_rss
 815   Lua:              $want_lua
 816   wireless:         $want_wlan
 817   IBM:              $want_ibm
 818   nvidia:           $want_nvidia
 819   eve-online:       $want_eve
 820   config-output:    $want_config_output
 821   IMLIB2:           $want_imlib2
 822   ALSA mixer:       $want_alsa
 823   apcupsd:          $want_apcupsd
 824 EOF