TARGET = xdxf

include(../plugin.pri)

QT = core \
    gui \
    xml \
    sql \
    network\
    declarative

maemo5 {
    LIBS += -lbz2 \
}

!maemo5 {
    LIBS += -ltar \
        -lbz2
}
maemo5:QT += maemo5

SOURCES += xdxfplugin.cpp \
    TranslationXdxf.cpp \
    XdxfDictDialog.cpp \
    XdxfCachingDialog.cpp \
    XdxfDialog.cpp \
    XdxfDictDownloader.cpp \
    XdxfDictSelectDialog.cpp \
    XdxfDictDownloadProgressDialog.cpp \
    DictsModel.cpp \
    HttpDownloader.cpp \
    DictsListModel.cpp \
    ../../include/ComboBoxModel.cpp

HEADERS += xdxfplugin.h \
    TranslationXdxf.h \
    ../../include/DictDialog.h \
    XdxfDictDialog.h \
    ../../include/translation.h \
    ../../include/settings.h \
    ../../include/CommonDictInterface.h \
    ../../include/ComboBoxModel.h \
    XdxfCachingDialog.h \
    XdxfDialog.h \
    XdxfDictDownloader.h \
    XdxfDictSelectDialog.h \
    XdxfDictDownloadProgressDialog.h \
    DownloadDict.h \
    DictsModel.h \
    DictsProxyModel.h \
    HttpDownloader.h \
    DictsListModel.h \
    DictsProxyListModel.h

RESOURCES += xdxf.qrc

TRANSLATIONS += pl_PL.ts \
                en_US.ts

OTHER_FILES += ../../mdictionary/qml/XdxfDialog.qml \
    ../../mdictionary/qml/XdxfDictDownloader.qml \
    ../../mdictionary/qml/TableWidget.qml \
    ../../mdictionary/qml/ScrollBar2.qml

unix {
    dicts.path = $$PLUGINS_DIR
    dicts.files += ../../../data/dicts/eng-us.xdxf
    dicts.files += ../../../data/dicts/eng-thai.xdxf
    plugin-icon.path = $$DATA_DIR
    plugin-icon.files += xdxf.png

    meego {
        qmls.path = $$DATA_DIR/qml
        qmls.files += ../../mdictionary/qml/XdxfDialog.qml
    }
    else:maemo5 {
        qmls.path = $$DATA_DIR/qml
        qmls.files += ../../mdictionary/qml/XdxfDialog.qml
    }
    else {
        qmls.path = $$DATA_DIR/qml
        qmls.files += ../../mdictionary/qml/XdxfDialog.qml
        qmls.files += ../../mdictionary/qml/XdxfDictDownloader.qml
        qmls.files += ../../mdictionary/qml/TableWidget.qml
        qmls.files += ../../mdictionary/qml/ScrollBar2.qml

    }

    INSTALLS += dicts \
        plugin-icon\
        qmls
}
check.commands = echo \
                'No check here'
QMAKE_EXTRA_TARGETS += check