vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         IconView icons;
  26
  27         private bool more_movies_available;
  28         private CellRendererText title_renderer;
  29         private CellRendererText secondary_renderer;
  30         private CellRendererText rating_renderer;
  31         private CellRendererText date_renderer;
  32         private MoviePoster.Factory poster_factory;
  33
  34         private bool poster_mode_;
  35         public bool poster_mode {
  36                 get {
  37                         return poster_mode_;
  38                 }
  39                 set {
  40                         if (value & !poster_mode_) {
  41                                 remove (tree);
  42                                 add (icons);
  43                         } else if (!value & poster_mode_) {
  44                                 remove (icons);
  45                                 add (tree);
  46                         }
  47                         poster_mode_ = value;
  48                 }
  49         }
  50
  51         public signal void movie_activated (Movie movie);
  52
  53         private Gtk.TreeView create_treeview (Gtk.Window window, bool show_date) {
  54                 // Tree View
  55                 var tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, store);
  56                 tree.set_headers_visible (false);
  57                 tree.set_rules_hint (true);
  58
  59                 // Tree selection object
  60                 var selection = tree.get_selection ();
  61                 selection.set_mode (SelectionMode.SINGLE);
  62
  63                 // Title column with poster
  64                 var title_column = new TreeViewColumn ();
  65                 title_column.set_title (_("Movie"));
  66                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  67                 title_column.set_reorderable (false);
  68                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  69                 title_column.set_expand (true);
  70
  71                 // Add poster icon to column
  72                 var pixbuf_renderer = new CellRendererPixbuf ();
  73                 pixbuf_renderer.width = 64;
  74                 pixbuf_renderer.xalign = 0.0f;
  75                 title_column.pack_start (pixbuf_renderer, false);
  76                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.ICON);
  77
  78                 // Add text to column
  79                 var vbox_renderer = new CellRendererVBox ();
  80
  81                 title_renderer = new CellRendererText ();
  82                 title_renderer.yalign = 1.0f;
  83                 title_renderer.ellipsize = Pango.EllipsizeMode.END;
  84
  85                 vbox_renderer.append (title_renderer, true);
  86
  87                 // Add secondary text to column (Genres, Director, etc.)
  88                 secondary_renderer = new CellRendererText ();
  89                 secondary_renderer.yalign = 0;
  90                 secondary_renderer.ellipsize = Pango.EllipsizeMode.END;
  91                 secondary_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
  92
  93                 vbox_renderer.append (secondary_renderer, true);
  94
  95                 title_column.pack_start (vbox_renderer, true);
  96                 title_column.set_cell_data_func (vbox_renderer, title_data_func);
  97
  98                 tree.append_column (title_column);
  99
 100                 // Year column
 101                 var year_column = new TreeViewColumn ();
 102                 year_column.set_title (_("Year"));
 103                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 104                 year_column.set_reorderable (false);
 105                 year_column.set_sort_order (SortType.DESCENDING);
 106                 tree.append_column (year_column);
 107
 108                 // Rating column
 109                 var rating_column = new TreeViewColumn ();
 110                 rating_column.set_title (_("Rating"));
 111                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 112                 rating_column.set_reorderable (false);
 113                 rating_column.set_sort_order (SortType.DESCENDING);
 114                 rating_column.xalign = 1.0f;
 115
 116                 vbox_renderer = new CellRendererVBox ();
 117
 118                 rating_renderer = new CellRendererText ();
 119                 rating_renderer.xalign = 1.0f;
 120                 if (show_date)
 121                         rating_renderer.yalign = 1.0f;
 122
 123                 vbox_renderer.append (rating_renderer, true);
 124
 125                 date_renderer = new CellRendererText ();
 126                 date_renderer.yalign = 0;
 127                 date_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
 128
 129                 if (show_date)
 130                         vbox_renderer.append (date_renderer, true);
 131
 132                 rating_column.pack_start (vbox_renderer, true);
 133                 rating_column.set_cell_data_func (vbox_renderer, rating_data_func);
 134
 135                 tree.append_column (rating_column);
 136                 tree.show ();
 137                 return tree;
 138         }
 139
 140         private Gtk.IconView create_iconview () {
 141                 var iconview = (Gtk.IconView) Hildon.gtk_icon_view_new_with_model (Hildon.UIMode.NORMAL, store);
 142                 iconview.set_column_spacing (0);
 143                 iconview.set_pixbuf_column (MovieListStore.Columns.POSTER);
 144                 iconview.margin = 0;
 145                 iconview.item_width = Poster.SMALL_WIDTH;
 146                 iconview.column_spacing = Hildon.MARGIN_HALF;
 147                 iconview.row_spacing = Hildon.MARGIN_HALF;
 148                 iconview.show ();
 149
 150                 return iconview;
 151         }
 152
 153         public MovieListView (Gtk.Window window, bool show_date = false) {
 154                 store = new MovieListStore ();
 155
 156                 // Sort by title
 157                 store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 158
 159                 Gdk.Color color;
 160                 window.ensure_style ();
 161                 if (window.style.lookup_color ("SecondaryTextColor", out color)) {
 162                         store.year_markup = "<span size=\"small\" fgcolor=\"%s\">(%%d)</span>".printf (color.to_string ());
 163                 }
 164
 165                 tree = create_treeview (window, show_date);
 166
 167                 icons = create_iconview ();
 168
 169                 add (tree);
 170
 171                 // Connect signals
 172                 get_vadjustment ().value_changed.connect (on_adjustment_value_changed);
 173                 tree.row_activated.connect (on_row_activated);
 174                 icons.item_activated.connect (on_item_activated);
 175                 store.row_changed.connect (on_row_changed);
 176                 store.search_finished.connect (on_search_finished);
 177         }
 178
 179         construct {
 180                 hscrollbar_policy = Gtk.PolicyType.NEVER;
 181
 182                 poster_factory = MoviePoster.Factory.get_instance ();
 183         }
 184
 185         public void set_hildon_ui_mode (UIMode mode) {
 186                 var selection = tree.get_selection ();
 187
 188                 if (mode == UIMode.NORMAL) {
 189                         selection.set_mode (SelectionMode.NONE);
 190                         icons.set_selection_mode (SelectionMode.NONE);
 191                 }
 192                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 193                 Hildon.gtk_icon_view_set_ui_mode (icons, mode);
 194                 if (mode == UIMode.EDIT) {
 195                         selection.set_mode (SelectionMode.MULTIPLE);
 196                         icons.set_selection_mode (SelectionMode.MULTIPLE);
 197                 }
 198         }
 199
 200         private Pango.AttrList get_attributes (Gtk.Window window, string font_name, string color_name) {
 201                 Pango.AttrList attr_list = new Pango.AttrList ();
 202                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), font_name, null, typeof (void));
 203                 if (style != null) {
 204                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
 205                         attr_list.insert ((owned) attr_font_desc);
 206                 }
 207                 Gdk.Color color;
 208                 window.ensure_style ();
 209                 if (window.style.lookup_color (color_name, out color)) {
 210                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
 211                         attr_list.insert ((owned) attr_color);
 212                 }
 213                 return attr_list;
 214         }
 215
 216         public void unselect_all () {
 217                 tree.get_selection ().unselect_all ();
 218                 icons.unselect_all ();
 219         }
 220
 221         public List<Movie> get_selected_movies () {
 222                 var movies = new List<Movie> ();
 223                 List<TreePath> paths;
 224
 225                 if (poster_mode_)
 226                         paths = icons.get_selected_items ();
 227                 else
 228                         paths = tree.get_selection ().get_selected_rows (null);
 229
 230                 // get selected movies from the store
 231                 foreach (TreePath path in paths) {
 232                         TreeIter iter;
 233
 234                         if (store.get_iter (out iter, path)) {
 235                                 Movie movie;
 236
 237                                 store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 238                                 if (movie != null) {
 239                                         movies.append (movie);
 240                                 }
 241                         }
 242                 }
 243
 244                 return movies;
 245         }
 246
 247         // TODO: after scrolling down 80% of the list, load more
 248         //       results if available.
 249         int last_a = 0;
 250         int last_b = 0;
 251         private void on_adjustment_value_changed () {
 252                 if (more_movies_available) {
 253                         var vadj = get_vadjustment ();
 254                         if (vadj.value > 0.8 * vadj.upper) {
 255                                 Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 256                                 more_movies_available = false;
 257                         }
 258                 }
 259
 260                 TreePath a_;
 261                 TreePath b_;
 262                 bool range;
 263                 if (poster_mode_) {
 264                         range = icons.get_visible_range (out a_, out b_);
 265                 } else {
 266                         range = tree.get_visible_range (out a_, out b_);
 267                 }
 268                 if (range) {
 269                         // We know the list store is flat
 270                         int a = a_.get_indices ()[0];
 271                         int b = b_.get_indices ()[0];
 272                         assert (a <= b);
 273
 274                         if (a == last_a && b == last_b)
 275                                 return;
 276
 277                         if (a > last_b || b < last_a) {
 278                                 check_posters (a, b);
 279                         } else if (a >= last_a && b > last_b) {
 280                                 check_posters (last_b + 1, b);
 281                         } else if (b <= last_b && a < last_a) {
 282                                 check_posters (a, last_a - 1);
 283                         }
 284
 285                         last_a = a;
 286                         last_b = b;
 287                 }
 288         }
 289
 290         private void check_posters (int a, int b) {
 291                 for (int i = a; i <= b; i++) {
 292                         var path = new TreePath.from_indices (i);
 293                         TreeIter iter;
 294                         if (store.get_iter (out iter, path)) {
 295                                 Movie movie;
 296                                 store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 297                                 if (movie != null) {
 298                                         if (poster_mode_) {
 299                                                 if (movie.poster == null || movie.poster.small == null) try {
 300                                                         poster_factory.queue_thumbnail (movie, Poster.SMALL_WIDTH, Poster.SMALL_HEIGHT, false, receive_poster_small);
 301                                                 } catch (Error e) {
 302                                                         warning ("Failed to queue poster request: %s\n", e.message);
 303                                                 }
 304                                         } else {
 305                                                 if (movie.poster == null || movie.poster.icon == null) try {
 306                                                         poster_factory.queue_thumbnail (movie, Poster.ICON_WIDTH, Poster.ICON_HEIGHT, false, receive_poster_icon);
 307                                                 } catch (Error e) {
 308                                                         warning ("Failed to queue poster request: %s\n", e.message);
 309                                                 }
 310                                         }
 311                                 }
 312                         }
 313                 }
 314         }
 315
 316         private void on_row_activated (TreeView tree, TreePath path, TreeViewColumn column) {
 317                 on_item_activated (path);
 318         }
 319
 320         private void on_item_activated (TreePath path) {
 321                 TreeIter iter;
 322
 323                 if (store.get_iter (out iter, path)) {
 324                         Movie movie;
 325                         store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 326                         movie_activated (movie);
 327                 }
 328         }
 329
 330         private void on_row_changed (TreePath path, TreeIter iter) {
 331                 TreePath a;
 332                 TreePath b;
 333                 bool range;
 334
 335                 if (poster_mode_) {
 336                         range = icons.get_visible_range (out a, out b);
 337                 } else {
 338                         range = tree.get_visible_range (out a, out b);
 339                 }
 340                 if (!range ||
 341                     (range && path.compare (a) >= 0 && path.compare (b) <= 0)) {
 342                         Movie movie;
 343
 344                         store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 345                         if (movie == null)
 346                                 return;
 347
 348                         int i = path.get_indices ()[0];
 349                         check_posters (i, i);
 350                 }
 351         }
 352
 353         private void receive_poster_small (Gdk.Pixbuf pixbuf, Movie movie) {
 354                 Poster poster;
 355                 if (movie.poster != null)
 356                         poster = movie.poster;
 357                 else
 358                         poster = new Poster ();
 359                 poster.small = pixbuf;
 360                 movie.poster = poster;
 361         }
 362
 363         private void receive_poster_icon (Gdk.Pixbuf pixbuf, Movie movie) {
 364                 Poster poster;
 365                 if (movie.poster != null)
 366                         poster = movie.poster;
 367                 else
 368                         poster = new Poster ();
 369                 poster.icon = pixbuf;
 370                 movie.poster = poster;
 371         }
 372
 373         private void on_search_finished (int movies) {
 374                 more_movies_available = (movies > 100); // FIXME
 375         }
 376
 377         private void title_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 378                 Movie movie;
 379                 string markup;
 380
 381                 model.get (iter, MovieListStore.Columns.MOVIE, out movie,
 382                                  MovieListStore.Columns.MARKUP, out markup);
 383                 title_renderer.markup = markup;
 384                 secondary_renderer.text = movie.secondary;
 385         }
 386
 387         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 388                 string rating;
 389                 Movie movie;
 390
 391                 model.get (iter, MovieListStore.Columns.RATING, out rating,
 392                                  MovieListStore.Columns.MOVIE, out movie);
 393                 rating_renderer.text = rating;
 394                 if (movie.julian_date != 0) {
 395                         var date = Date ();
 396                         date.set_julian (movie.julian_date);
 397                         var s = new char[64];
 398                         date.strftime (s, "%x");
 399                         date_renderer.text = (string) s;
 400                 } else {
 401                         date_renderer.text = "";
 402                 }
 403         }
 404 }