# -------------------------------------------------
# Project created by QtCreator 2010-03-26T07:57:35
# -------------------------------------------------
TARGET = ../situare
TEMPLATE = app
INCLUDEPATH += /usr/include/qjson
LIBS += -lqjson
RESOURCES += ../images.qrc
SOURCES += main.cpp \
    ui/mainwindow.cpp \
    situareservice/situareservice.cpp \
    situareservice/imagefetcher.cpp \
    facebookservice/facebookcredentials.cpp \
    facebookservice/facebookauthentication.cpp \
    map/mapengine.cpp \
    map/mapview.cpp \
    map/mapscene.cpp \
    map/maptile.cpp \
    map/mapfetcher.cpp \
    map/ownlocationitem.cpp \
    map/baselocationitem.cpp \
    map/friendlocationitem.cpp \
    ui/updatelocation/updatelocationdialog.cpp \
    ui/updatelocation/texteditautoresizer.cpp \
    ui/friendlistview.cpp \
    ui/friendlistitem.cpp \
    user/user.cpp \
    ui/avatarimage.cpp \
    engine/engine.cpp \
    ui/settingsdialog.cpp \
    ui/logindialog.cpp \
    map/maptilerequest.cpp \
    ui/imagebutton.cpp \
    ui/friendlistpanel.cpp \
    ui/userinfopanel.cpp \
    ui/panelsidebar.cpp \
    ui/panelsliderbar.cpp \
    map/friendgroupitem.cpp \
    map/frienditemshandler.cpp \
    gps/gpsposition.cpp \
    map/gpslocationitem.cpp \
    ui/zoombuttonpanel.cpp \
    ui/userinfo.cpp \
    ui/sidepanel.cpp \
    ui/zoombutton.cpp \
    network/networkaccessmanager.cpp \
    network/networkhandler.cpp \
    network/networkreply.cpp
HEADERS += ui/mainwindow.h \
    map/mapengine.h \
    map/mapview.h \
    map/mapscene.h \
    map/maptile.h \
    map/mapfetcher.h \
    map/mapcommon.h \
    map/ownlocationitem.h \
    map/baselocationitem.h \
    map/friendlocationitem.h \
    ui/updatelocation/updatelocationdialog.h \
    ui/updatelocation/texteditautoresizer.h \
    situareservice/situareservice.h \
    situareservice/situarecommon.h \
    situareservice/imagefetcher.h \
    facebookservice/facebookcredentials.h \
    facebookservice/facebookauthentication.h \
    facebookservice/facebookcommon.h \
    ui/friendlistview.h \
    ui/friendlistitem.h \
    user/user.h \
    ui/avatarimage.h \
    engine/engine.h \
    ui/settingsdialog.h \
    ui/logindialog.h \
    map/maptilerequest.h \
    ui/imagebutton.h \
    ui/friendlistpanel.h \
    ui/userinfopanel.h \
    ui/panelcommon.h \
    ui/panelsidebar.h \
    ui/panelsliderbar.h \
    map/friendgroupitem.h \
    map/frienditemshandler.h \
    gps/gpsposition.h \
    map/gpslocationitem.h \
    gps/gpscommon.h \
    ui/zoombuttonpanel.h \
    common.h \
    ui/userinfo.h \
    ui/sidepanel.h \
    ui/zoombutton.h \
    network/networkaccessmanager.h \
    network/networkhandler.h \
    network/networkreply.h
QT += network \
    webkit

#DEFINES += QT_NO_DEBUG_OUTPUT

maemo5 | simulator {
    sbox | simulator {
        DEFINES += SBOX
        SOURCES += network/networkhandlerprivatestub.cpp
        HEADERS += network/networkhandlerprivatestub.h
    } else {
        INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
        SOURCES += network/networkhandlerprivate.cpp
        HEADERS += network/networkhandlerprivate.h
        QT += dbus
        CONFIG += icd2
    }
    SOURCES += gps/gpspositionprivate.cpp
    HEADERS += gps/gpspositionprivate.h
    QT += maemo5
    CONFIG += mobility
    MOBILITY = location
    message([QJson])
    message(Make sure you have QJson development headers installed)
    message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
    message(to Scratchbox's sources.list in /etc/apt)
    message(run: apt-get update)
    message(install headers with: apt-get install libqjson-dev)
    message([QtMobility])
    message(Make sure you have QtMobility development headers installed)
    message(install headers with: apt-get install libqtm-dev)
} else {
    SOURCES += gps/gpspositionprivatestub.cpp \
               network/networkhandlerprivatestub.cpp
    HEADERS += gps/gpspositionprivatestub.h \
               network/networkhandlerprivatestub.h
    message(QJson built in)
    message(Make sure you have QJson development headers installed)
    message(install headers with: sudo apt-get install libqjson-dev)
}

# -----------------------------------------------------------------
# Debian packetizing additions
# -----------------------------------------------------------------
unix {
    # VARIABLES
    isEmpty(PREFIX):PREFIX = /usr
    BINDIR = $$PREFIX/bin
    DATADIR = $$PREFIX/share
    DEFINES += DATADIR=\\\"$$DATADIR\\\" \
        PKGDATADIR=\\\"$$PKGDATADIR\\\"
    
    # MAKE INSTALL
    desktop.path = $$DATADIR/applications/hildon
    desktop.files += situare.desktop
    INSTALLS += desktop
    icon48.path = $$DATADIR/icons/hicolor/48x48/apps
    icon48.files += ../res/icon/48x48/situare.png
    INSTALLS += icon48
    icon64.path = $$DATADIR/icons/hicolor/64x64/apps
    icon64.files += ../res/icon/64x64/situare.png
    INSTALLS += icon64
    target.path = $$BINDIR
    INSTALLS += target
}