vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += "/usr/include/qjson"
   7 LIBS += "-lqjson"
   8 RESOURCES += ../images.qrc
   9 SOURCES += main.cpp \
  10     ui/mainwindow.cpp \
  11     ui/mapviewscreen.cpp \
  12     ui/listviewscreen.cpp \
  13     situareservice/situareservice.cpp \
  14     situareservice/imagefetcher.cpp \
  15     cookiehandler/cookiehandler.cpp \
  16     facebookservice/facebookcredentials.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     map/mapengine.cpp \
  19     map/mapview.cpp \
  20     map/mapscene.cpp \
  21     map/maptile.cpp \
  22     map/mapfetcher.cpp \
  23     map/mapzoompanel.cpp \
  24     map/mapbutton.cpp \
  25     ui/pixmap.cpp \
  26     ui/infotab.cpp \
  27     ui/updatelocation/updatelocationdialog.cpp \
  28     ui/updatelocation/texteditautoresizer.cpp \
  29     user/user.cpp \
  30     ui/buttonitem.cpp \
  31     ui/situareuser.cpp \
  32     engine/engine.cpp
  33 HEADERS += ui/mainwindow.h \
  34     ui/mapviewscreen.h \
  35     ui/listviewscreen.h \
  36     map/mapengine.h \
  37     map/mapview.h \
  38     map/mapscene.h \
  39     map/maptile.h \
  40     map/mapfetcher.h \
  41     map/mapcommon.h \
  42     map/mapzoompanel.h \
  43     map/mapbutton.h \
  44     ui/pixmap.h \
  45     ui/infotab.h \
  46     ui/updatelocation/updatelocationdialog.h \
  47     ui/updatelocation/texteditautoresizer.h \
  48     situareservice/situareservice.h \
  49     situareservice/situarecommon.h \
  50     situareservice/imagefetcher.h \
  51     cookiehandler/cookiehandler.h \
  52     facebookservice/facebookcredentials.h \
  53     facebookservice/facebookauthentication.h \
  54     facebookservice/facebookcommon.h \
  55     ui/buttonitem.h \
  56     ui/situareuser.h \
  57     engine/engine.h \
  58     user/user.h
  59 QT += network \
  60     webkit
  61
  62 # use don't use OpenGL when building in scratchbox
  63 !maemo5 {
  64     QT += opengl
  65     message(OpenGL built in)
  66     message(Make sure you have OpenGL development headers installed)
  67     message(install headers with: sudo apt-get install libgl-dev libglu-dev)
  68
  69     message(QJson built in)
  70     message(Make sure you have QJson development headers installed)
  71     message(install headers with: sudo apt-get install libqjson-dev)
  72 }
  73
  74 maemo5 {
  75     message(QJson built in)
  76     message(Make sure you have QJson development headers installed)
  77     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
  78     message(and deb-src http://repository.maemo.org/extras-devel fremantle free non-free)
  79     message(to scratchbox's sources.list in /etc/apt)
  80     message(run: apt-get update)
  81     message(install headers with: apt-get install libqjson-dev)
  82 }
  83
  84 # -----------------------------------------------------------------
  85 # Debian packetizing additions
  86 # -----------------------------------------------------------------
  87 unix {
  88     # VARIABLES
  89     isEmpty(PREFIX):PREFIX = /usr
  90     BINDIR = $$PREFIX/bin
  91     DATADIR = $$PREFIX/share
  92     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  93         PKGDATADIR=\\\"$$PKGDATADIR\\\"
  94
  95     # MAKE INSTALL
  96     desktop.path = $$DATADIR/applications/hildon
  97     desktop.files += situare.desktop
  98     INSTALLS += desktop
  99     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 100     icon48.files += ../res/icon/48x48/situare.png
 101     INSTALLS += icon48
 102     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 103     icon64.files += ../res/icon/64x64/situare.png
 104     INSTALLS += icon64
 105     target.path = $$BINDIR
 106     INSTALLS += target
 107 }
 108 RESOURCES +=