vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         private bool more_movies_available;
  28
  29         public signal void movie_activated (Movie movie);
  30
  31         public MovieListView (Gtk.Window window) {
  32                 store = new MovieListStore ();
  33
  34                 // Add filter wrapper
  35                 var filtered_store = new TreeModelFilter (store, null);
  36
  37                 // Add sort wrapper
  38                 sorted_store = new TreeModelSort.with_model (filtered_store);
  39
  40                 // Tree View
  41                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  42                 tree.set_headers_visible (false);
  43
  44                 add (tree);
  45
  46                 tree.set_rules_hint (true);
  47
  48                 // Tree selection object
  49                 var selection = tree.get_selection ();
  50                 selection.set_mode (SelectionMode.SINGLE);
  51
  52                 // Title column with poster
  53                 var title_column = new TreeViewColumn ();
  54                 title_column.set_title (_("Movie"));
  55                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  56                 title_column.set_reorderable (false);
  57                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  58                 title_column.set_expand (true);
  59
  60                 // Add poster icon to column
  61                 var pixbuf_renderer = new CellRendererPixbuf ();
  62                 pixbuf_renderer.width = 64;
  63                 pixbuf_renderer.xalign = 0.0f;
  64                 title_column.pack_start (pixbuf_renderer, false);
  65                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  66
  67                 // Add text to column
  68                 var vbox_renderer = new CellRendererVBox ();
  69
  70                 var renderer = new CellRendererText ();
  71                 renderer.yalign = 1.0f;
  72                 renderer.ellipsize = Pango.EllipsizeMode.END;
  73
  74                 vbox_renderer.append (renderer, true);
  75                 vbox_renderer.set_data ("title", renderer);
  76
  77                 // Add secondary text to column (Genres, Director, etc.)
  78                 renderer = new CellRendererText ();
  79                 renderer.yalign = 0;
  80                 renderer.ellipsize = Pango.EllipsizeMode.END;
  81
  82                 Pango.AttrList attr_list = new Pango.AttrList ();
  83                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), "SmallSystemFont", null, typeof (void));
  84                 if (style != null) {
  85                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
  86                         attr_list.insert ((owned) attr_font_desc);
  87                 }
  88                 Gdk.Color color;
  89                 window.ensure_style ();
  90                 if (window.style.lookup_color ("SecondaryTextColor", out color)) {
  91                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
  92                         attr_list.insert ((owned) attr_color);
  93                 }
  94                 renderer.attributes = attr_list;
  95
  96                 vbox_renderer.append (renderer, true);
  97                 vbox_renderer.set_data ("secondary", renderer);
  98
  99                 title_column.pack_start (vbox_renderer, true);
 100                 title_column.set_cell_data_func (vbox_renderer, vbox_data_func);
 101
 102                 tree.append_column (title_column);
 103
 104                 // Sort by title
 105                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 106
 107                 // Year column
 108                 renderer = new CellRendererText ();
 109                 var year_column = new TreeViewColumn ();
 110                 year_column.set_title (_("Rating"));
 111                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 112                 year_column.set_reorderable (false);
 113                 year_column.set_sort_order (SortType.DESCENDING);
 114                 year_column.pack_start (renderer, true);
 115                 year_column.set_cell_data_func (renderer, year_data_func);
 116                 tree.append_column (year_column);
 117
 118                 // Rating column
 119                 renderer = new CellRendererText ();
 120                 var rating_column = new TreeViewColumn ();
 121                 rating_column.set_title (_("Rating"));
 122                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 123                 rating_column.set_reorderable (false);
 124                 rating_column.set_sort_order (SortType.DESCENDING);
 125                 rating_column.pack_start (renderer, true);
 126                 rating_column.set_cell_data_func (renderer, rating_data_func);
 127                 rating_column.xalign = (float) 1.0;
 128                 tree.append_column (rating_column);
 129
 130                 // Connect signals
 131                 get_vadjustment ().value_changed.connect (on_adjustment_value_changed);
 132                 tree.row_activated.connect (on_row_activated);
 133                 store.search_finished.connect (on_search_finished);
 134         }
 135
 136         public void set_hildon_ui_mode (UIMode mode) {
 137                 var selection = tree.get_selection ();
 138
 139                 if (mode == UIMode.NORMAL) {
 140                         selection.set_mode (SelectionMode.NONE);
 141                 }
 142                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 143                 if (mode == UIMode.EDIT) {
 144                         selection.set_mode (SelectionMode.MULTIPLE);
 145                 }
 146         }
 147
 148         public unowned TreeSelection get_selection () {
 149                 return tree.get_selection ();
 150         }
 151
 152         // TODO: after scrolling down 80% of the list, load more
 153         //       results if available.
 154         private void on_adjustment_value_changed () {
 155                 if (more_movies_available) {
 156                         var vadj = get_vadjustment ();
 157                         if (vadj.value > 0.8 * vadj.upper) {
 158                                 Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 159                                 more_movies_available = false;
 160                         }
 161                 }
 162         }
 163
 164         private void on_row_activated (TreeView tree, TreePath path, TreeViewColumn column) {
 165                 TreeModel model = tree.model;
 166                 TreeIter iter;
 167
 168                 if (model.get_iter (out iter, path)) {
 169                         Movie movie;
 170                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 171                         movie_activated (movie);
 172                 }
 173         }
 174
 175         private void on_search_finished (int movies) {
 176                 more_movies_available = (movies > 100); // FIXME
 177         }
 178
 179         private void vbox_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 180                 Movie movie;
 181                 CellRendererText renderer;
 182
 183                 model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 184
 185                 renderer = cell.get_data ("title");
 186                 renderer.text = movie.title;
 187
 188                 renderer = cell.get_data ("secondary");
 189                 renderer.text = movie.secondary;
 190         }
 191
 192         private void year_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 193                 int year;
 194
 195                 model.get (iter, MovieListStore.Columns.YEAR, out year);
 196                 ((CellRendererText) cell).text = (year > 0) ? year.to_string () : "";
 197         }
 198
 199         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 200                 int rating;
 201
 202                 model.get (iter, MovieListStore.Columns.RATING, out rating);
 203                 ((CellRendererText) cell).text = (rating > 0) ? "%d.%d".printf (rating / 10, rating % 10) : "";
 204         }
 205 }