vcs.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml sql
   2
   3 INCLUDEPATH += $$PWD \
   4     $$PWD/model \
   5     $$PWD/widgets
   6
   7 SOURCES += \
   8     main.cpp \
   9     mainwindow.cpp \
  10     bookview.cpp \
  11     model/unzip/unzip.c \
  12     model/unzip/ioapi.c \
  13     model/extractzip.cpp \
  14     model/library.cpp \
  15     model/book.cpp \
  16     librarydialog.cpp \
  17     devtools.cpp \
  18     infodialog.cpp \
  19     widgets/translucentbutton.cpp \
  20     settingswindow.cpp \
  21     model/settings.cpp \
  22     bookmarksdialog.cpp \
  23     model/sortedlibrary.cpp \
  24     bookmarkinfodialog.cpp \
  25     widgets/dyalog.cpp \
  26     chaptersdialog.cpp \
  27     widgets/fullscreenwindow.cpp \
  28     trace.cpp \
  29     widgets/toolbuttonbox.cpp \
  30     model/bookfinder.cpp \
  31     widgets/listwindow.cpp \
  32     widgets/progress.cpp \
  33     widgets/adopterwindow.cpp \
  34     platform.cpp \
  35     model/bookdb.cpp \
  36     searchdialog.cpp \
  37     search.cpp
  38
  39 HEADERS += \
  40     mainwindow.h \
  41     bookview.h \
  42     model/opshandler.h \
  43     model/unzip/unzip.h \
  44     model/unzip/ioapi.h \
  45     model/extractzip.h \
  46     model/library.h \
  47     model/book.h \
  48     librarydialog.h \
  49     devtools.h \
  50     infodialog.h \
  51     widgets/translucentbutton.h \
  52     settingswindow.h \
  53     model/settings.h \
  54     bookmarksdialog.h \
  55     model/xmlerrorhandler.h \
  56     model/containerhandler.h \
  57     model/sortedlibrary.h \
  58     model/ncxhandler.h \
  59     bookmarkinfodialog.h \
  60     widgets/dyalog.h \
  61     chaptersdialog.h \
  62     widgets/fullscreenwindow.h \
  63     trace.h \
  64     widgets/toolbuttonbox.h \
  65     model/bookfinder.h \
  66     widgets/listwindow.h \
  67     widgets/progress.h \
  68     widgets/adopterwindow.h \
  69     widgets/listview.h \
  70     model/xmlhandler.h \
  71     platform.h \
  72     model/bookdb.h \
  73     searchdialog.h \
  74     search.h
  75
  76 RESOURCES += \
  77     dorian.qrc
  78
  79 OTHER_FILES += \
  80     TODO.txt \
  81     pkg/acknowledgements.txt \
  82     pkg/maemo/postinst \
  83     pkg/maemo/dorian.desktop \
  84     pkg/maemo/control \
  85     pkg/maemo/changelog \
  86     pkg/maemo/build.sh \
  87     styles/night.css \
  88     pkg/changelog \
  89     pkg/maemo/build-scratchbox.sh \
  90     styles/sand.css \
  91     styles/default.css \
  92     pkg/version.txt \
  93     styles/sand.js \
  94     styles/night.js \
  95     styles/default.js \
  96     styles/day.js \
  97     www/index.html \
  98     pkg/maemo/autobuild.sh \
  99     pkg/maemo/autobuild-scratchbox.sh \
 100     LICENSE.txt \
 101     pkg/symbian/book.svg
 102
 103 DEFINES += \
 104     USE_FILE32API \
 105     DORIAN_TEST_MODEL
 106
 107 include(model/modeltest/modeltest.pri)
 108
 109 unix {
 110     symbian {
 111     } else {
 112         LIBS += -lz
 113     }
 114 }
 115 win32 {
 116     DEFINES += ZLIB_WINAPI
 117     INCLUDEPATH += $$PWD/model/zlib
 118     LIBS += pkg/win32/zlibstat.lib
 119 }
 120 symbian {
 121     ICON = $$PWD/pkg/symbian/book.svgt
 122     TARGET.UID3 = 0xEA633557
 123     # TARGET.CAPABILITY = ...
 124     # FIXME: Add OpenC ZLIB?
 125     INCLUDEPATH += C:/NokiaQtSDK/Symbian/SDK/src/3rdparty/zlib \
 126         c:/Qt/4.7.0/src/3rdparty/zlib
 127 }
 128 maemo5 {
 129     QT += maemo5 dbus
 130     isEmpty(PREFIX) {
 131         PREFIX = /usr
 132     }
 133     BINDIR = $$PREFIX/bin
 134     DATADIR =$$PREFIX/share
 135     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 136
 137     # For "make install"
 138
 139     INSTALLS += target desktop icon48 iconscalable
 140
 141     target.path = $$BINDIR
 142
 143     desktop.path = $$DATADIR/applications/hildon
 144     desktop.files += pkg/maemo/dorian.desktop
 145
 146     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 147     icon48.files += pkg/maemo/icon-48/dorian.png
 148
 149     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 150     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 151 }
 152 macx {
 153     CONFIG += x86
 154 }