X-Git-Url: https://vcs.maemo.org/git/?a=blobdiff_plain;f=demo%2Fenhancedtext.dem;fp=demo%2Fenhancedtext.dem;h=8b872b1e4a02e8f76b09e64be874b27c1bc4cb79;hb=39ec1247a71f61152a4a7f502a30f06a3896c5da;hp=0000000000000000000000000000000000000000;hpb=06be459be4f5f6a7c6ff878e84f355fb2575caa8;p=gnuplot

diff --git a/demo/enhancedtext.dem b/demo/enhancedtext.dem
new file mode 100644
index 0000000..8b872b1
--- /dev/null
+++ b/demo/enhancedtext.dem
@@ -0,0 +1,54 @@
+#
+# Test page for enhanced text mode
+#
+print "    ----------------------------------------------------"
+print "    This test page for enhanced text mode will only work"
+print "    if enhanced text is selected and supported for the"
+print "    current terminal type.  E.g. 'set term post enh'"
+print "    ----------------------------------------------------"
+#
+set termoption enhanced
+#
+set title "Test page for enhanced text mode"
+set xrange [-1:1]
+set yrange [-0.5:1.1]
+set format xy "%.1f"
+set arrow from  0.5, -0.5 to  0.5, 0.0 nohead
+#
+set label 1 at -0.65, 1.0
+set label 1 "These examples require no extra fonts:" tc lt 3
+set label 2 at -0.55, 0.9
+set label 2 "10^{-2}   A_{j,k}   e^x"
+set label 3 at -0.55, 0.8 
+set label 3 'x@^2_k    x@_0^{-3/2}y'
+
+set label 5 at -0.55,  0.7 
+set label 5 "Space-holders:" tc lt 3
+set label 6 at -0.45, 0.6 
+set label 6 "<&{{/=20 B}ig}> <&{x@_0^{-3/2}y}> holds space for"
+set label 7 at -0.45, 0.5 
+set label 7 "<{/=20 B}ig> <x@_0^{-3/2}y>"
+
+set label 8 at -0.9, -0.2
+set label 8 "Overprint\n(v should be centred over d)" tc lt 3
+set label 9 at -0.85, -0.4
+set label 9 " ~{abcdefg}{0.8v}"
+
+
+set label 10 at  -.40, 0.35
+set label 10 "Requires Symbol font:" tc lt 3
+set label 11 at -.30, 0.2
+set label 11 "{/Symbol=18 \362@_{/=9.6 0}^{/=12 ^\245}} {e^{-{/Symbol m}^2/2} d}{/Symbol m=(p/2)^{1/2}}"
+
+set label 21 at 0.5, -.1
+set label 21 "Left  ^{centered} text" left
+set label 22 at 0.5, -.2
+set label 22 "Right ^{centered} text" right
+set label 23 at 0.5, -.3
+set label 23 "Center^{centered} text" center
+#
+set key title " "
+plot sin(x)**2 lt 2 lw 2 title "sin^2(x)"
+#
+pause -1 "Hit <cr> to continue"
+reset