vcs.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml
   2
   3 SOURCES += \
   4     main.cpp \
   5     mainwindow.cpp \
   6     bookview.cpp \
   7     unzip/unzip.c \
   8     unzip/ioapi.c \
   9     extractzip.cpp \
  10     library.cpp \
  11     book.cpp \
  12     info.cpp \
  13     librarydialog.cpp \
  14     devtools.cpp \
  15     infodialog.cpp \
  16     translucentbutton.cpp \
  17     settingswindow.cpp \
  18     settings.cpp \
  19     bookmarksdialog.cpp \
  20     sortedlibrary.cpp
  21
  22 HEADERS += \
  23     mainwindow.h \
  24     bookview.h \
  25     selectionsuppressor.h \
  26     opshandler.h \
  27     unzip/unzip.h \
  28     unzip/ioapi.h \
  29     extractzip.h \
  30     library.h \
  31     book.h \
  32     info.h \
  33     librarydialog.h \
  34     devtools.h \
  35     infodialog.h \
  36     translucentbutton.h \
  37     settingswindow.h \
  38     settings.h \
  39     bookmarksdialog.h \
  40     opserrorhandler.h \
  41     containerhandler.h \
  42     sortedlibrary.h
  43
  44 RESOURCES += \
  45     dorian.qrc
  46
  47 OTHER_FILES += \
  48     TODO.txt \
  49     pkg/acknowledgements.txt \
  50     pkg/maemo/postinst \
  51     pkg/maemo/dorian.desktop \
  52     pkg/maemo/control \
  53     pkg/maemo/changelog \
  54     pkg/maemo/build.sh \
  55     styles/night.css \
  56     pkg/changelog \
  57     pkg/maemo/build-scratchbox.sh \
  58     styles/sand.css \
  59     styles/default.css \
  60     pkg/version.txt \
  61     styles/sand.js \
  62     styles/night.js \
  63     styles/default.js \
  64     styles/day.js
  65
  66 DEFINES += \
  67     USE_FILE32API \
  68     DORIAN_TEST_MODEL
  69
  70 include(modeltest/modeltest.pri)
  71
  72 unix {
  73     LIBS += -lz
  74 }
  75 windows {
  76     # FIXME: Build zlib, too
  77 }
  78 maemo5 {
  79     QT += maemo5
  80     isEmpty(PREFIX) {
  81         PREFIX = /usr
  82     }
  83     BINDIR = $$PREFIX/bin
  84     DATADIR =$$PREFIX/share
  85     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  86
  87     # For "make install"
  88
  89     INSTALLS += target desktop icon48 iconscalable
  90
  91     target.path = $$BINDIR
  92
  93     desktop.path = $$DATADIR/applications/hildon
  94     desktop.files += pkg/maemo/dorian.desktop
  95
  96     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
  97     icon48.files += pkg/maemo/icon-48/dorian.png
  98
  99     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 100     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 101 }