# -------------------------------------------------
# Project created by QtCreator 2010-03-26T07:57:35
# -------------------------------------------------
TARGET = ../situare
TEMPLATE = app
INCLUDEPATH += "/usr/include/qjson"
LIBS += "-lqjson"
RESOURCES += images.qrc
SOURCES += main.cpp \
    ui/mainwindow.cpp \
    ui/mapviewscreen.cpp \
    ui/listviewscreen.cpp \
    situareservice/situareservice.cpp \
    situareservice/imagefetcher.cpp \
    cookiehandler/cookiehandler.cpp \
    facebookservice/facebookcredentials.cpp \
    facebookservice/facebookauthentication.cpp \
    map/mapengine.cpp \
    map/mapview.cpp \
    map/mapscene.cpp \
    map/maptile.cpp \
    map/mapfetcher.cpp \
    ui/pixmap.cpp \
    ui/infotab.cpp \
    ui/updatelocation/updatelocationdialog.cpp \
    ui/updatelocation/texteditautoresizer.cpp \
    engine/engine.cpp \
    user/user.cpp
HEADERS += ui/mainwindow.h \
    ui/mapviewscreen.h \
    ui/listviewscreen.h \
    map/mapengine.h \
    map/mapview.h \
    map/mapscene.h \
    map/maptile.h \
    map/mapfetcher.h \
    map/mapcommon.h \
    ui/pixmap.h \
    ui/infotab.h \
    ui/updatelocation/updatelocationdialog.h \
    ui/updatelocation/texteditautoresizer.h \
    situareservice/situareservice.h \
    situareservice/situarecommon.h \
    situareservice/imagefetcher.h \
    cookiehandler/cookiehandler.h \
    facebookservice/facebookcredentials.h \
    facebookservice/facebookauthentication.h \
    facebookservice/facebookcommon.h \
    engine/engine.h \
    user/user.h
QT += network \
    webkit

# use don't use OpenGL when building in scratchbox
!maemo5 { 
    QT += opengl
    message(OpenGL built in)
    message(Make sure you have OpenGL development headers installed)
    message(install headers with: sudo apt-get install libgl-dev libglu-dev)
}

!maemo5 {
    message(QJson built in)
    message(Make sure you have QJson development headers installed)
    message(install headers with: sudo apt-get install libqjson-dev)
}

maemo5 {
    message(QJson built in)
    message(Make sure you have QJson development headers installed)
    message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
    message(to scratchbox's sources.list in /etc/apt)
    message(run: apt-get update)
    message(install headers with: apt-get install libqjson-dev)
}

# -----------------------------------------------------------------
# Debian packetizing additions
# -----------------------------------------------------------------
unix { 
    # VARIABLES
    isEmpty(PREFIX):PREFIX = /usr
    BINDIR = $$PREFIX/bin
    DATADIR = $$PREFIX/share
    DEFINES += DATADIR=\\\"$$DATADIR\\\" \
        PKGDATADIR=\\\"$$PKGDATADIR\\\"
    
    # MAKE INSTALL
    desktop.path = $$DATADIR/applications/hildon
    desktop.files += situare.desktop
    INSTALLS += desktop
    icon26.path = $$DATADIR/icons/hicolor/26x26/apps
    icon26.files += situare.png
    INSTALLS += icon26
    icon40.path = $$DATADIR/icons/hicolor/40x40/apps
    icon40.files += situare_40x40.png
    INSTALLS += icon40
    icon64.path = $$DATADIR/icons/hicolor/64x64/apps
    icon64.files += situare_64x64.png
    INSTALLS += icon64
    target.path = $$BINDIR
    INSTALLS += target
}
RESOURCES +=