vcs.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml
   2
   3 SOURCES += \
   4     main.cpp \
   5     mainwindow.cpp \
   6     bookview.cpp \
   7     unzip/unzip.c \
   8     unzip/ioapi.c \
   9     extractzip.cpp \
  10     library.cpp \
  11     book.cpp \
  12     librarydialog.cpp \
  13     devtools.cpp \
  14     infodialog.cpp \
  15     translucentbutton.cpp \
  16     settingswindow.cpp \
  17     settings.cpp \
  18     bookmarksdialog.cpp \
  19     sortedlibrary.cpp \
  20     bookmarkinfodialog.cpp \
  21     dialog.cpp \
  22     chaptersdialog.cpp \
  23     fullscreenwindow.cpp \
  24     trace.cpp \
  25     toolbuttonbox.cpp \
  26     bookfinder.cpp
  27
  28 HEADERS += \
  29     mainwindow.h \
  30     bookview.h \
  31     opshandler.h \
  32     unzip/unzip.h \
  33     unzip/ioapi.h \
  34     extractzip.h \
  35     library.h \
  36     book.h \
  37     librarydialog.h \
  38     devtools.h \
  39     infodialog.h \
  40     translucentbutton.h \
  41     settingswindow.h \
  42     settings.h \
  43     bookmarksdialog.h \
  44     xmlerrorhandler.h \
  45     containerhandler.h \
  46     sortedlibrary.h \
  47     ncxhandler.h \
  48     bookmarkinfodialog.h \
  49     dialog.h \
  50     chaptersdialog.h \
  51     fullscreenwindow.h \
  52     trace.h \
  53     toolbuttonbox.h \
  54     bookfinder.h
  55
  56 RESOURCES += \
  57     dorian.qrc
  58
  59 OTHER_FILES += \
  60     TODO.txt \
  61     pkg/acknowledgements.txt \
  62     pkg/maemo/postinst \
  63     pkg/maemo/dorian.desktop \
  64     pkg/maemo/control \
  65     pkg/maemo/changelog \
  66     pkg/maemo/build.sh \
  67     styles/night.css \
  68     pkg/changelog \
  69     pkg/maemo/build-scratchbox.sh \
  70     styles/sand.css \
  71     styles/default.css \
  72     pkg/version.txt \
  73     styles/sand.js \
  74     styles/night.js \
  75     styles/default.js \
  76     styles/day.js \
  77     www/index.html
  78
  79 DEFINES += \
  80     USE_FILE32API \
  81     DORIAN_TEST_MODEL
  82
  83 include(modeltest/modeltest.pri)
  84
  85 unix {
  86     LIBS += -lz
  87 }
  88 windows {
  89     # FIXME: Build zlib, too
  90 }
  91 maemo5 {
  92     QT += maemo5 dbus
  93     isEmpty(PREFIX) {
  94         PREFIX = /usr
  95     }
  96     BINDIR = $$PREFIX/bin
  97     DATADIR =$$PREFIX/share
  98     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  99
 100     # For "make install"
 101
 102     INSTALLS += target desktop icon48 iconscalable
 103
 104     target.path = $$BINDIR
 105
 106     desktop.path = $$DATADIR/applications/hildon
 107     desktop.files += pkg/maemo/dorian.desktop
 108
 109     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 110     icon48.files += pkg/maemo/icon-48/dorian.png
 111
 112     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 113     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 114 }