vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += "/usr/include/qjson"
   7 LIBS += "-lqjson"
   8 RESOURCES += images.qrc
   9 SOURCES += main.cpp \
  10     ui/mainwindow.cpp \
  11     ui/mapviewscreen.cpp \
  12     ui/listviewscreen.cpp \
  13     situareservice/situareservice.cpp \
  14     cookiehandler/cookiehandler.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     facebookservice/facebookauthentication.cpp \
  17     map/mapengine.cpp \
  18     map/mapview.cpp \
  19     map/mapscene.cpp \
  20     map/maptile.cpp \
  21     map/mapfetcher.cpp \
  22     ui/pixmap.cpp \
  23     ui/infotab.cpp \
  24     ui/updatelocation/updatelocationdialog.cpp \
  25     ui/updatelocation/texteditautoresizer.cpp \
  26     engine/engine.cpp \
  27     user/user.cpp
  28 HEADERS += ui/mainwindow.h \
  29     ui/mapviewscreen.h \
  30     ui/listviewscreen.h \
  31     map/mapengine.h \
  32     map/mapview.h \
  33     map/mapscene.h \
  34     map/maptile.h \
  35     map/mapfetcher.h \
  36     map/mapcommon.h \
  37     ui/pixmap.h \
  38     ui/infotab.h \
  39     ui/updatelocation/updatelocationdialog.h \
  40     ui/updatelocation/texteditautoresizer.h \
  41     situareservice/situareservice.h \
  42     situareservice/situarecommon.h \
  43     cookiehandler/cookiehandler.h \
  44     facebookservice/facebookcredentials.h \
  45     facebookservice/facebookauthentication.h \
  46     facebookservice/facebookcommon.h \
  47     engine/engine.h \
  48     user/user.h
  49 QT += network \
  50     webkit
  51
  52 # use don't use OpenGL when building in scratchbox
  53 !maemo5 {
  54     QT += opengl
  55     message(OpenGL built in)
  56     message(Make sure you have OpenGL development headers installed)
  57     message(install headers with: sudo apt-get install libgl-dev libglu-dev)
  58 }
  59
  60 !maemo5 {
  61     message(QJson built in)
  62     message(Make sure you have QJson development headers installed)
  63     message(install headers with: sudo apt-get install libqjson-dev)
  64 }
  65
  66 maemo5 {
  67     message(QJson built in)
  68     message(Make sure you have QJson development headers installed)
  69     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
  70     message(and deb-src http://repository.maemo.org/extras-devel fremantle free non-free)
  71     message(to scratchbox's sources.list in /etc/apt)
  72     message(run: apt-get update)
  73     message(install headers with: apt-get install libqjson-dev)
  74 }
  75
  76 # -----------------------------------------------------------------
  77 # Debian packetizing additions
  78 # -----------------------------------------------------------------
  79 unix {
  80     # VARIABLES
  81     isEmpty(PREFIX):PREFIX = /usr
  82     BINDIR = $$PREFIX/bin
  83     DATADIR = $$PREFIX/share
  84     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  85         PKGDATADIR=\\\"$$PKGDATADIR\\\"
  86
  87     # MAKE INSTALL
  88     desktop.path = $$DATADIR/applications/hildon
  89     desktop.files += situare.desktop
  90     INSTALLS += desktop
  91     icon26.path = $$DATADIR/icons/hicolor/26x26/apps
  92     icon26.files += situare.png
  93     INSTALLS += icon26
  94     icon40.path = $$DATADIR/icons/hicolor/40x40/apps
  95     icon40.files += situare_40x40.png
  96     INSTALLS += icon40
  97     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
  98     icon64.files += situare_64x64.png
  99     INSTALLS += icon64
 100     target.path = $$BINDIR
 101     INSTALLS += target
 102 }
 103 RESOURCES +=