vcs.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml sql network
   2
   3 INCLUDEPATH += $$PWD \
   4     $$PWD/model \
   5     $$PWD/widgets
   6
   7 SOURCES += \
   8     main.cpp \
   9     mainwindow.cpp \
  10     bookview.cpp \
  11     model/unzip/unzip.c \
  12     model/unzip/ioapi.c \
  13     model/extractzip.cpp \
  14     model/library.cpp \
  15     model/book.cpp \
  16     librarydialog.cpp \
  17     devtools.cpp \
  18     infodialog.cpp \
  19     widgets/translucentbutton.cpp \
  20     settingswindow.cpp \
  21     model/settings.cpp \
  22     bookmarksdialog.cpp \
  23     model/sortedlibrary.cpp \
  24     bookmarkinfodialog.cpp \
  25     widgets/dyalog.cpp \
  26     chaptersdialog.cpp \
  27     widgets/fullscreenwindow.cpp \
  28     trace.cpp \
  29     widgets/toolbuttonbox.cpp \
  30     model/bookfinder.cpp \
  31     widgets/listwindow.cpp \
  32     widgets/progress.cpp \
  33     widgets/adopterwindow.cpp \
  34     platform.cpp \
  35     model/bookdb.cpp \
  36     searchdialog.cpp \
  37     search.cpp \
  38     widgets/flickable.cpp \
  39     widgets/listview.cpp \
  40     searchresultsdialog.cpp \
  41     searchresultinfodialog.cpp \
  42     widgets/progressdialog.cpp
  43
  44 HEADERS += \
  45     mainwindow.h \
  46     bookview.h \
  47     model/opshandler.h \
  48     model/unzip/unzip.h \
  49     model/unzip/ioapi.h \
  50     model/extractzip.h \
  51     model/library.h \
  52     model/book.h \
  53     librarydialog.h \
  54     devtools.h \
  55     infodialog.h \
  56     widgets/translucentbutton.h \
  57     settingswindow.h \
  58     model/settings.h \
  59     bookmarksdialog.h \
  60     model/xmlerrorhandler.h \
  61     model/containerhandler.h \
  62     model/sortedlibrary.h \
  63     model/ncxhandler.h \
  64     bookmarkinfodialog.h \
  65     widgets/dyalog.h \
  66     chaptersdialog.h \
  67     widgets/fullscreenwindow.h \
  68     trace.h \
  69     widgets/toolbuttonbox.h \
  70     model/bookfinder.h \
  71     widgets/listwindow.h \
  72     widgets/progress.h \
  73     widgets/adopterwindow.h \
  74     widgets/listview.h \
  75     model/xmlhandler.h \
  76     platform.h \
  77     model/bookdb.h \
  78     searchdialog.h \
  79     search.h \
  80     widgets/flickable.h \
  81     searchresultsdialog.h \
  82     searchresultinfodialog.h \
  83     widgets/progressdialog.h
  84
  85 RESOURCES += \
  86     dorian.qrc
  87
  88 OTHER_FILES += \
  89     TODO.txt \
  90     pkg/acknowledgements.txt \
  91     pkg/maemo/postinst \
  92     pkg/maemo/dorian.desktop \
  93     pkg/maemo/control \
  94     pkg/maemo/changelog \
  95     pkg/maemo/build.sh \
  96     styles/night.css \
  97     pkg/changelog \
  98     pkg/maemo/build-scratchbox.sh \
  99     styles/sand.css \
 100     styles/default.css \
 101     pkg/version.txt \
 102     styles/sand.js \
 103     styles/night.js \
 104     styles/default.js \
 105     styles/day.js \
 106     www/index.html \
 107     pkg/maemo/autobuild.sh \
 108     pkg/maemo/autobuild-scratchbox.sh \
 109     LICENSE.txt \
 110     pkg/symbian/book.svg
 111
 112 DEFINES += \
 113     USE_FILE32API
 114
 115 !symbian {
 116     DEFINES += DORIAN_TEST_MODEL
 117     include(model/modeltest/modeltest.pri)
 118 }
 119
 120 unix {
 121     symbian {
 122     } else {
 123         LIBS += -lz
 124     }
 125 }
 126
 127 win32 {
 128     DEFINES += ZLIB_WINAPI
 129     INCLUDEPATH += $$PWD/model/zlib
 130     LIBS += pkg/win32/zlibstat.lib
 131 }
 132
 133 symbian {
 134     TARGET = Dorian
 135     TARGET.UID3 = 0xEA633557
 136     TARGET.CAPABILITY = NetworkServices ReadUserData WriteUserData
 137     TARGET.EPOCHEAPSIZE = 0x080000 0x4000000
 138     ICON = $$PWD/pkg/symbian/book.svg
 139     packageheader = "$${LITERAL_HASH}{\"Dorian\"}, (0xEA633557), 0, 3, 4"
 140     vendorinfo = \
 141         "%{\"Nokia Betalabs \"}" \
 142         ":\"Nokia Betalabs \""
 143     my_deployment.pkg_prerules = packageheader vendorinfo
 144     DEPLOYMENT += my_deployment
 145
 146     INCLUDEPATH += $(QTDIR)/src/3rdparty/zlib
 147     HEADERS += widgets/flickcharm.h
 148     SOURCES += widgets/flickcharm.cpp
 149 }
 150
 151 maemo5 {
 152     QT += maemo5 dbus
 153     isEmpty(PREFIX) {
 154         PREFIX = /usr
 155     }
 156     BINDIR = $$PREFIX/bin
 157     DATADIR =$$PREFIX/share
 158     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 159
 160     # For "make install"
 161
 162     INSTALLS += target desktop icon48 iconscalable
 163
 164     target.path = $$BINDIR
 165
 166     desktop.path = $$DATADIR/applications/hildon
 167     desktop.files += pkg/maemo/dorian.desktop
 168
 169     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 170     icon48.files += pkg/maemo/icon-48/dorian.png
 171
 172     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 173     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 174 }