vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/panelbar.cpp \
  74     ui/panelbase.cpp \
  75     ui/panelcontentstack.cpp \
  76     ui/panelcontextbuttonbar.cpp \
  77     ui/paneltab.cpp \
  78     ui/paneltabbar.cpp \
  79     ui/tabbedpanel.cpp \
  80     ui/routingpanel.cpp \
  81     ui/routewaypointlistitem.cpp \
  82     ui/routewaypointlistview.cpp \
  83     user/user.cpp \
  84     ui/locationsearchpanel.cpp \
  85     ui/textmodifier.cpp \
  86     ui/meetpeoplepanel.cpp \
  87     situareservice/database.cpp \
  88     ui/tagsdialog.cpp \
  89     engine/contactmanager.cpp \
  90     ui/messagelistview.cpp \
  91     ui/messagelistitem.cpp \
  92     situareservice/message.cpp \
  93     ui/headerlistitemdelegate.cpp
  94 HEADERS += application.h \
  95     common.h \
  96     coordinates/geocoordinate.h \
  97     coordinates/scenecoordinate.h \
  98     engine/engine.h \
  99     engine/mce.h \
 100     error.h \
 101     facebookservice/facebookauthentication.h \
 102     facebookservice/facebookcommon.h \
 103     facebookservice/facebookcredentials.h \
 104     gps/gpscommon.h \
 105     gps/gpsposition.h \
 106     map/baselocationitem.h \
 107     map/friendgroupitem.h \
 108     map/frienditemshandler.h \
 109     map/friendlocationitem.h \
 110     map/gpslocationitem.h \
 111     map/mapcommon.h \
 112     map/mapengine.h \
 113     map/mapfetcher.h \
 114     map/maprouteitem.h \
 115     map/mapscene.h \
 116     map/mapscroller.h \
 117     map/maptile.h \
 118     map/maptilerequest.h \
 119     map/mapview.h \
 120     map/osm.h \
 121     map/ownlocationitem.h \
 122     network/networkaccessmanager.h \
 123     network/networkcookiejar.h \
 124     network/networkhandler.h \
 125     network/networkreply.h \
 126     routing/geocodingservice.h \
 127     routing/location.h \
 128     routing/route.h \
 129     routing/routesegment.h \
 130     routing/routingcommon.h \
 131     routing/routingservice.h \
 132     situareservice/imagefetcher.h \
 133     situareservice/situarecommon.h \
 134     situareservice/situareservice.h \
 135     ui/updatelocation/texteditautoresizer.h \
 136     ui/updatelocation/updatelocationdialog.h \
 137     ui/avatarimage.h \
 138     ui/extendedlistitem.h \
 139     ui/extendedlistitemdelegate.h \
 140     ui/extendedlistitemstore.h \
 141     ui/friendlistitem.h \
 142     ui/friendlistitemdelegate.h \
 143     ui/friendlistpanel.h \
 144     ui/friendlistview.h \
 145     ui/fullscreenbutton.h \
 146     ui/imagebutton.h \
 147     ui/indicatorbutton.h \
 148     ui/indicatorbuttonpanel.h \
 149     ui/logindialog.h \
 150     ui/locationlistitem.h \
 151     ui/locationlistview.h \
 152     ui/mainwindow.h \
 153     ui/mapscale.h \
 154     ui/settingsdialog.h \
 155     ui/userinfo.h \
 156     ui/userinfopanel.h \
 157     ui/zoombutton.h \
 158     ui/zoombuttonpanel.h \
 159     ui/listcommon.h \
 160     ui/listview.h \
 161     ui/listitem.h \
 162     ui/listitemdelegate.h \
 163     ui/searchdialog.h \
 164     ui/panelbar.h \
 165     ui/panelbase.h \
 166     ui/panelcommon.h \
 167     ui/panelcontentstack.h \
 168     ui/panelcontextbuttonbar.h \
 169     ui/paneltab.h \
 170     ui/paneltabbar.h \
 171     ui/tabbedpanel.h \
 172     ui/routingpanel.h \
 173     ui/routewaypointlistitem.h \
 174     ui/routewaypointlistview.h \
 175     user/user.h \
 176     ui/locationsearchpanel.h \
 177     ui/textmodifier.h \
 178     ui/meetpeoplepanel.h \
 179     situareservice/database.h \
 180     ui/tagsdialog.h \
 181     engine/contactmanager.h \
 182     ui/messagelistview.h \
 183     ui/messagelistitem.h \
 184     situareservice/message.h \
 185     ui/headerlistitemdelegate.h
 186 QT += network \
 187     webkit \
 188     sql
 189 DEFINES += QT_NO_DEBUG_OUTPUT
 190
 191 simulator {
 192     SOURCES += network/networkhandlerprivatestub.cpp \
 193                gps/gpspositionprivate.cpp
 194     HEADERS += network/networkhandlerprivatestub.h \
 195                gps/gpspositionprivate.h
 196     SOURCES += engine/contactmanagerprivatestub.cpp
 197     HEADERS += engine/contactmanagerprivatestub.h
 198     QT += maemo5
 199     CONFIG += mobility
 200     MOBILITY += location
 201 } else:maemo5 {
 202     armel {
 203         DEFINES += ARMEL
 204         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 205         SOURCES += network/networkhandlerprivate.cpp \
 206                    engine/mceprivate.cpp
 207         HEADERS += network/networkhandlerprivate.h \
 208                    engine/mceprivate.h
 209         QT += dbus xml
 210         CONFIG += icd2 qdbus
 211         SOURCES += gps/gpspositionprivateliblocation.cpp \
 212                    gps/liblocationwrapper.cpp \
 213                    gps/geopositioninfo.cpp
 214         HEADERS += gps/gpspositionprivateliblocation.h \
 215                    gps/liblocationwrapper.h \
 216                    gps/geopositioninfo.h
 217         CONFIG += link_pkgconfig
 218         PKGCONFIG += glib-2.0 liblocation mce gtk+-2.0 libosso-abook-1.0
 219         LIBS += -llocation
 220         SOURCES += engine/contactmanagerprivate.cpp \
 221                    ui/ossoabookdialog.cpp
 222         HEADERS += engine/contactmanagerprivate.h \
 223                    ui/ossoabookdialog.h
 224         CONFIG += mobility
 225         MOBILITY += contacts
 226     } else {
 227         SOURCES += gps/gpspositionprivatestub.cpp \
 228                    network/networkhandlerprivatestub.cpp \
 229                    engine/mceprivatestub.cpp
 230         HEADERS += gps/gpspositionprivatestub.h \
 231                    network/networkhandlerprivatestub.h \
 232                    engine/mceprivatestub.h
 233         SOURCES += engine/contactmanagerprivatestub.cpp
 234         HEADERS += engine/contactmanagerprivatestub.h
 235     }
 236
 237     QT += maemo5
 238
 239     message([QJson])
 240     message(Make sure you have QJson development headers installed)
 241     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 242     message(to Scratchbox's sources.list in /etc/apt)
 243     message(run: apt-get update)
 244     message(install headers with: apt-get install libqjson-dev)
 245     message([QtMobility])
 246     message(Make sure you have QtMobility development headers installed)
 247     message(install headers with: apt-get install libqtm-dev)
 248 } else {
 249     SOURCES += gps/gpspositionprivatestub.cpp \
 250                network/networkhandlerprivatestub.cpp \
 251                engine/mceprivatestub.cpp
 252     HEADERS += gps/gpspositionprivatestub.h \
 253                network/networkhandlerprivatestub.h \
 254                engine/mceprivatestub.h
 255     SOURCES += engine/contactmanagerprivatestub.cpp
 256     HEADERS += engine/contactmanagerprivatestub.h
 257     message(QJson built in)
 258     message(Make sure you have QJson development headers installed)
 259     message(install headers with: sudo apt-get install libqjson-dev)
 260 }
 261
 262 # -----------------------------------------------------------------
 263 # Debian packetizing additions
 264 # -----------------------------------------------------------------
 265 unix {
 266     # VARIABLES
 267     isEmpty(PREFIX):PREFIX = /usr
 268     BINDIR = $$PREFIX/bin
 269     DATADIR = $$PREFIX/share
 270     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 271         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 272
 273     # MAKE INSTALL
 274     desktop.path = $$DATADIR/applications/hildon
 275     desktop.files += situare.desktop
 276     INSTALLS += desktop
 277     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 278     icon48.files += ../res/icon/48x48/situare.png
 279     INSTALLS += icon48
 280     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 281     icon64.files += ../res/icon/64x64/situare.png
 282     INSTALLS += icon64
 283     target.path = $$BINDIR
 284     INSTALLS += target
 285 }