vcs.maemo.org Git - beifahrer/blob - src/query-window.vala

   1 /* This file is part of Beifahrer.
   2  *
   3  * Copyright (C) 2010 Philipp Zabel
   4  *
   5  * Beifahrer is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Beifahrer is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Beifahrer. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class QueryWindow : StackableWindow {
  23         public const string GCONF_KEY_ARRIVAL = "/apps/beifahrer/arrival";
  24         public const string GCONF_KEY_DEPARTURE = "/apps/beifahrer/departure";
  25         public const string GCONF_KEY_USE_LOCATION = "/apps/beifahrer/use_location";
  26
  27         AdacMitfahrclub adac;
  28         TouchSelector city_from_selector;
  29         TouchSelector city_to_selector;
  30         TouchSelector umkreis_from_selector;
  31         TouchSelector umkreis_to_selector;
  32         DateButton date;
  33         TouchSelector tolerance_selector;
  34         Location.GPSDControl control;
  35         Location.GPSDevice device;
  36         GConf.Client gconf;
  37         bool use_location = true;
  38         bool want_location;
  39
  40         construct {
  41                 set_title ("Beifahrer");
  42
  43                 var menu = new AppMenu ();
  44                 var settings = new Gtk.Button.with_label (_("Settings"));
  45                 settings.show ();
  46                 menu.append (settings);
  47                 set_main_menu (menu);
  48
  49                 adac = new AdacMitfahrclub ();
  50                 gconf = GConf.Client.get_default ();
  51
  52                 city_from_selector = new TouchSelectorEntry.text ();
  53                 city_to_selector = new TouchSelectorEntry.text ();
  54                 foreach (unowned City city in adac.get_city_list ()) {
  55                         city_from_selector.append_text (city.name);
  56                         city_to_selector.append_text (city.name);
  57                 }
  58
  59                 umkreis_from_selector = new TouchSelector.text ();
  60                 umkreis_to_selector = new TouchSelector.text ();
  61                 for (int km = 0; km <= 50; km += 10) {
  62                         umkreis_from_selector.append_text ("%d km".printf (km));
  63                         umkreis_to_selector.append_text ("%d km".printf (km));
  64                 }
  65
  66                 tolerance_selector = new TouchSelector.text ();
  67                 for (int days = 0; days <= 4; days += 1)
  68                         tolerance_selector.append_text (_("+/- %d days").printf (days));
  69
  70                 var table = new Table (5, 2, false);
  71
  72                 var button = new PickerButton (SizeType.FINGER_HEIGHT,
  73                                                ButtonArrangement.VERTICAL);
  74                 button.set_selector (city_from_selector);
  75                 button.set_title (_("Departure"));
  76                 button.set_value (_("Please select"));
  77                 button.set_alignment (0.0f, 0.0f, 0.5f, 0.5f);
  78                 table.attach (button, 0, 1, 0, 1, AttachOptions.FILL | AttachOptions.EXPAND, AttachOptions.FILL, 0, 0);
  79
  80                 try {
  81                         button.set_active (gconf.get_int ("/apps/beifahrer/departure"));
  82                 } catch (Error e) {
  83                 }
  84
  85                 button = new PickerButton (SizeType.FINGER_HEIGHT,
  86                                            ButtonArrangement.VERTICAL);
  87                 button.set_selector (umkreis_from_selector);
  88                 button.set_title (_("Vicinity"));
  89                 button.set_value ("0 km");
  90                 button.set_alignment (0.0f, 0.0f, 0.5f, 0.5f);
  91                 table.attach (button, 1, 2, 0, 1, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
  92
  93                 button = new PickerButton (SizeType.FINGER_HEIGHT,
  94                                            ButtonArrangement.VERTICAL);
  95                 button.set_selector (city_to_selector);
  96                 button.set_title (_("Arrival"));
  97                 button.set_value (_("Please select"));
  98                 button.set_alignment (0.0f, 0.0f, 0.5f, 0.5f);
  99                 table.attach (button, 0, 1, 1, 2, AttachOptions.FILL | AttachOptions.EXPAND, AttachOptions.FILL, 0, 0);
 100
 101                 try {
 102                         button.set_active (gconf.get_int ("/apps/beifahrer/arrival"));
 103                 } catch (Error e) {
 104                 }
 105
 106                 button = new PickerButton (SizeType.FINGER_HEIGHT,
 107                                            ButtonArrangement.VERTICAL);
 108                 button.set_selector (umkreis_to_selector);
 109                 button.set_title (_("Vicinity"));
 110                 button.set_value ("0 km");
 111                 button.set_alignment (0.0f, 0.0f, 0.5f, 0.5f);
 112                 table.attach (button, 1, 2, 1, 2, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 113
 114                 var switch_button = new Gtk.Button.with_label (_("Switch departure and arrival"));
 115                 Hildon.gtk_widget_set_theme_size (switch_button, SizeType.FINGER_HEIGHT);
 116                 switch_button.set_alignment (0.0f, 0.5f);
 117                 table.attach (switch_button, 0, 1, 2, 3, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 118
 119                 date = new DateButton (SizeType.FINGER_HEIGHT,
 120                                        ButtonArrangement.VERTICAL);
 121                 date.set_alignment (0.0f, 0.0f, 0.5f, 0.5f);
 122                 table.attach (date, 0, 1, 3, 4, AttachOptions.FILL | AttachOptions.EXPAND, AttachOptions.FILL, 0, 0);
 123
 124                 button = new PickerButton (SizeType.FINGER_HEIGHT,
 125                                            ButtonArrangement.VERTICAL);
 126                 button.set_selector (tolerance_selector);
 127                 button.set_title (_("Tolerance"));
 128                 button.set_value (_("+/- 0 days"));
 129                 button.set_alignment (0.0f, 0.0f, 0.5f, 0.5f);
 130                 table.attach (button, 1, 2, 3, 4, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 131
 132                 var search_button = new Gtk.Button.with_label (_("Search"));
 133                 Hildon.gtk_widget_set_theme_size (search_button, SizeType.FINGER_HEIGHT);
 134                 table.attach (search_button, 0, 2, 4, 5, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 135
 136                 add (table);
 137
 138                 switch_button.clicked.connect (on_switch_button_clicked);
 139                 search_button.clicked.connect (on_search_button_clicked);
 140                 settings.clicked.connect (on_settings_clicked);
 141
 142                 show_all ();
 143
 144                 control = Location.GPSDControl.get_default ();
 145                 control.preferred_method = Location.METHOD_ACWP;
 146                 control.preferred_interval = Location.GPSDControlInterval.@1S;
 147                 control.error.connect (() => { print ("control error\n"); });
 148                 control.error_verbose.connect ((e) => {
 149                         switch (e) {
 150                         case Location.GPSDControlError.USER_REJECTED_DIALOG:
 151                                 print ("\tuser rejected dialog\n");
 152                                 break;
 153                         case Location.GPSDControlError.USER_REJECTED_SETTINGS:
 154                                 print ("\tuser rejected settings\n");
 155                                 break;
 156                         case Location.GPSDControlError.BT_GPS_NOT_AVAILABLE:
 157                                 print ("\tbt gps not available\n");
 158                                 break;
 159                         case Location.GPSDControlError.METHOD_NOT_ALLOWED_IN_OFFLINE_MODE:
 160                                 print ("\tmethod not allowed in offline mode\n");
 161                                 break;
 162                         case Location.GPSDControlError.SYSTEM:
 163                                 Banner.show_information (this, null, _("No GPS available!"));
 164                                 break;
 165                         }
 166                 });
 167                 control.gpsd_running.connect (() => { print ("control running\n"); });
 168                 control.gpsd_stopped.connect (() => { print ("control stopped\n"); });
 169
 170                 try {
 171                         use_location = gconf.get_bool (GCONF_KEY_USE_LOCATION);
 172                 } catch (Error e) {
 173                 }
 174                 want_location = use_location;
 175                 if (want_location)
 176                         control.start ();
 177
 178                 device = (Location.GPSDevice) GLib.Object.@new (typeof (Location.GPSDevice), null);
 179                 device.changed.connect (on_location_changed);
 180                 device.connected.connect (() => { print ("device connected\n"); });
 181                 device.disconnected.connect (() => { print ("device disconnected\n"); });
 182
 183                 // In case the device already has a fix:
 184                 on_location_changed ();
 185         }
 186
 187         void on_location_changed () requires (device.fix != null) {
 188                 if (!want_location || device.status == Location.GPSDeviceStatus.NO_FIX)
 189                         return;
 190
 191                 if (Location.GPS_DEVICE_LATLONG_SET in (int) device.fix.fields) {
 192                         print ("fix: lat=%f, lon=%f\n", device.fix.latitude, device.fix.longitude);
 193
 194                         unowned City city = adac.find_nearest_city (device.fix.latitude, device.fix.longitude);
 195                         if (city != null) {
 196                                 int n = adac.get_city_list ().index (city);
 197                                 int n_from = city_from_selector.get_active (0);
 198                                 int n_to = city_to_selector.get_active (0);
 199
 200                                 print ("city(%d): %s (%d)\n", n, city.name, city.number);
 201
 202                                 if (n != n_from) {
 203                                         city_from_selector.set_active (0, n);
 204
 205                                         // If we are at the previous point of arrival, prepare for return trip
 206                                         if (n == n_to)
 207                                                 city_to_selector.set_active (0, n_from);
 208                                 }
 209                         }
 210
 211                         control.stop ();
 212                         want_location = false;
 213                 }
 214         }
 215
 216         void on_search_button_clicked (Gtk.Button button) {
 217                 int n;
 218
 219                 n = city_from_selector.get_active (0);
 220                 if (n == -1)
 221                         return;
 222                 string city_from = adac.get_city_list ().nth_data (n).name;
 223                 try {
 224                         if (gconf.get_int (GCONF_KEY_DEPARTURE) != n)
 225                                 gconf.set_int (GCONF_KEY_DEPARTURE, n);
 226                 } catch (Error e) {
 227                 }
 228
 229                 n = city_to_selector.get_active (0);
 230                 if (n == -1)
 231                         return;
 232                 string city_to = adac.get_city_list ().nth_data (n).name;
 233                 try {
 234                         if (gconf.get_int (GCONF_KEY_ARRIVAL) != n)
 235                                 gconf.set_int (GCONF_KEY_ARRIVAL, n);
 236                 } catch (Error e) {
 237                 }
 238
 239                 uint year, month, day;
 240                 date.get_date (out year, out month, out day);
 241                 var date = Date ();
 242                 date.set_day ((DateDay) day);
 243                 date.set_month ((DateMonth) (month + DateMonth.JANUARY));
 244                 date.set_year ((DateYear) year);
 245
 246                 int tolerance = tolerance_selector.get_active (0);
 247
 248                 var window = new LiftListWindow (adac);
 249                 window.show ();
 250                 window.find_lifts.begin (city_from, city_to, date, tolerance);
 251         }
 252
 253         // Switch departure and arrival
 254         void on_switch_button_clicked () {
 255                 int n = city_from_selector.get_active (0);
 256                 city_from_selector.set_active (0, city_to_selector.get_active (0));
 257                 city_to_selector.set_active (0, n);
 258                 n = umkreis_from_selector.get_active (0);
 259                 umkreis_from_selector.set_active (0, umkreis_to_selector.get_active (0));
 260                 umkreis_to_selector.set_active (0, n);
 261         }
 262
 263         void on_settings_clicked () {
 264                 var dialog = new SettingsDialog (this);
 265                 dialog.response.connect (on_settings_response);
 266                 dialog.show ();
 267         }
 268
 269         void on_settings_response (int response_id) {
 270                 bool old_use_location = use_location;
 271                 use_location = gconf.get_bool (GCONF_KEY_USE_LOCATION);
 272                 if (!old_use_location && use_location) {
 273                         want_location = true;
 274                         control.start ();
 275                 }
 276         }
 277 }