vcs.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml
   2
   3 INCLUDEPATH += $$PWD \
   4     $$PWD/model \
   5     $$PWD/widgets
   6
   7 SOURCES += \
   8     main.cpp \
   9     mainwindow.cpp \
  10     bookview.cpp \
  11     model/unzip/unzip.c \
  12     model/unzip/ioapi.c \
  13     model/extractzip.cpp \
  14     model/library.cpp \
  15     model/book.cpp \
  16     librarydialog.cpp \
  17     devtools.cpp \
  18     infodialog.cpp \
  19     widgets/translucentbutton.cpp \
  20     settingswindow.cpp \
  21     model/settings.cpp \
  22     bookmarksdialog.cpp \
  23     model/sortedlibrary.cpp \
  24     bookmarkinfodialog.cpp \
  25     widgets/dyalog.cpp \
  26     chaptersdialog.cpp \
  27     widgets/fullscreenwindow.cpp \
  28     trace.cpp \
  29     widgets/toolbuttonbox.cpp \
  30     model/bookfinder.cpp \
  31     widgets/listwindow.cpp \
  32     widgets/progress.cpp \
  33     widgets/adopterwindow.cpp
  34
  35 HEADERS += \
  36     mainwindow.h \
  37     bookview.h \
  38     model/opshandler.h \
  39     model/unzip/unzip.h \
  40     model/unzip/ioapi.h \
  41     model/extractzip.h \
  42     model/library.h \
  43     model/book.h \
  44     librarydialog.h \
  45     devtools.h \
  46     infodialog.h \
  47     widgets/translucentbutton.h \
  48     settingswindow.h \
  49     model/settings.h \
  50     bookmarksdialog.h \
  51     model/xmlerrorhandler.h \
  52     model/containerhandler.h \
  53     model/sortedlibrary.h \
  54     model/ncxhandler.h \
  55     bookmarkinfodialog.h \
  56     widgets/dyalog.h \
  57     chaptersdialog.h \
  58     widgets/fullscreenwindow.h \
  59     trace.h \
  60     widgets/toolbuttonbox.h \
  61     model/bookfinder.h \
  62     widgets/listwindow.h \
  63     widgets/progress.h \
  64     widgets/adopterwindow.h \
  65     widgets/listview.h
  66
  67 RESOURCES += \
  68     dorian.qrc
  69
  70 OTHER_FILES += \
  71     TODO.txt \
  72     pkg/acknowledgements.txt \
  73     pkg/maemo/postinst \
  74     pkg/maemo/dorian.desktop \
  75     pkg/maemo/control \
  76     pkg/maemo/changelog \
  77     pkg/maemo/build.sh \
  78     styles/night.css \
  79     pkg/changelog \
  80     pkg/maemo/build-scratchbox.sh \
  81     styles/sand.css \
  82     styles/default.css \
  83     pkg/version.txt \
  84     styles/sand.js \
  85     styles/night.js \
  86     styles/default.js \
  87     styles/day.js \
  88     www/index.html \
  89     pkg/maemo/autobuild.sh \
  90     pkg/maemo/autobuild-scratchbox.sh \
  91     LICENSE.txt
  92
  93 DEFINES += \
  94     USE_FILE32API \
  95     DORIAN_TEST_MODEL
  96
  97 include(model/modeltest/modeltest.pri)
  98
  99 unix {
 100     LIBS += -lz
 101 }
 102 windows, symbian {
 103     # FIXME: Build zlib, too
 104 }
 105 maemo5 {
 106     QT += maemo5 dbus
 107     isEmpty(PREFIX) {
 108         PREFIX = /usr
 109     }
 110     BINDIR = $$PREFIX/bin
 111     DATADIR =$$PREFIX/share
 112     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 113
 114     # For "make install"
 115
 116     INSTALLS += target desktop icon48 iconscalable
 117
 118     target.path = $$BINDIR
 119
 120     desktop.path = $$DATADIR/applications/hildon
 121     desktop.files += pkg/maemo/dorian.desktop
 122
 123     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 124     icon48.files += pkg/maemo/icon-48/dorian.png
 125
 126     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 127     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 128 }
 129 macx {
 130     CONFIG += x86
 131 }