/* This file is part of Cinaest.
*
* Copyright (C) 2009 Philipp Zabel
*
* Cinaest is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* Cinaest is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with Cinaest. If not, see .
*/
using Gtk;
using Hildon;
public class SourceListView : PannableArea {
TreeView tree;
ListStore store;
TreeModelFilter filtered_store;
bool filtered;
public signal void source_activated (MovieSource source);
public SourceListView (List list, bool _filtered, Gtk.Window window) {
filtered = _filtered;
// Source list
store = new ListStore (3, typeof (string), typeof (string), typeof (MovieSource));
add_sources (list);
if (filtered) {
// Add filter wrapper
filtered_store = new TreeModelFilter (store, null);
filtered_store.set_visible_func (filter_visible_func);
// Tree View
tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, filtered_store);
} else {
tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, store);
}
tree.set_headers_visible (false);
add (tree);
tree.set_rules_hint (true);
// Tree selection object
var selection = tree.get_selection ();
selection.set_mode (SelectionMode.SINGLE);
// Source column
var title_column = new TreeViewColumn ();
title_column.set_title (_("Source"));
title_column.set_reorderable (false);
title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
title_column.set_expand (true);
// Add name
var vbox_renderer = new CellRendererVBox ();
var renderer = new CellRendererText ();
renderer.yalign = 1.0f;
vbox_renderer.append (renderer, true);
vbox_renderer.set_data ("name", renderer);
// Add description
renderer = new CellRendererText ();
renderer.yalign = 0;
renderer.ellipsize = Pango.EllipsizeMode.END;
Pango.AttrList attr_list = new Pango.AttrList ();
var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), "SmallSystemFont", null, typeof (void));
if (style != null) {
var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
attr_list.insert ((owned) attr_font_desc);
}
Gdk.Color color;
window.ensure_style ();
if (window.style.lookup_color ("SecondaryTextColor", out color)) {
Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
attr_list.insert ((owned) attr_color);
}
renderer.attributes = attr_list;
vbox_renderer.append (renderer, true);
vbox_renderer.set_data ("description", renderer);
title_column.pack_start (vbox_renderer, true);
title_column.set_cell_data_func (vbox_renderer, vbox_data_func);
tree.append_column (title_column);
// Connect signals
tree.row_activated.connect (on_row_activated);
}
bool filter_visible_func (TreeModel model, TreeIter iter) {
MovieSource source = null;
store.get (iter, 2, out source);
return source.active;
}
public void add_sources (List list) {
foreach (MovieSource source in list) {
TreeIter iter;
store.insert_with_values (out iter, -1, 0, source.get_name (), 1, source.get_description (), 2, source);
source.notify["active"].connect (this.on_source_changed);
}
}
private void on_source_changed (GLib.Object _source, GLib.ParamSpec spec) {
var source = (MovieSource) _source;
TreeIter iter;
if (get_iter (source, out iter)) {
TreePath path = store.get_path (iter);
store.row_changed (path, iter);
}
}
public bool get_iter (MovieSource source, out Gtk.TreeIter iter) {
if (store.get_iter_first (out iter)) do {
MovieSource s = null;
store.get (iter, 2, out s);
if (s == source) {
return true;
}
} while (store.iter_next (ref iter));
return false;
}
public unowned TreeSelection get_selection () {
return tree.get_selection ();
}
public void set_hildon_ui_mode (UIMode mode) {
var selection = tree.get_selection ();
if (mode == UIMode.NORMAL) {
selection.set_mode (SelectionMode.NONE);
}
Hildon.gtk_tree_view_set_ui_mode (tree, mode);
if (mode == UIMode.EDIT) {
selection.set_mode (SelectionMode.MULTIPLE);
}
}
public int length () {
TreeIter iter;
int len = 0;
if (store.get_iter_first (out iter)) do {
len++;
} while (store.iter_next (ref iter));
return len;
}
private void on_row_activated (TreeView tree, TreePath path_, TreeViewColumn column) {
TreePath path = path_.copy (); // FIXME - calling model.get_iter with path_ directly causes a C qualifier warning
TreeModel model = tree.model;
TreeIter iter;
if (model.get_iter (out iter, path)) {
MovieSource source;
model.get (iter, 2, out source);
source_activated (source);
}
}
private void vbox_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
CellRendererText renderer;
string name;
string description;
model.get (iter, 0, out name, 1, out description);
renderer = cell.get_data ("name");
renderer.text = name;
renderer = cell.get_data ("description");
renderer.text = description;
}
}