vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/panelbar.cpp \
  74     ui/panelbase.cpp \
  75     ui/panelcontentstack.cpp \
  76     ui/panelcontextbuttonbar.cpp \
  77     ui/paneltab.cpp \
  78     ui/paneltabbar.cpp \
  79     ui/tabbedpanel.cpp \
  80     ui/routingpanel.cpp \
  81     ui/routewaypointlistitem.cpp \
  82     ui/routewaypointlistview.cpp \
  83     user/user.cpp \
  84     ui/meetpeoplepanel.cpp \
  85     situareservice/database.cpp \
  86     ui/tagsdialog.cpp
  87 HEADERS += application.h \
  88     common.h \
  89     coordinates/geocoordinate.h \
  90     coordinates/scenecoordinate.h \
  91     engine/engine.h \
  92     engine/mce.h \
  93     error.h \
  94     facebookservice/facebookauthentication.h \
  95     facebookservice/facebookcommon.h \
  96     facebookservice/facebookcredentials.h \
  97     gps/gpscommon.h \
  98     gps/gpsposition.h \
  99     map/baselocationitem.h \
 100     map/friendgroupitem.h \
 101     map/frienditemshandler.h \
 102     map/friendlocationitem.h \
 103     map/gpslocationitem.h \
 104     map/mapcommon.h \
 105     map/mapengine.h \
 106     map/mapfetcher.h \
 107     map/maprouteitem.h \
 108     map/mapscene.h \
 109     map/mapscroller.h \
 110     map/maptile.h \
 111     map/maptilerequest.h \
 112     map/mapview.h \
 113     map/osm.h \
 114     map/ownlocationitem.h \
 115     network/networkaccessmanager.h \
 116     network/networkcookiejar.h \
 117     network/networkhandler.h \
 118     network/networkreply.h \
 119     routing/geocodingservice.h \
 120     routing/location.h \
 121     routing/route.h \
 122     routing/routesegment.h \
 123     routing/routingcommon.h \
 124     routing/routingservice.h \
 125     situareservice/imagefetcher.h \
 126     situareservice/situarecommon.h \
 127     situareservice/situareservice.h \
 128     ui/updatelocation/texteditautoresizer.h \
 129     ui/updatelocation/updatelocationdialog.h \
 130     ui/avatarimage.h \
 131     ui/extendedlistitem.h \
 132     ui/extendedlistitemdelegate.h \
 133     ui/extendedlistitemstore.h \
 134     ui/friendlistitem.h \
 135     ui/friendlistitemdelegate.h \
 136     ui/friendlistpanel.h \
 137     ui/friendlistview.h \
 138     ui/fullscreenbutton.h \
 139     ui/imagebutton.h \
 140     ui/indicatorbutton.h \
 141     ui/indicatorbuttonpanel.h \
 142     ui/logindialog.h \
 143     ui/locationlistitem.h \
 144     ui/locationlistview.h \
 145     ui/mainwindow.h \
 146     ui/mapscale.h \
 147     ui/settingsdialog.h \
 148     ui/userinfo.h \
 149     ui/userinfopanel.h \
 150     ui/zoombutton.h \
 151     ui/zoombuttonpanel.h \
 152     ui/listcommon.h \
 153     ui/listview.h \
 154     ui/listitem.h \
 155     ui/listitemdelegate.h \
 156     ui/searchdialog.h \
 157     ui/panelbar.h \
 158     ui/panelbase.h \
 159     ui/panelcommon.h \
 160     ui/panelcontentstack.h \
 161     ui/panelcontextbuttonbar.h \
 162     ui/paneltab.h \
 163     ui/paneltabbar.h \
 164     ui/tabbedpanel.h \
 165     ui/routingpanel.h \
 166     ui/routewaypointlistitem.h \
 167     ui/routewaypointlistview.h \
 168     user/user.h \
 169     ui/meetpeoplepanel.h \
 170     situareservice/database.h \
 171     ui/tagsdialog.h
 172 QT += network \
 173     webkit \
 174     sql
 175
 176 DEFINES += QT_NO_DEBUG_OUTPUT
 177
 178 simulator {
 179     SOURCES += network/networkhandlerprivatestub.cpp \
 180                gps/gpspositionprivate.cpp
 181     HEADERS += network/networkhandlerprivatestub.h \
 182                gps/gpspositionprivate.h
 183     QT += maemo5
 184     CONFIG += mobility
 185     MOBILITY += location messaging
 186 } else:maemo5 {
 187     armel {
 188         DEFINES += ARMEL
 189         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 190         SOURCES += network/networkhandlerprivate.cpp \
 191                    engine/mceprivate.cpp
 192         HEADERS += network/networkhandlerprivate.h \
 193                    engine/mceprivate.h
 194         QT += dbus xml
 195         CONFIG += icd2 qdbus
 196         SOURCES += gps/gpspositionprivateliblocation.cpp \
 197                    gps/liblocationwrapper.cpp \
 198                    gps/geopositioninfo.cpp
 199         HEADERS += gps/gpspositionprivateliblocation.h \
 200                    gps/liblocationwrapper.h \
 201                    gps/geopositioninfo.h
 202         CONFIG += link_pkgconfig
 203         PKGCONFIG += glib-2.0 liblocation mce
 204         LIBS += -llocation
 205         CONFIG += mobility
 206         MOBILITY += messaging
 207
 208     } else {
 209         SOURCES += gps/gpspositionprivatestub.cpp \
 210                    network/networkhandlerprivatestub.cpp \
 211                    engine/mceprivatestub.cpp
 212         HEADERS += gps/gpspositionprivatestub.h \
 213                    network/networkhandlerprivatestub.h \
 214                    engine/mceprivatestub.h
 215     }
 216
 217     QT += maemo5
 218
 219     message([QJson])
 220     message(Make sure you have QJson development headers installed)
 221     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 222     message(to Scratchbox's sources.list in /etc/apt)
 223     message(run: apt-get update)
 224     message(install headers with: apt-get install libqjson-dev)
 225     message([QtMobility])
 226     message(Make sure you have QtMobility development headers installed)
 227     message(install headers with: apt-get install libqtm-dev)
 228 } else {
 229     SOURCES += gps/gpspositionprivatestub.cpp \
 230                network/networkhandlerprivatestub.cpp \
 231                engine/mceprivatestub.cpp
 232     HEADERS += gps/gpspositionprivatestub.h \
 233                network/networkhandlerprivatestub.h \
 234                engine/mceprivatestub.h
 235     message(QJson built in)
 236     message(Make sure you have QJson development headers installed)
 237     message(install headers with: sudo apt-get install libqjson-dev)
 238 }
 239
 240 # -----------------------------------------------------------------
 241 # Debian packetizing additions
 242 # -----------------------------------------------------------------
 243 unix {
 244     # VARIABLES
 245     isEmpty(PREFIX):PREFIX = /usr
 246     BINDIR = $$PREFIX/bin
 247     DATADIR = $$PREFIX/share
 248     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 249         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 250
 251     # MAKE INSTALL
 252     desktop.path = $$DATADIR/applications/hildon
 253     desktop.files += situare.desktop
 254     INSTALLS += desktop
 255     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 256     icon48.files += ../res/icon/48x48/situare.png
 257     INSTALLS += icon48
 258     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 259     icon64.files += ../res/icon/64x64/situare.png
 260     INSTALLS += icon64
 261     target.path = $$BINDIR
 262     INSTALLS += target
 263 }